Hjælp til meget simpel artikelfunktion

Jeg kan da lave et eks som du kan prøve..

Følger lige med...

Alle 3 filer skal ligge i samme folder; backend.asp, showtext.asp samt data.txt:


-- Filen ---- backend.asp:


<html>
<head></head>
<body>
<%
filnavn = "data.txt"

Set objFSO = Server.CreateObject("Scripting.FileSystemObject")

if Request.ServerVariables("REQUEST_METHOD") = "POST" then
  Set objTextStream = objFSO.OpenTextFile(Server.MapPath(filnavn), 2)
  objTextStream.write Request.Form("textData")
  objTextStream.close
end if

Set objTextStream = objFSO.OpenTextFile(Server.MapPath(filnavn), 1)
if Not objTextStream.AtEndOfStream then
  strText = objTextStream.readAll
end if
objTextStream.Close

Set objTextStream = Nothing
Set objFSO = Nothing
%>


<form action="backend.asp" method="post">
<table align="center">
<tr><td><TEXTAREA NAME="textData" COLS="45" ROWS="6"><%=strText%></TEXTAREA>
</td></tr>
<tr><td><input type="submit" name="Opdater" value="Opdater">
</td></tr>
</table>
</form>

</body>
</html>

-- Filen ---- showtext.asp:


<%
filnavn = "data.txt"
strText = ""

Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
Set objTextStream = objFSO.OpenTextFile(Server.MapPath(filnavn), 1)

if Not objTextStream.AtEndOfStream then
  strText = objTextStream.readAll
end if
objTextStream.Close

if strText <> "" then
  'Lav links og email om til rigtige links
  strText = LinkString (strText)
  'Lav Enter-knappem om til HTML-return <br>.
  strText = Replace(strText,vbCrLf,"<br>")
end if

'Udskrive teksten fra filen
Response.write strText

Set objTextStream = Nothing
Set objFSO = Nothing

'Functioner----------------------
Function LinkString(strInput)
Set objRegExpHTTP1 = New RegExp
Set objRegExpHTTP2 = New RegExp
Set objRegExpEMail = New RegExp

objRegExpHTTP1.Pattern = "(http|ftp)(:\/\/[\w\._-]+\.[\w\._-]+\S*)"
objRegExpHTTP2.Pattern = "(^|[^\/])(www[^\.\s]?\.[\w\._-]+\.[A-Za-z]{2,3}[\w\S]*)"
objRegExpEMail.Pattern = "([\w\._-]+@[\w\._-]+\.[A-Za-z]{2,3}\S*)"

objRegExpHTTP1.Global = True
objRegExpHTTP2.Global = True
objRegExpEMail.Global = True

objRegExpHTTP1.IgnoreCase = True
objRegExpHTTP2.IgnoreCase = True
objRegExpEMail.IgnoreCase = True

strOutput = objRegExpEMail.Replace(strInput, " <a href='mailto:$1'>$1</a> ")
strOutput = objRegExpHTTP1.Replace(strOutput, " <a href='$1$2' target='_blank'>$1$2</a> ")
strOutput = objRegExpHTTP2.Replace(strOutput, " $1<a href='http://$2' target='_blank'>$2</a> ")

objRegExpHTTP2.Pattern = "(<br>|[,.)\]\}])('>)"
strOutput = objRegExpHTTP2.Replace(strOutput, "$2")
objRegExpHTTP2.Pattern = "(<br>|[,.)\]\}])(' target=)"
strOutput = objRegExpHTTP2.Replace(strOutput, "$2")
objRegExpHTTP2.Pattern = "(<br>|[,.)\]\}])(</a>)"
strOutput = objRegExpHTTP2.Replace(strOutput, "$2$1")

Set objRegExpHTTP2 = Nothing
set objRegExpHTTP1 = Nothing
Set objRegExpEMail = Nothing

LinkString = strOutput
End Function


%>

Hvis filen data.txt ikke findes skal du lige lave en tom fil som hedder data.txt

Beklager, jeg kan ikke få det til at virke.
Ved submit kommer der en fejl 500 og der skrives
ikke noget i tekstfilen.

Har du oprettet en tekst fil data.txt som er tom??

Har du skrive rettigheder til den folder som data.txt ligger i?

Prøv evt i IE menuen Tools->Internet Options->Advanced  og slå "Show firendly HTTP error messages" fra.

OK, så får jeg en :

Microsoft VBScript runtime error '800a0046'

Permission denied

/backend.asp, line 10


Hvad betyder det?
(Alle filer i mappen er CHMOD 777 som default på serveren)

Har du et Web-hotel eller egen server??

så skal du havde skrive rettigheder til den folder filen data.txt ligge i.

Ok, jeg vender tilbage i morgen.

Det er en privat server, men ikke
mig der passer den.

Endelig får jeg det til at virke!
Ham der passer serveren brokkede sig over at det ville give nogle
sikkerhedsproblemer(?) fordi der skulle ændres ved standard-permissions
for IIS-guest accounten.

Anyway, det virker nu, og jeg er klar til at godkende!

Hvad skal jeg tilføje til koden for at få formularen til at
sende mig til en anden side efter at der er submittet?

Response.Redirect("andenside.asp")
:)

Tænker du på at sende form data til en anden side for så rettes det i form tagen action del, her bliver form data send til backend.asp :

<form action="backend.asp" method="post">

Nej, blot at man automatisk kommer til f.eks. sin forside
når formularen er opdateret.
Som det er nu bliver den jo på form siden.

Så skal du bruger Response.Redirect "filnavn.asp"
Så kan du lave en redirect når tekst filen er blevet opdateret.

if Request.ServerVariables("REQUEST_METHOD") = "POST" then
  Set objTextStream = objFSO.OpenTextFile(Server.MapPath(filnavn), 2)
  objTextStream.write Request.Form("textData")
  objTextStream.close
  'Send til forsiden...
  Response.Redirect ("forside.asp")        '<----------- Indsættes her
end if

Det er muligt at denne linie også lige skal ind i toppen af filen:

<% Response.Buffer = true %>

for den ikke melder fejl når man laver redirect.

Tak for hjælpen!