Har lige flettet det sammen med det første, men du kan se det i den sidste del:
<%
Dim objXMLHTTP, objXMLDOM
'Opretter en instans af Microsoft.XMLHTTP, så det er muligt at få fat på dokumentet
Set objXMLHTTP = Server.CreateObject("Microsoft.XMLHTTP")
'Opretter en instans af Microsofts XML-parser, XMLDOM
Set objXMLDOM = Server.CreateObject("Microsoft.XMLDOM")
'Opretter forbindelse til xml-dokumentet
Call objXMLHTTP.Open("GET", "
http://www.camelot-europe.com/herald/servers/Excalibur/guilds/23.xml", False)
objXMLHTTP.Send
'Lægger indholdet af dokumentet over i vores XML-parser objekt
Set objXMLDOM = objXMLHTTP.ResponseXML
' Henter alle character-elementer ud
Set characters = objXMLDOM.getElementsByTagName("character")
'Løber igennem alle characterd, og udskriver dem
'Attributter hentes med getAttribute("attributnavn")
'Nodes hentes med selectSingleNode("nodenavn").Text
For i = 0 To characters.length - 1
set character = characters(i)
Response.Write("Name: " & character.getAttribute("name") & "<br>")
Response.Write("Last on: " & character.getAttribute("laston") & "<br>")
Response.Write("Race: " & character.selectSingleNode("race").Text & "<br>")
Response.Write("Class: " & character.selectSingleNode("class").Text & "<br>")
Response.Write("Level: " & character.selectSingleNode("level").Text & "<br>")
Set character = Nothing
Next
' Henter alle top-elementer ud
Set tops = objXMLDOM.getElementsByTagName("top")
For i = 0 To tops.length - 1
set top = tops(i)
Response.Write("Type: " & top.getAttribute("type") & "<br>")
Response.Write("Name: " & top.selectSingleNode("top_char").getAttribute("name") & "<br>")
Response.Write("Point: " & top.selectSingleNode("top_char").getAttribute("point") & "<br>")
Set top = Nothing
Next
Set tops = Nothing
Set characters = Nothing
Set objXMLHTTP = Nothing
Set objXMLDOM = Nothing
%>
Se evt. MSXML-reference for mere information om metoder og properties:
http://msdn.microsoft.com/library/default.asp?url=/library/en-us/xmlsdk30/htm/xmmscxmlreference.asp/Martin Sommer
www.magik.dk
