Problemer med replace funktionen

Prøv med denne:


    str = ".....Din streng som skal lave om...."

    strRpl = str
    DO
      startPos = Instr(1,strRpl, "<FONT SIZE=5>", 1)
      slutPos = InStr (Cint(startPos)+1,strRpl,"</FONT>",1) 
      If (startPos > 0) and (slutPos > 0) then
        strRpl = Replace(strRpl,"<FONT SIZE=5>","<h2>",1,1,0)
        strRpl = Replace(strRpl,"</font>","</h2>",1,1,0)
      end if
    LOOP WHILE (startPos > 0) and (slutPos > 0)   
    str = strRpl


Response.write str

Eller vha regular expressions:

' Lav et regExp objekt
Set regEx = New RegExp               
' Dette er pattern, der skal søges efter
regEx.Pattern = "<FONT SIZE=5>(.*?)</FONT>"
' Vi vil finde mere end bare den første forekomst, så global skal være true
regEx.global = true
' Foretag selve erstatningen
resultat = regEx.Replace( kildeStreng, "<h2>$1</h2>" )

Jeg spørger lige :

Hvad hvis </FONT> først finde på næste linie ?

regEx.Pattern = "<FONT SIZE=5>([^<]*?)</FONT>"

burde fungere på tværs af linebreaks.

Hmm "eagleeye" har du læst problemstillingen?? I din løsnng søger den stadig fra punkt 1. (strRpl = Replace(strRpl,"</font>","</h2>",[1],1,0)) Det vil sige at den stadig kommer til at fjerne </FONT> taget fra de andre <FONT SIZE=et andet tal end 5>

Hmm jeg har ikke brugt regExp før.

Kunne du ikke lave et mere konkret eksempel jeg kunne bruge lidt nemmere?? Hvor får du foresten de mærkelige tegn fra??? Hvordan ved du at det virker?? (Det ligner lidt på noget PHP)

Ps. Jeg har lavet et script nu som kan lave det samme, men det er lavet på en lidt tåbeligt måde. (Instr() og Mid()). Jeg vil dog gerne løse det på "rigtig måde" så jeg vil stadig give point hvis i kan løse det! Har bare ikke så meget tid til at prøve halve løsninger lige nu. Jeg har en deadline, men jeg skal nok tjecke det efter!

Du kan godt bruge regExp: Men det er så en god ide også at sætte den til IgnoreCase så den fanger både store og små bogstaver:


str = "En test <font size=3>TEST</font> mere test <font size=5>gerne h2 tags omkring</font> kajdf"

' Lav et regExp objekt
Set regEx = New RegExp               
' Dette er pattern, der skal søges efter
regEx.Pattern = "<FONT SIZE=5>([^<]*?)</FONT>"
' Vi vil finde mere end bare den første forekomst, så global skal være true
regEx.global = true
regEx.IgnoreCase = true
' Foretag selve erstatningen
resultat = regEx.Replace(str , "<h2>$1</h2>" )
Set regEx = Nothing

Response.Write resultat

<% @Language=VBScript %>
<%
REsponse.expires=0

    const ForReading=1, ForWriting=2, ForAppending=8
    const TristateUseDefault=-2
    const TristateTrue=-1
    const TristateFalse=0

    fil="demo.html"
    gemfil="red_demo.html"


    starttxt="<FONT SIZE=5>"
    Sluttxt="</FONT>"
   
    replstart="<H2>"
    replslut="</H2>"

    startok=0
    slutok=0
    linjetjekket=0
    beggetjek=0

    mappe=Server.MapPath(".")
    Set objFS=server.CreateObject("scripting.FileSystemObject")
    Set objFG=server.CreateObject("scripting.FileSystemObject")

    If objFS.FileExists(mappe & "\" & fil)=true Then
        Set objTextS=objFS.OpenTextFile(mappe & "\" & fil,ForReading, TristateFalse)
       
        If objFS.FileExists(mappe & "\" & fil)=true Then
            Set objGem=objFS.OpenTextFile(mappe & "\" & gemfil,ForWriting, TristateFalse)
        Else
            Set objGem=objFS.CreateTextFile(mappe & "\" & gemfil,False,False)
        End if

        Do While objTextS.AtEndOfStream<>True
            tempstr=objTextS.Readline
            If startok=0 Then
                While Instr(UCASE(tempstr),UCASE(starttxt))
                    tempstr=Replace(UCASE(tempstr),UCASE(starttxt),UCASE(replstart),1,1,1)
                    startok=1
                    slutok=0
                    IF Instr(UCASE(tempstr),UCASE(sluttxt))<>0 Then
                        tempstr=Replace(UCASE(tempstr),UCASE(sluttxt),UCASE(replslut),1,1,1)
                        slutok=1
                        startok=0
                    End if
                Wend
            Else
                While Instr(UCASE(tempstr),UCASE(sluttxt))<>0
                    tempstr=Replace(UCASE(tempstr),UCASE(sluttxt),UCASE(replslut))
                    slutok=1
                    startok=0
                    IF Instr(UCASE(tempstr),UCASE(starttxt))<>0 Then
                        tempstr=Replace(UCASE(tempstr),UCASE(starttxt),UCASE(replstart))
                        slutok=0
                        startok=1
                    End if
                Wend
            End if
            objGem.Writeline tempstr
            Response.Write tempstr
        Loop

        objGem.Close
        objTextS.CLose
        Set objGem=Nothing
        Set objTextS=Nothing
        Set objFG=Nothing
        Set objFS=Nothing
    Else
        Response.write("Fejl Filen er ikke fundet ")
        Set objFG=Nothing
        Set objFS=Nothing
    End If
%>


Denne søger og erstatter med STOR tekst, så det er vel vigtigt at det kun er tags der søges efter !

Benson

UPS !

Det er jo hele linjen der bliver til stor tekst !

Nå men, så fjerne vi bare alle UCASE, og håber på at vi bruger samme tegnsætning til alle tags ! :-)

Hmm ja langes eksempel virkede jo fint fint. Lækker lille kode. Så han få da meste af pointne.
Eagleeye kom lige med linebrackeren, så han får lidt.
Bensons eksempel har jeg ikke prøved. Det er lige så indviklet som det jeg selv har lavet, men du får også nogle point, for det virker sikkert!

Hygge og tak for hjælpen!

Jo, Regular Expression (RegExp) er især kendt fra Unix/Linux verdenen og dermed også PHP. Det er et fremragende og meget kraftfuldt værktøj, når man skal lave streng-sammenligninger, der bare er en smule avancerede.

RegEx er forholdsvist let at anvende, når først man får grejet den temmeligt kryptiske syntax, der anvendes til patterns ("de mærkelige tegn"). Du kan finde en reference på http://msdn.microsoft.com/library/default.asp?url=/library/en-us/script56/html/vspropattern.asp. På http://py-howto.sourceforge.net/regex/regex.html er en udmærket Regular Expression HowTo, der dog er Python-centreret, men afsnittene om opbygning af patterns er stadigvæk gældende.

For at være lidt mere konkret:


Pattern = "<FONT SIZE=5>(.*?)</FONT>" betyder: Find alle forekomster af en streng, der begynder med "<FONT SIZE=5>" efterfulgt af 0 eller flere vilkårlige tegn indtil "</FONT>". Spørgsmålstegnet er med for at sikre, at rækken af vilkårlige tegn bliver kortest muligt - uden det ville den matche så meget som muligt og altså muligvis springe flere <FONT>-tags over.

Pattern = "<FONT SIZE=5>([^<]*?)</FONT>" betyder: Find alle forekomster af en streng, der begynder med "<FONT SIZE=5>" efterfulgt af 0 eller flere characters, der må være alt andet end "<", indtil "</FONT>".

Held og lykke med at kigge nærmere på det :)

Takker mange gange igen. Jeg har også været ude og finde nogle artikler om det!

http://www.aspalliance.com/brettb/VBScriptRegularExpressions.asp

Jeg prøvede denne kode med variabler og der virkede den ikke hvorfor det??

' Lav et regExp objekt
Set regEx = New RegExp               
' Dette er pattern, der skal søges efter
regEx.Pattern = var1 & "([^<]*?)" & var2
' Vi vil finde mere end bare den første forekomst, så global skal være true
regEx.global = true
regEx.IgnoreCase = true
' Foretag selve erstatningen
resultat = regEx.Replace(str , var3 & "$1" & var4 )
Set regEx = Nothing

Response.Write resultat

Tja, det kommer jo voldsomt meget an på, hvad der er i din str og i de 4 "var"-variable, og hvordan det ikke virkede. Forsvandt alt din tekst, blev intet erstattet eller noget tredje?

Se: http://www.eksperten.dk/spm/258896