Kode som danner alle datoer i et år ud fra et årstal

For i = 0 To 365
Response.Write DateAdd("d", i, date())
Next

Vi kunne forbedre den en smule, for at tage højde for 29. februar o.s.v.

varBeginDate = "01/01/2003"

For i = 0 To 366
varDate = DateAdd("d", i, varBeginDate)

If Year(varDate) = Year(varBeginDate) Then
  Response.Write varDate & "<BR>"
Else
  Exit For
End If

Next

Ja nummer 2 er meget bedre end forslag 1,
kan jeg også få det sidste på ? altså uge nummer

Function df_ISOWeek (ByVal dDate)
    'returns the ISO week number (week 1 is the week that contains the 4th of January / Monday is the first day of the week)
    'or -1 for invalid dates
    If IsDate (dDate) Then
        df_ISOWeek = DatePart("ww", dDate, vbMonday, vbFirstFourDays)
    Else
        df_ISOWeek = -1
    End If
End Function


varBeginDate = "01/01/2003"

For i = 0 To 366
varDate = DateAdd("d", i, varBeginDate)

If Year(varDate) = Year(varBeginDate) Then
  Response.Write varDate & " " & df_ISOWeek(varDate) & "<BR>"
Else
  Exit For
End If

Next

nu ved jeg selvfølgelig ikke hvad du skal bruge det til - men prøv at tag et kig på denne;

http://www.activedeveloper.dk/aspdigital/studies/kalender.asp

Ek kan det gøres sådan:

<%
'Set start dato
startDato = "24-06-2002"
'Lig et år til og find slut dato
slutDato = DateAdd("yyyy",1,startDato)

'udskriv og lig en dag til ad gangen.
do while CDate(startDato) < CDate(slutDato)
  Response.Write "Dato : " & startDato & "<br>"
  startDato = DateAdd("d",1,startDato)
loop
%>

hmm du skal hvade uge nummer med og kun et års tal som start så gør sådan her:
<%
StartAar = "2002"
'Set start dato til 1/1-startÅr
startDato = "01-01-" & startAar
'Lig et år til og find slut dato
slutDato = DateAdd("yyyy",1,startDato)
'udskriv og lig en dag til ad gangen.
do while CDate(startDato) < CDate(slutDato)
  Response.Write "Dato : " & startDato
  Response.Write " Uge nummer : " & DatePart("ww", startDato, vbMonday, vbFirstFourDays) & "<br>"
 
  startDato = DateAdd("d",1,startDato)
loop
%>

Okie i får (eagleeye + tmceu) den ene var først med dato på et valgfrit år og den anden satte ugenummer på.

Tak for svarene
Troels