Ændre et diagrams RowSource i VBA

diagrams rowsource! waht do you mean here?

Jeg vil ændre de data diagrammet er baseret på. Hvordan gør jeg det i runtime?

diagrammet! what is a diagram? Do you meana form?

me.recordsource = "NewTable"

A want to change the source of a chart i have in a report on the fly.

Dit diagram skal have et navn.

Derefter er det 'bare' at bygge en SQL op

strSQL = "SELECT bla, bla,,,,,"
ctlDiagramNavn.RowSource = SQL

Niels

Option Compare Database
Option Explicit

Private m_objChart      As Graph.Chart

Private Sub cboCompany_Change()
   
    On Error GoTo cboCompany_Change_Err

    Dim strSQL      As String

    ' different select statement for all records
    If cboCompany = -1 Then
        strSQL = "qryxSalesSummary"
    Else
        strSQL = "SELECT * FROM qryxSalesSummary WHERE CompanyName=""" & _
            cboCompany.Column(1) & """"
    End If

    ' set the data source for the chart
    ctlChart.RowSource = strSQL
    ctlChart.RowSourceType = "Table/Query"

    ' format the chart
    With m_objChart
        ' set the font size
        .ChartArea.Font.Size = 8
        .HasLegend = chkLegend
        .Refresh

        ' If showing all then make multi-layered
        If cboCompany = -1 Then
            .ChartType = xl3DColumn
            .Refresh
            .Axes(xlSeriesAxis).HasTitle = False
        Else
            .ChartType = xl3DColumnStacked
            .Refresh
        End If
       
        ' format the x-axis
        With .Axes(xlCategory)
            .HasTitle = True
            .AxisTitle.Caption = "Month"
        End With
       
        ' format the y-axis
        With .Axes(xlValue)
            .HasTitle = True
            .AxisTitle.Caption = "Total Sales"
        End With

    End With

cboCompany_Change_Exit:
    Exit Sub

cboCompany_Change_Err:
    If Err.Number = 1004 Then
        m_objChart.Refresh
    Else
        Err.Raise Err.Number, Err.Source, Err.Description, Err.HelpFile, Err.HelpContext
    End If

End Sub

Private Sub chkLegend_Click()

    m_objChart.HasLegend = chkLegend

End Sub

Private Sub Form_Load()

    ' set a reference to the chart object
    Set m_objChart = ctlChart.Object

End Sub

Private Sub Form_Unload(Cancel As Integer)

    ' clean up reference
    Set m_objChart = Nothing

End Sub

Ovenstående er et eksempel, håber du kan bruge noget af det

Æh... Jeg har en lavet et diagram i en rapport. Diagramet hedder oleDiagram. Spørgsmållet er, hvordan kan jeg ændre diagrammets RowSource-property, når rapporten starter?

Jeg har flg. kode, men Access brokker sig:

Sub Report_Open()
  Me.oleDiagram.RowSource = "SELECT * FROM tblTabel WHERE Dit = " & Dat
End Sub

Jeg får følgende fejl:

Run-time error '2455':

Det indtastede udtryk indeholder en udyldig reference til egenskaben RowSource.

Jeg har fundet noget på Microsofts KB-database. http://support.microsoft.com/default.aspx?scid=KB;EN-US;Q209993&

Er der ikke en simplere metode?

Sorry, jeg så ikke det var en rapport :(

Du er nødt til at åbne rapporten i design før du kan ændre dine objekter på rapporten.


DoCmd.OpenReport "rapport2", acViewDesign

Reports("rapport2").oleDiagram.RowSource = "SELECT * FROM tblTabel WHERE Dit = " & Dat

DoCmd.OpenReport "rapport2", acViewPreview


Niels

nih >> Vi kan alle sammen tage fejl. Tag det ikke så tungt :) Men det der med at man skal åbne rapport i design-mode, før man kan ændre et objekt, har jeg allerede fundet ud af. Og hvis der ikke er andre løsninger, så lukker jeg spørgsmålet. Læg lige et svar, så vi tre kan dele de 30 points :)

Hvis ikke du er tilfreds med mine forslag, ta'r du bare points selv. Det er ikke derfor jeg deltager.

Niels

nih >> Det kunne jeg jo bare gøre :)