%username%

:start
if {%1}=={} goto :EOF
XCOPY "C:\Documents and Settings\%1\Lokale indstillinger\Application Data\Microsoft\Outlook" "H:\Documents and Settings\%1\Lokale indstillinger\Application Data\Microsoft\Outlook" /s /e /h /k /o /y /i
XCOPY "C:\Documents and Settings\%1\Foretrukne" "H:\Documents and Settings\%1\Foretrukne" /s /e /h /k /o /y /i
XCOPY "C:\Documents and Settings\%1\Dokumenter" "H:\Documents and Settings\%1\Dokumenter" /s /e /h /k /o /y /i
XCOPY "C:\Documents and Settings\%1\Application Data\Microsoft\Address Book" "H:\Documents and Settings\%1\Application Data\Microsoft\Address Book" /s /e /h /k /o /y /i
shift
goto start

Gem filen som kopier.cmd og kør den med de brugernavne der skal kopieres.
Eksempel:
kopier.cmd Bruger1 Bruger2 Bruger3

uhm... der skal du nok have fat i noget ADSI-scripting

Set ObjDomain = GetObject("WinNT://Domain")

For each object in ObjDomain ' Look at each object
If object.class = "User" Then

xcopy c:\documents and settings\"& object.name &", e:\backup\"& object.name

End If

Next

:) mit script kan nemt skrives om så det passer ind i tpo's bafil :)

Set ObjDomain = GetObject("WinNT://Domain")

For each object in ObjDomain ' Look at each object
If object.class = "User" Then

strUsers = strUsers & object.name &" "

End If
Next

Shell("xcopy "& strUsers)

Jeg er ikke helt med på det her, så er der ikke lige kan forklare hvad jeg skal.

tpo<<jeg har skrevet det du skrev ind i bat-filen, men hvad skal jeg gøre mere?

cyberfessor<<Hvad skal jeg gøre med dit?

2400nv>> det paster du ind i en vbsfil.. retter domain til navnet på dit domain/computer som brugerne findes på og derefter kører du vbsfilen

en anden mulighed var at bruge FileSystemObject til at læse navnene på alle de mapper der findes i c:\documents and settings

Nu kender jeg meget til programmering andet end lidt dos/cmd. Hvordan opretter jeg en vbsfil?

Hej 2400nv
Lad os tage et skridt af gangen.
Hvor har du gemt filen?
Hvad er navnet på filen?

Jeg har skrevet det du skrev ind i filen. Har kaldt filen kopier.cmd og gemt den på e:\

Klik Start ->Kør
Tast: e:\kopier.cmd Bruger1 bruger2

Bruger1 og Bruger2 udskiftes med de rigtige brugernavne, f.eks. Administrator.

Det virker ikke med:
e:\kopier.cmd Bruger1 bruger2

Prøver lige at omdøbe bat-fil til bare kopier

Nu sker der noget!! Hvad gør man hvis, en bruger har et fornavn og efternavn i sit brugernavn. Eks. Jens Jensen

e:\kopier.cmd "Fornavn Efternavn" Bruger2 "Fornavn2 Efternavn2"

Det prøver jeg så

Det virker fint nok med 1. brugernavn, men det 2. brugernavn driller

cyberfessor<<Hvordan opretter jeg en vbs-fil?

2400nv>> åbn notepad, gem filen som etellerandet.vbs

Er hermed gjort:-) Hvad gør jeg så?

det kommer lidt an på hvad du vil...

hvis du kopiere det her ind i filen

Set ObjDomain = GetObject("WinNT://Domain")

For each object in ObjDomain ' Look at each object
If object.class = "User" Then

msgbox(object.name)

End If
Next

og kører filen, så kommer der en dialogbox for hver bruger der er på dit domain

Kan du lave den, så den automatisk henter de forskellige brugere og kopiere disse filer?

Min outlook fil
Mine dokumenter
Mine foretrukne
Mit adressekatotek

hehe.. joo.. det kan jeg da godt.. men har du ikke lyst til at prøve selv? hvis du nu tænker dig lidt om, så er det faktisk ikke så svært :)

Jeg ville godt, hvis jeg kendte noget til vbs, men det gør jeg ikke :-( (endnu). Hvis du du vil hjælpe mig med at lave det, vil jeg blive meget glad :-)

altså.. hvis du nu laver en batfil der kopierer de 4 mapper for en given bruger, så skal du kalde den batfil fra din vbsfil for hver bruger der blev fundet.

Altså jeg skal først lave en bat-fil og derefter en vbs-fil? Hvordan skal bat-filen se ud?

Noget i denne stil, eller hvad?
**********************************************
set username=Administrator
echo %username%

XCOPY "C:\Documents and Settings\%username%\Lokale indstillinger\Application Data\Microsoft\Outlook" "H:\Documents and Settings\%username%\Lokale indstillinger\Application Data\Microsoft\Outlook" /s /e /h /k /o /y /i
XCOPY "C:\Documents and Settings\%username%\Foretrukne" "H:\Documents and Settings\%username%\Foretrukne" /s /e /h /k /o /y /i
XCOPY "C:\Documents and Settings\%username%\Dokumenter" "H:\Documents and Settings\%username%\Dokumenter" /s /e /h /k /o /y /i
XCOPY "C:\Documents and Settings\%username%\Application Data\Microsoft\Address Book" "H:\Documents and Settings\%username%\Application Data\Microsoft\Address Book" /s /e /h /k /o /y /i

ej... den er jo ikke dynamisk.. så vil brugeren jo være administrator HVER gang.. prøv heller edet her

set username=%1
echo %username%

XCOPY "C:\Documents and Settings\%username%\Lokale indstillinger\Application Data\Microsoft\Outlook" "H:\Documents and Settings\%username%\Lokale indstillinger\Application Data\Microsoft\Outlook" /s /e /h /k /o /y /i
XCOPY "C:\Documents and Settings\%username%\Foretrukne" "H:\Documents and Settings\%username%\Foretrukne" /s /e /h /k /o /y /i
XCOPY "C:\Documents and Settings\%username%\Dokumenter" "H:\Documents and Settings\%username%\Dokumenter" /s /e /h /k /o /y /i
XCOPY "C:\Documents and Settings\%username%\Application Data\Microsoft\Address Book" "H:\Documents and Settings\%username%\Application Data\Microsoft\Address Book" /s /e /h /k /o /y /i

så kaldes den dinfil.bat bruger

Jeg gemmer dette i en bat-fil og gemmer den som dinfil.bat. Når jeg har gjort det, hvad gør jeg så? Skal jeg ikke lave en vbs-fil?

Jeg troede det hele skulle laves i vbs.

nej nej... vbs bruger vi kun til at hente brugerne ud fra din computer, og på den måde kalder din batfil med den rigtige bruger som parameter...

altså.. du har din batfil som skal køres på denne måde: fil.bat bruger

i din vbsfil bliver det altså til

Set ObjDomain = GetObject("WinNT://Domain")

For each object in ObjDomain ' Look at each object
If object.class = "User" Then

Shell("fil.bat "& object.name)

End If
Next

Har nu både lavet bat-fil og vbs-fil. Har gemt filerne i roden af c:\

Jeg kører bare bat-fil ved at gå ind i start - kør og så skrive "c:\dinfil.bat Administrator" eller hvad?

hehe.. nej, det er jo vbsfilen du skal køre... den kalder sp din batfil

Hvordan kører jeg vbs-filen?

Til tpo:
Sidder lige og leger lidt med din løsning. Kan man ikke skrive brugerne ind i bat-filen ? Noget i denne retning, hvis man kan.
************************************************
:start
if {%username%}=={} goto :EOF
set username=Administrator "Jens Jensen" "Hans Hansen"
echo %username%

XCOPY "C:\Documents and Settings\%username%\Lokale indstillinger\Application Data\Microsoft\Outlook" "H:\Documents and Settings\%username%\Lokale indstillinger\Application Data\Microsoft\Outlook" /s /e /h /k /o /y /i
XCOPY "C:\Documents and Settings\%username%\Foretrukne" "H:\Documents and Settings\%username%\Foretrukne" /s /e /h /k /o /y /i
XCOPY "C:\Documents and Settings\%username%\Dokumenter" "H:\Documents and Settings\%username%\Dokumenter" /s /e /h /k /o /y /i
XCOPY "C:\Documents and Settings\%username%\Application Data\Microsoft\Address Book" "H:\Documents and Settings\%username%\Application Data\Microsoft\Address Book" /s /e /h /k /o /y /i
shift
goto start

:EOF

2400nv>> dobbeltklikker på den.. bare som et nromalt program

cyberfessor>>der sker ikke noget, når jeg dobbeltklikker :-(

SLET ikke noget... eller åbner den i notepad, eller i cmd... eller, bare ingenting...

prøv at skriv følgende i toppen af filen

MsgBox("starting script...")

Jeg har tilføjet MsgBox("starting script..."). Der kommer en box, hvor der står starting script, men ellers sker der ikke noget!

Har rettet vbs-filen til dette:
*******************************
MsgBox("starting script...")
Set ObjDomain = GetObject("WinNT://Domain")

For each object in ObjDomain ' Look at each object
If object.class = "User" Then

Shell("fil.bat "& object.name)

End If
Next

ææhm... nu ved jeg sælvfælgelig ikke hvordan din setup er, men mon ikke du skulle ændre Domain til noget andet?

Jeg har hvis ikke noget Domain. Det er bare en lokal computer.

så skriver du navnet på din lokale computer :)

Så hvis navnet på computeren er "computer1", så retter jeg:
Set ObjDomain = GetObject("WinNT://Domain")
til:
Set ObjDomain = GetObject("computer1")

Set ObjDomain = GetObject("WinNT://computer1")

:)

Der er fejl i linje 7, tegn 1. Fejl:Typer stemmer ikke overens:'shell'.
*************************************
MsgBox("starting script...")
Set ObjDomain = GetObject("WinNT://nicolai")

For each object in ObjDomain ' Look at each object
If object.class = "User" Then

Shell("fil.bat "& object.name)

End If
Next

Til tpo: Kan man ikke rette lidt i dit script?

Hvad med det jeg skrev:
17/03-2003 12:00:40

Her er et eksempel med brugernavne i selve scriptet.


@echo off
@goto start
@Skriv dine bruger navne herunder (i stedet for Anders And og Fedtmule)
Anders And
Fedtmule

@:start
@for /f "eol=@ delims=" %%a in (%~sf0) do (
@echo Kopierer filer for %%a
@echo.
@xcopy "C:\Documents and Settings\%%a\Lokale indstillinger\Application Data\Microsoft\Outlook" "H:\Documents and Settings\%%a\Lokale indstillinger\Application Data\Microsoft\Outlook" /s /e /h /k /o /y /i
@xcopy "C:\Documents and Settings\%%a\Foretrukne" "H:\Documents and Settings\%%a\Foretrukne" /s /e /h /k /o /y /i
@xcopy "C:\Documents and Settings\%%a\Dokumenter" "H:\Documents and Settings\%%a\Dokumenter" /s /e /h /k /o /y /i
@xcopy "C:\Documents and Settings\%%a\Application Data\Microsoft\Address Book" "H:\Documents and Settings\%%a\Application Data\Microsoft\Address Book" /s /e /h /k /o /y /i
@echo. )
@Pause

tpo<<Jeg har lige prøvet dit script. Fedt!! Det er lige det som jeg mente. Jeg har dog lige en ting, så jeg godt kunne tænke mig at få tilføjet scriptet.

Kan man tilføje en log-fil over det finder som bliver kopieret (også gerne dem som ikke bliver)? Jeg har prøvet at køre med outlook åben samt word. Når jeg så kører dit script, kopiere det alle filerne, men undtagen de filer som er i brug. Den skriver det også i cmd´en at filerne er i brug.

Kan man lave en log-fil, som viser det samme som bliver vist/skrevet i cmd´en?

Prøv dette:

@echo off
@echo Kopierings log %date% %time%>H:\Kopiering.txt
@echo. >>H:\Kopiering.txt
@goto start
@Skriv dine bruger navne herunder (i stedet for Anders And og Fedtmule)
Anders And
Fedtmule

@:start
@for /f "eol=@ delims=" %%a in (%~sf0) do (
@echo Kopierer filer for %%a >>H:\Kopiering.txt
@echo. >>H:\Kopiering.txt
@xcopy "C:\Documents and Settings\%%a\Lokale indstillinger\Application Data\Microsoft\Outlook" "H:\Documents and Settings\%%a\Lokale indstillinger\Application Data\Microsoft\Outlook" /s /e /h /k /o /y /i >>H:\Kopiering.txt
@xcopy "C:\Documents and Settings\%%a\Foretrukne" "H:\Documents and Settings\%%a\Foretrukne" /s /e /h /k /o /y /i >>H:\Kopiering.txt
@xcopy "C:\Documents and Settings\%%a\Dokumenter" "H:\Documents and Settings\%%a\Dokumenter" /s /e /h /k /o /y /i >>H:\Kopiering.txt
@xcopy "C:\Documents and Settings\%%a\Application Data\Microsoft\Address Book" "H:\Documents and Settings\%%a\Application Data\Microsoft\Address Book" /s /e /h /k /o /y /i >>H:\Kopiering.txt
@echo. >>H:\Kopiering.txt )
@start notepad H:\Kopiering.txt

Jeg har lige prøvet det nye script. Fedt at den selv åbner log-filen til sidst.

Det er også godt nok, at den viser hvor mange filer der er kopieret (også dem med 0 filer).

Kan man ikke lave det sådan, at den også skriver hvorfor filen ikke blev kopieret f.eks. filen blev ikke fundet eller filen er i brug.

Hermed er der kommet ekstra 30 point til spørgsmålet

Så bliver det ikke bedre.


@echo off
@echo Kopierings log %date% %time%>H:\Kopiering.txt
@echo. >>H:\Kopiering.txt
@goto start
@Skriv dine bruger navne herunder (i stedet for Anders And og Fedtmule)
Anders And
Fedtmule

@:start
@for /f "eol=@ delims=" %%a in (%~sf0) do (
@echo Kopierer filer for %%a >>H:\Kopiering.txt
@echo. >>H:\Kopiering.txt
@xcopy "C:\Documents and Settings\%%a\Lokale indstillinger\Application Data\Microsoft\Outlook" "H:\Documents and Settings\%%a\Lokale indstillinger\Application Data\Microsoft\Outlook" /s/e/h/k/y/i/f/r >>H:\Kopiering.txt
@xcopy "C:\Documents and Settings\%%a\Foretrukne" "H:\Documents and Settings\%%a\Foretrukne" /s/e /h/k/y/i/f/r >>H:\Kopiering.txt
@xcopy "C:\Documents and Settings\%%a\Dokumenter" "H:\Documents and Settings\%%a\Dokumenter" /s/e/h/k/y/i/f/r >>H:\Kopiering.txt
@xcopy "C:\Documents and Settings\%%a\Application Data\Microsoft\Address Book" "H:\Documents and Settings\%%a\Application Data\Microsoft\Address Book" /s/e/h/k/y/i/f/r >>H:\Kopiering.txt
@echo. >>H:\Kopiering.txt )
@start notepad H:\Kopiering.txt

Hvad er det du lavet på det sidste script? Kan ikke lige selv se forskelligen.

Jeg kan også sagtens bruge dette script. Det er fedt at man kan kopiere for alle brugere på en gang.

Jeg forstår bare ikke hvorfor, at log-filen kun skriver de filer som er kopieret og skriver "0 fil(er) kopieret", der hvor der ikke er kopieret noget.

I cmd´en skriver den jo enten "filen er i brug" eller "filen blev ikke fundet". Kan man ikke overføre det til log-filen?

Ellers vil jeg bare sige mange gange tak for hjælpen :-). Prøver lige at høre, hvad cyberfessor har fundet ud af inden jeg lukket spørgsmålet.

"I cmd´en skriver den jo enten "filen er i brug" eller "filen blev ikke fundet". Kan man ikke overføre det til log-filen?"

Det kan man ikke umidelbart, kræver en del programering.

Jeg har ændret på svitch'ne for at få et større indput til log filen.

Jeg kan godt se nu, at du har ændret nogle switch.

"Det kan man ikke umidelbart, kræver en del programering."

Den programmering der skal til, er det noget du kan? Hvis ja, så opretter jeg det under et nyt spørgsmål.

Ok nu tror jeg den er som du vil ha'.

@echo off
@echo Kopierings log %date% %time%>H:\Kopiering.txt
@echo. >>H:\Kopiering.txt
@goto start
@Skriv dine bruger navne herunder (i stedet for Anders And og Fedtmule)
Anders And
Fedtmule

@:start
@for /f "eol=@ delims=" %%a in (%~sf0) do (
@echo Kopierer filer for %%a >>H:\Kopiering.txt
@echo. >>H:\Kopiering.txt
@xcopy "C:\Documents and Settings\%%a\Lokale indstillinger\Application Data\Microsoft\Outlook" "H:\Documents and Settings\%%a\Lokale indstillinger\Application Data\Microsoft\Outlook" /s/e/h/k/y/i/f/r/o/c >>H:\Kopiering.txt 2>&1
@xcopy "C:\Documents and Settings\%%a\Foretrukne" "H:\Documents and Settings\%%a\Foretrukne" /s/e /h/k/y/i/f/r/o/c >>H:\Kopiering.txt 2>&1
@xcopy "C:\Documents and Settings\%%a\Dokumenter" "H:\Documents and Settings\%%a\Dokumenter" /s/e/h/k/y/i/f/r/o/c >>H:\Kopiering.txt 2>&1
@xcopy "C:\Documents and Settings\%%a\Application Data\Microsoft\Address Book" "H:\Documents and Settings\%%a\Application Data\Microsoft\Address Book" /s/e/h/k/y/i/f/r/o/c >>H:\Kopiering.txt 2>&1
@echo. >>H:\Kopiering.txt )
@start notepad H:\Kopiering.txt


Det ender med at jeg bliver rigtig god til CMD script.
:-)

Perfekt :-) Nu kører det bare som det skal!! Kan helt klart bruge det du har lavet. Hvad er det du har gjort, så fejlmeddelsen kommer med i log-filen?

Så spørgsmplet kan snart lukkes, men vil lige høre, hvad cyberfessor havde af bud på en løsning.

2400nv>> hehe.. der er sket lidt siden jeg sidst kigge ind :)

ser fint ud hvad du har fået lavet her... eneste "ulempe" er jo at den ikke er vildt dynamisk, på den måde at du skal til at tilføje navne hvis der er kommer flere brugere på maskinen... men det betyder nok ikke det store i dit tilfælde :)

ang mit script var jeg vist lige hurtig nok med koden... det skal selvfølgelig være

MsgBox("starting script...")
Set ObjDomain = GetObject("WinNT://nicolai")
Set wsh = Server.CreateObject("WScript.Shell")

For each object in ObjDomain ' Look at each object
If object.class = "User" Then

wsh.Run("fil.bat "& object.name)

End If
Next

det kan endda gøres helt uden brug af en batfil:

MsgBox("starting script...")
Set ObjDomain = GetObject("WinNT://nicolai")
Set wsh = Server.CreateObject("WScript.Shell")

For each object in ObjDomain ' Look at each object
If object.class = "User" Then

MsgBox("Kopierer data for "& object.name)
wsh.Run("xcopy C:\Documents and Settings\"& object.name &"\Lokale indstillinger\Application Data\Microsoft\Outlook H:\Documents and Settings\"& object.name &"\Lokale indstillinger\Application Data\Microsoft\Outlook /s/e/h/k/y/i/f/r/o/c > H:\Kopiering.txt")
wsh.Run("xcopy "C:\Documents and Settings\"& object.name &"\Foretrukne H:\Documents and Settings\"& object.name &"\Foretrukne /s/e/h/k/y/i/f/r/o/c > H:\Kopiering.txt")
wsh.Run("xcopy "C:\Documents and Settings\"& object.name &"\Dokumenter H:\Documents and Settings\"& object.name &"\Dokumenter /s/e/h/k/y/i/f/r/o/c > H:\Kopiering.txt")
wsh.Run("xcopy "C:\Documents and Settings\"& object.name &"\Application Data\Microsoft\Address Book H:\Documents and Settings\"& object.name &"\Application Data\Microsoft\Address Book /s/e/h/k/y/i/f/r/o/c >>H:\Kopiering.txt")

End If
Next

wsh.Run("notepad h:\Kopiering.txt")

der kom tre "'er for meget med..

MsgBox("starting script...")
Set ObjDomain = GetObject("WinNT://nicolai")
Set wsh = Server.CreateObject("WScript.Shell")

For each object in ObjDomain ' Look at each object
If object.class = "User" Then

MsgBox("Kopierer data for "& object.name)
wsh.Run("xcopy C:\Documents and Settings\"& object.name &"\Lokale indstillinger\Application Data\Microsoft\Outlook H:\Documents and Settings\"& object.name &"\Lokale indstillinger\Application Data\Microsoft\Outlook /s/e/h/k/y/i/f/r/o/c > H:\Kopiering.txt")
wsh.Run("xcopy C:\Documents and Settings\"& object.name &"\Foretrukne H:\Documents and Settings\"& object.name &"\Foretrukne /s/e/h/k/y/i/f/r/o/c > H:\Kopiering.txt")
wsh.Run("xcopy C:\Documents and Settings\"& object.name &"\Dokumenter H:\Documents and Settings\"& object.name &"\Dokumenter /s/e/h/k/y/i/f/r/o/c > H:\Kopiering.txt")
wsh.Run("xcopy C:\Documents and Settings\"& object.name &"\Application Data\Microsoft\Address Book H:\Documents and Settings\"& object.name &"\Application Data\Microsoft\Address Book /s/e/h/k/y/i/f/r/o/c >>H:\Kopiering.txt")

End If
Next

wsh.Run("notepad h:\Kopiering.txt")

Her er en version der selv finder brugerne.
Den tager dog "All Users" og "Default User" med.


@echo off
echo Kopierings log %date% %time%>H:\Kopiering.txt
echo. >>H:\Kopiering.txt
for /f "delims=" %%a in ('dir /A:D/Q/B "C:\Documents and Settings/"') do (
echo Kopierer filer for %%a >>H:\Kopiering.txt
echo. >>H:\Kopiering.txt
xcopy "C:\Documents and Settings\%%a\Lokale indstillinger\Application Data\Microsoft\Outlook" "H:\Documents and Settings\%%a\Lokale indstillinger\Application Data\Microsoft\Outlook" /s/e/h/k/y/i/f/r/o/c >>H:\Kopiering.txt 2>&1
xcopy "C:\Documents and Settings\%%a\Foretrukne" "H:\Documents and Settings\%%a\Foretrukne" /s/e /h/k/y/i/f/r/o/c >>H:\Kopiering.txt 2>&1
xcopy "C:\Documents and Settings\%%a\Dokumenter" "H:\Documents and Settings\%%a\Dokumenter" /s/e/h/k/y/i/f/r/o/c >>H:\Kopiering.txt 2>&1
xcopy "C:\Documents and Settings\%%a\Application Data\Microsoft\Address Book" "H:\Documents and Settings\%%a\Application Data\Microsoft\Address Book" /s/e/h/k/y/i/f/r/o/c >>H:\Kopiering.txt 2>&1
echo. >>H:\Kopiering.txt )
start notepad H:\Kopiering.txt

:-)

tpo>> du er stædig med det gamle dos-scripting-ting, hva' ? ;)

cyberfessor<<jeg har kørt vbs-filen. Den starter fint nok, men der kommer en fejlmeddelse: Linje 3, Tegn 1, Fejl: Et objekt er obligatorisk: 'Server'.

MsgBox("starting script...")
Set ObjDomain = GetObject("WinNT://nicolai")
Set wsh = Server.CreateObject("WScript.Shell")

For each object in ObjDomain ' Look at each object
If object.class = "User" Then

MsgBox("Kopierer data for "& object.name)
wsh.Run("xcopy C:\Documents and Settings\"& object.name &"\Lokale indstillinger\Application Data\Microsoft\Outlook H:\Documents and Settings\"& object.name &"\Lokale indstillinger\Application Data\Microsoft\Outlook /s/e/h/k/y/i/f/r/o/c > H:\Kopiering.txt")
wsh.Run("xcopy C:\Documents and Settings\"& object.name &"\Foretrukne H:\Documents and Settings\"& object.name &"\Foretrukne /s/e/h/k/y/i/f/r/o/c > H:\Kopiering.txt")
wsh.Run("xcopy C:\Documents and Settings\"& object.name &"\Dokumenter H:\Documents and Settings\"& object.name &"\Dokumenter /s/e/h/k/y/i/f/r/o/c > H:\Kopiering.txt")
wsh.Run("xcopy C:\Documents and Settings\"& object.name &"\Application Data\Microsoft\Address Book H:\Documents and Settings\"& object.name &"\Application Data\Microsoft\Address Book /s/e/h/k/y/i/f/r/o/c >>H:\Kopiering.txt")

End If
Next

wsh.Run("notepad h:\Kopiering.txt")

tpo<<Kanon fedt, nu kører det bare :-). Kan du ikke lige forklare, hvordan scriptet virker (hvad der gør hvad)? Hvis jeg rette i scriptet, kan jeg så få det til at køre modsatte vej (h: til c:)?

Hvad ligger der i "All Users" og "Default User"? Er der nogle grund til at de bliver kopieret med over? Hvis det ikke er et for stort arbejde må du gerne lave en version, som ikke medtager "All Users" og "Default User".

Jeg er rigtigt glad for det sidste script, der selv finder alle brugerne og kopiere dem over på et andet drev.

Din version af W2K er vist på dansk? Om det er "All Users" og "Default User" på en dansk version er jeg ikke klar over. Kommer de med i logfilen?

Her er en version der "kører begge veje" og udelader "All Users" og "Default User"


@echo off

:Menu
cls
echo.
echo            - MENU -
echo.
echo  1 = Backup.
echo  2 = Restore.
echo.
set /p valg= Indtast dit valg og tast Enter:

echo.

if {%valg%}=={1} goto Backup
if {%valg%}=={2} goto Restore

goto Menu

:Backup
set FraDrev=C:\
set Tildrev=H:\
set LogTxt=Backup log: %date% %time%
set logFile=%Tildrev%BackupLog.txt
echo.
echo  Backup.
goto Start

:Restore
set FraDrev=H:\
set Tildrev=C:\
set LogTxt=Restore log: %date% %time%
set logFile=%FraDrev%RestoreLog.txt
echo  Restore.
goto Start

:Start
set Udelad=All Users Default User

echo %LogTxt% > %logFile%
echo. >>%logFile%

for /f "delims=" %%a in ('dir /A:D/B "%FraDrev%Documents and Settings/"') do (
  echo  %Udelad% | find "%%a" >nul
  if errorlevel 1 (
    echo Kopierer filer fra %FraDrev% til %Tildrev% for %%a >>%logFile%
    echo. >>%logFile%
    xcopy "%FraDrev%Documents and Settings\%%a\Lokale indstillinger\Application Data\Microsoft\Outlook" "%TilDrev%Documents and Settings\%%a\Lokale indstillinger\Application Data\Microsoft\Outlook" /s/e/h/k/y/i/f/r/o/c >>%logFile% 2>&1
    xcopy "%FraDrev%Documents and Settings\%%a\Foretrukne" "%TilDrev%Documents and Settings\%%a\Foretrukne" /s/e /h/k/y/i/f/r/o/c >>%logFile% 2>&1
    xcopy "%FraDrev%Documents and Settings\%%a\Dokumenter" "%TilDrev%Documents and Settings\%%a\Dokumenter" /s/e/h/k/y/i/f/r/o/c >>%logFile% 2>&1
    xcopy "%FraDrev%Documents and Settings\%%a\Application Data\Microsoft\Address Book" "%TilDrev%Documents and Settings\%%a\Application Data\Microsoft\Address Book" /s/e/h/k/y/i/f/r/o/c >>%logFile% 2>&1
    echo. >>%logFile%
  )
)

start notepad %logFile%


God fornøjelse!

2400nv>> det hedder bare CreateObject og ikke Server.CreateObject

Cyberfessor<<Det driller stadigvæk. Fejl i linje 3, Tegn 1, Fejl: Antallet af argumenter er forkert eller egenskabstildelingen er ugyldig:'wsh'

MsgBox("starting script...")
Set ObjDomain = GetObject("WinNT://nicolai")
Set wsh = CreateObject("WScript.Shell")

For each object in ObjDomain ' Look at each object
If object.class = "User" Then

MsgBox("Kopierer data for "& object.name)
wsh.Run("xcopy C:\Documents and Settings\"& object.name &"\Lokale indstillinger\Application Data\Microsoft\Outlook H:\Documents and Settings\"& object.name &"\Lokale indstillinger\Application Data\Microsoft\Outlook /s/e/h/k/y/i/f/r/o/c > H:\Kopiering.txt")
wsh.Run("xcopy C:\Documents and Settings\"& object.name &"\Foretrukne H:\Documents and Settings\"& object.name &"\Foretrukne /s/e/h/k/y/i/f/r/o/c > H:\Kopiering.txt")
wsh.Run("xcopy C:\Documents and Settings\"& object.name &"\Dokumenter H:\Documents and Settings\"& object.name &"\Dokumenter /s/e/h/k/y/i/f/r/o/c > H:\Kopiering.txt")
wsh.Run("xcopy C:\Documents and Settings\"& object.name &"\Application Data\Microsoft\Address Book H:\Documents and Settings\"& object.name &"\Application Data\Microsoft\Address Book /s/e/h/k/y/i/f/r/o/c >>H:\Kopiering.txt")

End If
Next

wsh.Run("notepad h:\Kopiering.txt")

tpo<< Det kører fint. På log-filen kommer alle bruger med undtagen "All Users" og "Default User". Det er jo sådan som det skal være.

Jeg tror, jeg må sige at opgaven er løst. Jeg har dog en lille opgave til, men jeg opretter lige et nyt spørgsmål på det.

Link til det nye spørgsmål:
http://www.eksperten.dk/spm/331192

2400nv>> jeg giver op.. hehe... det virker ellers fint på min maskine...
prøv at erstat alle wsh'erne med w'er... men nok om det... tpo's løsning er mindst lige så god :)

>cyberfessor
Hvilket OS har du? Dine scripts kører heller ikke på min W2K Pro SP3.

Hvis jeg ændrer det sådan her, kører det fint, det kopierer bare ikke noget.

MsgBox("starting script...")
Set ObjDomain = GetObject("WinNT://MinMaskine")
Set objShell = WScript.CreateObject("WScript.Shell")

For each object in ObjDomain ' Look at each object
If object.class = "User" Then

MsgBox("Kopierer data for "& object.name)
objShell.Run("xcopy C:\Documents and Settings\"& object.name &"\Lokale indstillinger\Application Data\Microsoft\Outlook H:\Documents and Settings\"& object.name &"\Lokale indstillinger\Application Data\Microsoft\Outlook /s/e/h/k/y/i/f/r/o/c"),0
objShell.Run("xcopy C:\Documents and Settings\"& object.name &"\Foretrukne H:\Documents and Settings\"& object.name &"\Foretrukne /s/e/h/k/y/i/f/r/o/c"),0
objShell.Run("xcopy C:\Documents and Settings\"& object.name &"\Dokumenter H:\Documents and Settings\"& object.name &"\Dokumenter /s/e/h/k/y/i/f/r/o/c"),0
objShell.Run("xcopy C:\Documents and Settings\"& object.name &"\Application Data\Microsoft\Address Book H:\Documents and Settings\"& object.name &"\Application Data\Microsoft\Address Book /s/e/h/k/y/i/f/r/o/c"),0

End If
Next

objShell.Run("notepad h:\Kopiering.txt")

tpo>> winXP... dog har jeg glemt at sætte stierne i anførselstegn... hehe..., så mon ikke det var derfor den ikke kopiere noget ? :)

ja, jeg indrømmer det.. jeg er ikke nogen xcopy-mand ;)

cyberfessor<< Nu kører dit script, men det kopiere bare ikke :-( Er det noget med nogle anførelstegn?

Kan I ikke kort forklare, hvor jeres script er bygget op og hvordan det virker. Meget gerne hvordan I fik log-filen til at indholde; de filer som blev kopieret og dem, hvor der opstod fejl.

efter at jeg satte "" omkring stierne... altså

xcopy "C:\Documents and Settings\"& object.name &"\Lokale indstillinger\Application Data\Microsoft\Outlook" H:\Documents and Settings\"& object.name &"\Lokale indstillinger\Application Data\Microsoft\Outlook" /s/e/h/k/y/i/f/r/o/c"),0

virkede det fint hos mig

Tag et kik i Windows Help!

mit script er lavet i VBS, og gør såmend ikke andet, end at vi først henter alle objecterne fra din computer, derefter løbe vi dem igennem, og hvis vi kommer til en bruger henter vi navnet for denne bruger, og starter xcopy med de rigtige parametre :)

cyberfessor<<Hvis dit script virker nu, kan du ikke lige ligge hele scriptet på siden her!.

Set ObjDomain = GetObject("WinNT://Mouse")
Set objShell = WScript.CreateObject("WScript.Shell")

For each object in ObjDomain ' Look at each object
If object.class = "User" Then

objShell.Run("xcopy ""c:\"& object.name &""" ""e:\"& object.name &""" /s/e/h/k/y/i/f/r/o/c")

End If
Next

Hvorfor ser scriptet ikke ud som det gjorde: 20/03-2003 15:20:08 ? Mangler der ikke noget?

Hej 2400nv

Jeg har forbedret scriptet en smule, god fornøjelse.


@echo off
set PassOver=All Users Default User
:MainMenu
  cls
  set ValidChoice=SBR
  set Choice=
  echo.
  echo    - Hoved menu -
  echo.
  echo  S = Slut
  echo  B = Backup
  echo  R = Restore
  echo.
  set /p Choice=Indtast dit Valg:
  if {%Choice%}=={} goto MainMenu
  call set Test=%%ValidChoice:%Choice:~0,1%=%%
  if "%Test%" EQU "%ValidChoice%" goto MainMenu
goto MainChoice-%Choice:~0,1%

:MainChoice-S
goto :EOF

:MainChoice-B
  call :UniversalDate
  set Task=Backup
  set FromDrive=C:\
  set ToDrive=H:\
  set LogTxt=%Task% log: %dd%-%mm%-%yy% %time%
  set logFile=%ToDrive%%Task%.txt
goto :SubMenu

:MainChoice-R
  call :UniversalDate
  set Task=Restore
  set FromDrive=H:\
  set ToDrive=C:\
  set LogTxt=%Task% log: %dd%-%mm%-%yy% %time%
  set logFile=%ToDrive%%Task%.txt
goto :SubMenu

:SubMenu
  cls
  set ValidChoice=SHA
  set Choice=
  set /a Counter=0
  echo.
  echo    - %Task% menu -
  echo.
  echo  S = Slut
  echo  H = Hoved menu
  echo  A = Alle brugere
  for /f "delims=" %%a in ('dir /A:D/B "%FromDrive%Documents and Settings/"') do (
    echo  %PassOver% | find "%%a" >nul
    if errorlevel 1 call :WriteSubMenu "%%a"
  )
  echo.
  set /p Choice=Indtast dit Valg:
  if {%Choice%}=={} goto SubMenu
  call set Test=%%ValidChoice:%Choice%=%%
  if "%Test%" EQU "%ValidChoice%" goto SubMenu
  if "%Choice:~0,1%" GTR "9" goto SubChoice-%Choice:~0,1%
  call :FindUser %Choice%
goto SubMenu

:SubChoice-H
goto :MainMenu

:SubChoice-S
goto :EOF

:SubChoice-A
  call :CopyAllUsers
goto :SubMenu

:WriteSubMenu
  set /a Counter+=1
  set Name=%1
  echo  %Counter% = %Name:"=%
  set ValidChoice=%ValidChoice%%Counter%
goto :EOF

:FindUser
  set /a Counter=0
  for /f "delims=" %%a in ('dir /A:D/B "%FromDrive%Documents and Settings/"') do (
    echo  %PassOver% | find "%%a" >nul
    if errorlevel 1 call :CopyUser %1 "%%a"
  )
goto :EOF

:CopyUser
  set User=%2
  set User=%User:"=%
  set /a Counter+=1
  if %Counter% EQU %1 (
    cls
    echo.
    echo Starter %Task% af "%User%".
    echo.
    echo Tast Ctrl+c for at afbryde.
    echo %LogTxt% > %logFile%
    echo. >>%logFile%
    echo Kopierer filer fra %FromDrive% til %ToDrive% for %User% >>%logFile%
    echo. >>%logFile%
    xcopy "%FromDrive%Documents and Settings\%User%\Lokale indstillinger\Application Data\Microsoft\Outlook" "%ToDrive%Documents and Settings\%User%\Lokale indstillinger\Application Data\Microsoft\Outlook" /s/e/h/k/y/i/f/r/o/c >>%logFile% 2>&1
    xcopy "%FromDrive%Documents and Settings\%User%\Foretrukne" "%ToDrive%Documents and Settings\%User%\Foretrukne" /s/e /h/k/y/i/f/r/o/c >>%logFile% 2>&1
    xcopy "%FromDrive%Documents and Settings\%User%\Dokumenter" "%ToDrive%Documents and Settings\%User%\Dokumenter" /s/e/h/k/y/i/f/r/o/c >>%logFile% 2>&1
    xcopy "%FromDrive%Documents and Settings\%User%\Application Data\Microsoft\Address Book" "%ToDrive%Documents and Settings\%User%\Application Data\Microsoft\Address Book" /s/e/h/k/y/i/f/r/o/c >>%logFile% 2>&1
    echo. >>%logFile%
    cls
    echo.
    echo Færdig, tryk på en tast!
    pause >nul
    start Notepad %logFile%
  )
goto :EOF

:CopyAllUsers
  cls
  echo.
  echo Starter %Task% af "Alle brugere".
  echo.
  echo Tast Ctrl+c for at afbryde.
  echo %LogTxt% > %logFile%
  echo. >>%logFile%
  for /f "delims=" %%a in ('dir /A:D/B "%FromDrive%Documents and Settings/"') do (
    echo  %PassOver% | find "%%a" >nul
    if errorlevel 1 (
      echo Kopierer filer fra %FromDrive% til %ToDrive% for %%a >>%logFile%
      echo. >>%logFile%
      xcopy "%FromDrive%Documents and Settings\%%a\Lokale indstillinger\Application Data\Microsoft\Outlook" "%ToDrive%Documents and Settings\%%a\Lokale indstillinger\Application Data\Microsoft\Outlook" /s/e/h/k/y/i/f/r/o/c >>%logFile% 2>&1
      xcopy "%FromDrive%Documents and Settings\%%a\Foretrukne" "%ToDrive%Documents and Settings\%%a\Foretrukne" /s/e /h/k/y/i/f/r/o/c >>%logFile% 2>&1
      xcopy "%FromDrive%Documents and Settings\%%a\Dokumenter" "%ToDrive%Documents and Settings\%%a\Dokumenter" /s/e/h/k/y/i/f/r/o/c >>%logFile% 2>&1
      xcopy "%FromDrive%Documents and Settings\%%a\Application Data\Microsoft\Address Book" "%ToDrive%Documents and Settings\%%a\Application Data\Microsoft\Address Book" /s/e/h/k/y/i/f/r/o/c >>%logFile% 2>&1
      echo. >>%logFile%
    )
  )
  cls
  echo.
  echo Færdig, tryk på en tast!
  pause >nul
  start Notepad %logFile%
goto :EOF

:UniversalDate
  set $tok=1-3
  for /f "tokens=1 delims=.:/-, " %%u in ('date /t') do set $d1=%%u
  if "%$d1:~0,1%" GTR "9" set $tok=2-4
  for /f "tokens=%$tok% delims=.:/-, " %%u in ('date /t') do (
    for /f "skip=1 tokens=2-4 delims=/-,()." %%x in ('echo.^|date') do (
      set %%x=%%u
      set %%y=%%v
      set %%z=%%w
      set $d1=
      set $tok=
    )
  )
goto :EOF

2400nv>> måske fordi at jeg går ud fra at du trods alt har lært en smule efterhånden og selv kan rette det til så det kopierer de ting du skal have kopieret ;)

Lukketid!

Nu har jeg prøvet flere gange, men det kopiere ikke noget, ellers kører det fint nok. Jeg har også W2K Pro SP3. Ellers er det også ved at være lukketid:-)

MsgBox("starting script...")
Set ObjDomain = GetObject("WinNT://nicolai")
Set objShell = WScript.CreateObject("WScript.Shell")

For each object in ObjDomain ' Look at each object
If object.class = "User" Then

MsgBox("Kopierer data for "& object.name)
objShell.Run("xcopy ""C:\Documents and Settings\"& object.name &"\Lokale indstillinger\Application Data\Microsoft\Outlook"" ""H:\Documents and Settings\"& object.name &"\Lokale indstillinger\Application Data\Microsoft\Outlook"" /s/e/h/k/y/i/f/r/o/c"),0
objShell.Run("xcopy ""C:\Documents and Settings\"& object.name &"\Foretrukne"" ""H:\Documents and Settings\"& object.name &"\Foretrukne"" /s/e/h/k/y/i/f/r/o/c"),0
objShell.Run("xcopy ""C:\Documents and Settings\"& object.name &"\Dokumenter"" ""H:\Documents and Settings\"& object.name &"\Dokumenter"" /s/e/h/k/y/i/f/r/o/c"),0
objShell.Run("xcopy ""C:\Documents and Settings\"& object.name &"\Application Data\Microsoft\Address Book"" ""H:\Documents and Settings\"& object.name &"\Application Data\Microsoft\Address Book"" /s/e/h/k/y/i/f/r/o/c"),0

End If
Next

objShell.Run("notepad h:\Kopiering.txt")

Har lige ændret spørgsmålet til 100 point. Hvis cyberfessor vil have nogle point, må du lige lave et svar.

2400nv>> giv du dem bare til tpo... det lader til at der har været lidt for meget bøvl med mit script til at det er point værdigt ;)

cyberfessor>> Er vi ikke lige ved at have den. Kan du ikke lige prøve at se om der er noget i vejen med scriptet: 22/03-2003 22:29:07

Der er point til jer begge 2!!

nu har jeg prøvet at udføre dette script

MsgBox("starting script...")
Set ObjDomain = GetObject("WinNT://Mouse")
Set objShell = WScript.CreateObject("WScript.Shell")
Set fso = CreateObject("Scripting.FileSystemObject")

fso.CreateTextFile("C:\backup.txt")
Set file = fso.OpenTextFile("C:\backup.txt", 2)

For each object in ObjDomain ' Look at each object
If object.class = "User" Then

MsgBox("Kopierer data for "& object.name)

strExecute = "xcopy ""C:\Documents and Settings\"& object.name &"\Lokale indstillinger\Application Data\Microsoft\Outlook"" ""H:\Documents and Settings\"& object.name &"\Lokale indstillinger\Application Data\Microsoft\Outlook"" /s/e/h/k/y/i/f/r/o/c"
file.WriteLine(strExecute)
'objShell.Run(strExecute)

strExecute = "xcopy ""C:\Documents and Settings\"& object.name &"\Foretrukne"" ""H:\Documents and Settings\"& object.name &"\Foretrukne"" /s/e/h/k/y/i/f/r/o/c"
file.WriteLine(strExecute)
'objShell.Run(strExecute)

strExecute = "xcopy ""C:\Documents and Settings\"& object.name &"\Dokumenter"" ""H:\Documents and Settings\"& object.name &"\Dokumenter"" /s/e/h/k/y/i/f/r/o/c"
file.WriteLine(strExecute)
'objShell.Run(strExecute)

strExecute = "xcopy ""C:\Documents and Settings\"& object.name &"\Application Data\Microsoft\Address Book"" ""H:\Documents and Settings\"& object.name &"\Application Data\Microsoft\Address Book"" /s/e/h/k/y/i/f/r/o/c"
file.WriteLine(strExecute)
'objShell.Run(strExecute)

End If
Next

og ved at åbne c:\backup.txt ser jeg dette indhold

xcopy "C:\Documents and Settings\Administrator\Lokale indstillinger\Application Data\Microsoft\Outlook" "H:\Documents and Settings\Administrator\Lokale indstillinger\Application Data\Microsoft\Outlook" /s/e/h/k/y/i/f/r/o/c
xcopy "C:\Documents and Settings\Administrator\Foretrukne" "H:\Documents and Settings\Administrator\Foretrukne" /s/e/h/k/y/i/f/r/o/c
xcopy "C:\Documents and Settings\Administrator\Dokumenter" "H:\Documents and Settings\Administrator\Dokumenter" /s/e/h/k/y/i/f/r/o/c
xcopy "C:\Documents and Settings\Administrator\Application Data\Microsoft\Address Book" "H:\Documents and Settings\Administrator\Application Data\Microsoft\Address Book" /s/e/h/k/y/i/f/r/o/c
xcopy "C:\Documents and Settings\Guest\Lokale indstillinger\Application Data\Microsoft\Outlook" "H:\Documents and Settings\Guest\Lokale indstillinger\Application Data\Microsoft\Outlook" /s/e/h/k/y/i/f/r/o/c
xcopy "C:\Documents and Settings\Guest\Foretrukne" "H:\Documents and Settings\Guest\Foretrukne" /s/e/h/k/y/i/f/r/o/c
xcopy "C:\Documents and Settings\Guest\Dokumenter" "H:\Documents and Settings\Guest\Dokumenter" /s/e/h/k/y/i/f/r/o/c
xcopy "C:\Documents and Settings\Guest\Application Data\Microsoft\Address Book" "H:\Documents and Settings\Guest\Application Data\Microsoft\Address Book" /s/e/h/k/y/i/f/r/o/c
xcopy "C:\Documents and Settings\Jesus Freak\Lokale indstillinger\Application Data\Microsoft\Outlook" "H:\Documents and Settings\Jesus Freak\Lokale indstillinger\Application Data\Microsoft\Outlook" /s/e/h/k/y/i/f/r/o/c
xcopy "C:\Documents and Settings\Jesus Freak\Foretrukne" "H:\Documents and Settings\Jesus Freak\Foretrukne" /s/e/h/k/y/i/f/r/o/c
xcopy "C:\Documents and Settings\Jesus Freak\Dokumenter" "H:\Documents and Settings\Jesus Freak\Dokumenter" /s/e/h/k/y/i/f/r/o/c
xcopy "C:\Documents and Settings\Jesus Freak\Application Data\Microsoft\Address Book" "H:\Documents and Settings\Jesus Freak\Application Data\Microsoft\Address Book" /s/e/h/k/y/i/f/r/o/c
xcopy "C:\Documents and Settings\SQLDebugger\Lokale indstillinger\Application Data\Microsoft\Outlook" "H:\Documents and Settings\SQLDebugger\Lokale indstillinger\Application Data\Microsoft\Outlook" /s/e/h/k/y/i/f/r/o/c
xcopy "C:\Documents and Settings\SQLDebugger\Foretrukne" "H:\Documents and Settings\SQLDebugger\Foretrukne" /s/e/h/k/y/i/f/r/o/c
xcopy "C:\Documents and Settings\SQLDebugger\Dokumenter" "H:\Documents and Settings\SQLDebugger\Dokumenter" /s/e/h/k/y/i/f/r/o/c
xcopy "C:\Documents and Settings\SQLDebugger\Application Data\Microsoft\Address Book" "H:\Documents and Settings\SQLDebugger\Application Data\Microsoft\Address Book" /s/e/h/k/y/i/f/r/o/c
xcopy "C:\Documents and Settings\Temp\Lokale indstillinger\Application Data\Microsoft\Outlook" "H:\Documents and Settings\Temp\Lokale indstillinger\Application Data\Microsoft\Outlook" /s/e/h/k/y/i/f/r/o/c
xcopy "C:\Documents and Settings\Temp\Foretrukne" "H:\Documents and Settings\Temp\Foretrukne" /s/e/h/k/y/i/f/r/o/c
xcopy "C:\Documents and Settings\Temp\Dokumenter" "H:\Documents and Settings\Temp\Dokumenter" /s/e/h/k/y/i/f/r/o/c
xcopy "C:\Documents and Settings\Temp\Application Data\Microsoft\Address Book" "H:\Documents and Settings\Temp\Application Data\Microsoft\Address Book" /s/e/h/k/y/i/f/r/o/c


Jeg er ikke den store xcopy-nørd, men tpo må da kunne svare på om den ikke burde kopiere ? Hver linje svarer til den commando der vil blive udført hvis jeg ikke havde udkommenteret (') dem.

Takker mange gange for hjælpen. Kan I ikke lige her til sidst, fortælle mig, hvordan jeg laver en log-fil som viser det hele ved en simpel xcopy kommando?

xcopy FRA TIL >logfil.txt 2>&1

Jeg lige prøvet:
xcopy d:\ H:\ /s/e/h/k/y/i/f/r/o/c >logfil.txt 2>&1

Det virker fint!

:-)

Hvorfor kan scriptet ikke skrive "Færdig, tryk på en tast!" rigtigt? Er det med de danske bogstaver?

Du skal bruge komandoen: pause

xcopy d:\ H:\ /s/e/h/k/y/i/f/r/o/c >logfil.txt 2>&1
pause

Jeg har oprettet et nyt spørgsmål:

http://www.eksperten.dk/spm/389684

Jeg kunne godt tænke mig, at få tilføjet noget mere til vores script.