et lille problem...

hvis du dobbelt klikker på din timer kommer du ud i en procedure som hedder DinForm.Timer1.OnTimer, og der i sætte du så LavGuldGnu('mokka'); noget ligende dette:

procedure TForm1.Timer1.OnTimer;
begin
LavGuldGnu('mokka');
end;

/ZIRON

det er en timer der bliver sat ind i runtime

oki så bare iorden, så 2 sek... nok

/ZIRON

problemet er at det man kalder ved OnTimer eventen er en TNotifyEvent og det er en procedure uden parametre, er der en måde at 'Overgå' dette?

En TNotifyEvent er en procedure med parameteren Sender som er af typen TObject, og en event er af typen "procedure of object" hvilket betyder det skal være det man også kalder en metode ( en procedure i en klase )

eks :

type
  myclass = tclass
    myt : TTimer;   
    procedure MyOnTimer( sender : tobject );
  end;


begin
  myt := TTimer.create(nil);
  myt.OnTimer := MyOnTimer;   
end;

----------------------
Sådan gøres det

/Martin

det hjælper mig jo ikke så meget hvis jeg gerne vil skrive:
myt.OnTimer := MyOnTimer('mokka','gnu');

Ok, Det jeg så er ude efter er at ændre timerens OnTimer property.
HVORDAN!!!!????
kan man ik gøre noget lignende:

TMinTimer = class(TTimer)
property OnTimer: //Og så er det sq allerede her jeg står af!
                  //men det skulle jo meget gerne ende op med at
                  //jeg kan kalde MinOnTimer som vist herunder.
end;

var
minTimer : TMinTimer;

minTimer := TminTimer.create(nil);
minTimer.OnTimer := MinOnTimer('Hans Larsen');

procedure MinOnTimer(tekst : string);
begin
//whatever
end;

PS. hvis de 15 point ikke er nok så finder vi bare ud af det!!!

Du skal lave en klasse der arver fra TTimer for at kunne gøre det. Men det er heldigvis ikke så svært, her er et eksempel:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Extctrls;

type
{ ---------- TMyTimer --------------> }
  TMyNotifyEvent = procedure(Sender: TObject; NotifyString: string) of object;

  TMyTimer = class(TTimer)
  private
    FOnTimerEx : TMyNotifyEvent;
    FNotifyString: string;
    procedure SetTimerEx(OnTimerEx: TMyNotifyEvent);
    procedure OldTimerEvent(Sender: TObject);
  published
    property NotifyString: string read FNotifyString write FNotifyString;
    property OnTimerEx: TMyNotifyEvent read FOnTimerEx write SetTimerEx;
  end;

{ --------- normal TForm ------------> }

  TForm1 = class(TForm)
    Label1: TLabel;
    procedure FormShow(Sender: TObject);
  private
    T : TMyTimer;
    procedure OnTimerEx(Sender: TObject; NotifyString: string);
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

{ ---------- TMyTimer --------------> }

procedure TMyTimer.OldTimerEvent(Sender: TObject);
begin
  if Assigned(FOnTimerEx) then FOnTimerEx(Self, FNotifyString);
end;

procedure TMyTimer.SetTimerEx(OnTimerEx: TMyNotifyEvent);
begin
  FOnTimerEx := OnTimerEx;
  OnTimer := OldTimerEvent;
end;

{ --------- normal TForm ------------> }

procedure TForm1.OnTimerEx(Sender: TObject; NotifyString: string);
begin
  Label1.Caption := NotifyString;
end;

procedure TForm1.FormShow(Sender: TObject);
begin
  T := TMyTimer.Create(Self);
  T.OnTimerEx := OnTimerEx;
  T.NotifyString := 'TMyTimer muhahaha';
  T.Interval := 1000;
  T.Enabled := TRUE;
end;

end.

takker zimp, smid lige et lille svar så får du dine velfortjente point

Welcome