Ændre pagesetup

Ja det har jeg - MEN du kan kun gøre det ved at åbne rapporten i designvisning, ændre det og så gemme rapporten. Der efter kan du udskrive/vise rapporten.  Altså er en .mde fil udelukket.

Hvorfor skal du kunne gøre dette ?

Type str_PRTMIP
    strRGB As String * 28
End Type

Type type_PRTMIP
    xLeftMargin As Long
    yTopMargin As Long
    xRightMargin As Long
    yBotMargin As Long
    fDataOnly As Long
    xWidth As Long
    yHeight As Long
    fDefaultSize As Long
    cxColumns As Long
    yColumnSpacing As Long
    xRowSpacing As Long
    rItemLayout As Long
    fFastPrint As Long
    fDataSheet As Long
End Type


Function fhpSetMargins(strReport As String) As Integer
' -----------------------------------------------------------------------------------
' Purpose      : Sets the margin of a report
' Called from  :
' Returns      :
' Remarks      : 1440 twips = 1 inch  567 twips = 1 cm
' -----------------------------------------------------------------------------------
  Dim PrtMipString As str_PRTMIP
  Dim PM As type_PRTMIP
  Dim rpt As Report
   
  DoCmd.OpenReport strReport, acDesign                      'Open report in design view
 
  Set rpt = Reports(strReport)
  PrtMipString.strRGB = rpt.PrtMip
  LSet PM = PrtMipString
  PM.xLeftMargin = 1 * 567                                  'Set left margin
  PM.yTopMargin = 1 * 567
  PM.xRightMargin = 1 * 567
  PM.yBotMargin = 1 * 567
  LSet PrtMipString = PM                                    'Update property.
  rpt.PrtMip = PrtMipString.strRGB
 
  DoCmd.Close acReport, strReport, acSaveYes                'Close report

End Function


Denne funktion sætter alle marginer til 1 cm !  Det kan du så 'bare' rette til det du har brug for eller udbygge funktionen til at tage flere parametre.

Vil det sige at det godt kan lade sig gøre alligevel?

Så længe det er en .mdb ( eller .adp ) fil, så kan man godt ja.
Hvis du bruger en .mde fil er rapporternes designvisning låst og funktionen virker ikke.

Det var ærgerligt - tak for hjælpen alligevel!

mvh mundt