Et par cookies spørgsmål

En værdi i en cookie opdaters ved at tildele den en ny værdi.
Den slettes ved tildele en tom tekst.

ja men jeg mener at hvis jeg har
cookies("temp")("nr") værdier 2,5,3,7,5
cookies("temp")("antal") værdier 10,43,21,2
så hører 2 til 10 osv
hvordan opdater jeg 2 til eks 3 ?
Og hvordan fjerner jeg eks nr5 og antal 2 fra min cookies ??

For at opdatere cookien:
Response.Cookies("temp")("nr") = 2

For at slette cookien:
Response.Cookies("temp")("nr") = Empty

sn0wflake >> Hvis jeg gør som du siger hvad sker der så med
resten af værdierne ?? hvis nu 2 skulle blive til 100.
Jeg vil jo stadig gerne beholde de andre værdier i cookien
2,5,3,7,6 bliver til 100,5,3,7,6

Altså jeg ville bruge det i et shopping script hvor nr er id på varen og antal er antal af vare

Det er jo dit problem at sørge for at værdierne er rigtige. Jezus Christ!
Tænk lidt selvstændigt.

arrg jeg er muligvis fat svag men jeg er overhovedet ikke med på det du siger.
Skal jeg bruge instr til det eller et arr eller hvad.

Hvad med at oprette en Cookie der anvender varenr som Key og indholdet er antal. Det gør det lidt nemmere. Her er et lille eksempel.

<%

strMode = Request.QueryString("mode")
strVareNr = Request.QueryString("varenr")

if strMode = "reset" then
  ' Nulstil kurv
  for each Key in Request.Cookies("Kurv")
    Response.Cookies("Kurv")(Key) = "0"
  next
end if

if strMode = "insert" then
  ' Indsæt vare i kurv
  Found = False
  for each Key in Request.Cookies("Kurv")
    if Key = strVareNr then
      Response.Cookies("Kurv")(Key) = CStr(CInt(Request.Cookies("Kurv")(Key)) + 1) ' Antal = Antal + 1
      Found = True
      exit for
    end if
  next
  if not Found then
    Response.Cookies("Kurv")(strVareNr) = "1"
  end if
end if

if strMode = "delete" then
  ' Slet vare fra kurv
  for each Key in Request.Cookies("Kurv")
    if Key = strVareNr then
      Response.Cookies("Kurv")(Key) = "0"
      exit for
    end if
  next
end if

' Vis vareliste
Response.Write("<center>")
Response.Write("<table width='50%'>")
Response.Write("<tr><td align='center'><b>VARELISTE</b></td></tr>")
Response.Write("</table>")
Response.Write("<br>")
Response.Write("<table width='50%'>")
Response.Write("<tr><td width='10%'>Varenr</td><td width='70%'>Varetekst</td><td width='20%'>Tilføj 1 stk.</tr>")
' Vis varer
Response.Write("<tr><td width='10%'>A12</td><td width='70%'>Vare A12</td><td width='20%'><a href='?mode=insert&varenr=A12'>Tilføj</a></tr>")
Response.Write("<tr><td width='10%'>A13</td><td width='70%'>Vare A13</td><td width='20%'><a href='?mode=insert&varenr=A13'>Tilføj</a></tr>")
Response.Write("<tr><td width='10%'>A14</td><td width='70%'>Vare A14</td><td width='20%'><a href='?mode=insert&varenr=A14'>Tilføj</a></tr>")
Response.Write("<tr><td width='10%'>A15</td><td width='70%'>Vare A15</td><td width='20%'><a href='?mode=insert&varenr=A15'>Tilføj</a></tr>")
Response.Write("</table>")
Response.Write("</center>")
Response.Write("<br>")

' Vis kurv
Response.Write("<center>")
Response.Write("<table width='50%'>")
Response.Write("<tr><td align='center'><b>KURV</b></td></tr>")
Response.Write("</table>")
Response.Write("<br>")
' Vis indhold kurv
Response.Write("<table width='50%'>")
Response.Write("<tr><td width='10%'>Varenr</td><td width='70%'>Cookie</td><td width='10%' align='right'>Antal</td><td width='10%'>Fjern</td></tr>")
for each key in Request.Cookies("Kurv")
  if (Request.Cookies("Kurv")(Key) <> "0") then
    Response.Write("<tr><td width='10%'>" & Key & "</td><td width='70%'>(Kurv)(" & Key & ")=" & Request.Cookies("Kurv")(Key) & "</td><td width='10%' align='right'>" & Request.Cookies("Kurv")(Key) & "</td><td width='10%'><a href='?mode=delete&varenr=" & Key & "'>Fjern</a></td></tr>")
  end if
next

Response.Write("</table>")
Response.Write("</center>")
Response.Write("<br>")
Response.Write("<a href='?mode=reset'>Nulstil kurv</a>")

%>

Håber det kan bruges.

coltau >> Yeps det var præsis det jeg ledte efter