Tegne program (select/fill)

http://galt.mrl.nyu.edu/pub/Intro_to_Multimedia/snapshot_of_stage/snapshot_of_stage.html

Sorry mate, det er jo selve tegne delen den har jeg styr på, det er selve det at udfylde et område med en farve (som med malerspanden i Photo shop osv.) og at kunne selecte et område (som magic ward i Photoshop osv.)…

trick ;o)

Prøv denne behavior: Drop det på et bitmap billed.
-------------------------- SCRIPT ---------------------------------
property pPctRef
property pSprLeft
property pSprTop
property pSprScalarX
property pSprScalarY
property pPixelActorListX
property pPixelActorListY
property pSpreadListX
property pSpreadListY

on beginSprite me
  mySpr = sprite me.spriteNum
  pPctRef = mySpr.member
  pSprLeft = mySpr.left
  pSprTop = mySpr.top
  pSprScalarX = float(pPctRef.width) / mySpr.width
  pSprScalarY = float(pPctRef.height) / mySpr.height
  pPixelActorListX = []
  pPixelActorListY = []
  pSpreadListX = [1, 0, -1, 0]
  pSpreadListY = [0, 1, 0, -1]
end

on mouseDown me
  me.initPaint()
end

on initPaint me, col
  if voidP(col) then
    col = random(16777216)
  end if
 
  sprX = the mouseH - pSprLeft
  sprY = the mouseV - pSprTop
  mbrX = integer(sprX * pSprScalarX) - 1
  mbrY = integer(sprY * pSprScalarY) - 1
 
  me.paintBucket(mbrX, mbrY, col)
end


on paintBucket me, aX, aY, aSourceColor
  targetColor = pPctRef.getPixel(aX, aY)
  pPctRef.setPixel(aX, aY, aSourceColor)
  append pPixelActorListX, aX
  append pPixelActorListY, aY
  repeat while count(pPixelActorListX)
    xCur = getAt(pPixelActorListX, 1)
    yCur = getAt(pPixelActorListY, 1)
    deleteAt pPixelActorListX, 1
    deleteAt pPixelActorListY, 1
    repeat with n = 1 to 4
      xTest = xCur + getAt(pSpreadListX, n)
      yTest = yCur + getAt(pSpreadListY, n)
      if pPctRef.getPixel(xTest, yTest) = targetColor then
        pPctRef.setPixel(xTest, yTest, aSourceColor)
        -- updateStage
        append pPixelActorListX, xTest
        append pPixelActorListY, yTest
      end if
    end repeat
  end repeat
end
------------------------- END SCRIPT -------------------------------

Nice, thanks mate..!
Er sikker på at jeg kan strikke det sammen som jeg vil ud fra den grundkode..

trick ;o)