Kan man skrive fra asp til IIS 5.0

Du kan aflæse IP-adressen og du kan så have en liste af tilladte adresser. Afvis alle andre.
Du vil også kunne beskytte en side ved hjælp af ntfs-rettigheder.
En bruger vil så blive afkrævet et brugernavn og adgangskode for at komme videre.

Request.Servervariables("REMOTE_HOST")
Response.Write Request.ServerVariables("REMOTE_ADDR")

http://www.webmasterworld.com/forum47/41.htm
http://www.tconsult.com/developer/ip.asp
http://www.developerfusion.com/show/1626/
http://www.15seconds.com/issue/981104.htm

ja, det er muligt at connecte til IIS5.0 som serverObject.. og derved kan du styre den helt via ASP ..

Hvordan ?

Set objIIS = GetObject("IIS://localhost/W3SVC")
Set objServer = objIIS.Create("IIsWebServer",16)

Hvordan skal det se ud hvis man vil lave ip adgangs begrænsning ?

det kan du læse om her ; http://msdn.microsoft.com/library/en-us/iissdk/iis/ref_prog_iaorefiipsec.asp?frame=true

You can use the IPGrant property of the IIsIPSecurity (ADSI) object to edit lists of IP addresses, in an array, that are not allowed access to the server.


Syntax

SecObj. IPGrant = "IPAddress,SubnetMask"

varIPGrant = SecObj. IPGrant


Parameters


SecObj
An IIS ADSI Object of type IIsIPSecurity.
IPAddress
A specific IP address that you want to grant access to the server.
SubnetMask
The subnet mask for the specified IP address.

Code Example


<%


' Remember to enable Integrated Windows authentication and


' disable Anonymous Access, or you will get a Server 500 error.


Dim SecObj


Dim MyIPSec


Dim IPList


' Get the IIS object that holds the info for the default site.


' This could be any site root/vdir, or IIS://LocalHost/W3SVC for global


' properties.


Set SecObj = GetObject("IIS://LocalHost/W3SVC/1/Root")


' Get the IIsIPSecurity object.


Set MyIPSec = SecObj.IPSecurity


' Make sure GrantByDefault=FALSE or your changes will not count.


If (TRUE = MyIPSec.GrantByDefault) Then


Response.Write


"<BR>GrantByDefault was not FALSE. Setting to FALSE.<BR>"


MyIPSec.GrantByDefault = FALSE


End If


' Get the Grant list as an array, and add your newly allowed IP address


IPList = MyIPSec.IPGrant


Redim IPList (Ubound(IPList)+1)


IPList (Ubound(IPList)) = "123.0.0.1,255.255.255.0"


' Set the new lists back in the metabase in two stages, and then set


' the metabase.


MyIPSec.IPGrant = IPList


SecObj.IPSecurity = MyIPSec


SecObj.Setinfo


Response.Write "The IPRestriction has been set<BR>"


%>

Jeg får den her error

error '80070003'

Set SecObj = GetObject("IIS://LocalHost/W3SVC/1/Root")

Har det noget med den her at gøre ?

Du skal huske at ovenstående script skal køres som administrator på serveren og ik som almindelig IUSR

Set SecObj = GetObject("IIS://LocalHost/W3SVC/1/Root")

Den her varierer den - eller skal der stå som du har skrevet ?
Jeg kører som administrator.
Min min webside på computeren ligger under en folder som hedder web-bedsted.

' Get the IIS object that holds the info for the default site.
Hvor på serveren ligger det ? sti ?

kører du på en windows 2000 server ? .. eller noget andet ?

windows 2000 server

ok.. så skal du oprette et nyt website til denne side. . og det website skal du sætte til at logge ind med administrator i stedet for iusr

Den web side jeg har oprettet er oprettet med web side oprators: administrators

det er ik nok..

Du skal ind i properties, Directory security, EDIT anonumous access, Edit anonumous account, og der skal du taste administrator username og password

error '80070003'
i den her linie
Set SecObj = GetObject("IIS://LocalHost/W3SVC/1/Root")

ja, men det er fordi scriptet skal være administrator.. på den måde jeg forklarede,...

Jeg har gjort det
Du skal ind i properties, Directory security, EDIT anonumous access, Edit anonumous account, og der skal du taste administrator username og password
Men får fejlen
error '80070003'

prøv at fjerne "/root" så ..

gør ingen ændring

mærkeligt..

IIS://LocalHost/W3SVC/1/Root

Hvor ligger det her på computeren ?

tror det er lidt i stil med logfilen.. men tror det er en virtuel mappe

Set SecObj = GetObject("IIS://LocalHost/W3SVC/1/Root")
Jeg mener at serveren ikke er istand til at finde opjected ?

brug den øverste jeg skrev..

Ja Ok - Jeg er gået lidt død i den her ? -

Jeg mangler måske hvad der skal gøres helt fra bunden ?

prøv at gå ind på det link jeg skrev.. og læs om det..

det skulle gerne hjælpe lidt på det :-)

men hvorfor er det lige du vil kunne skrive ip halløjet der.. jeg mener er det ik hurtigere bare at gøre det i iis.. så er det klaret

Jeg har nu fået det til at køre fra asp koden - det var noget med rettigheder der
manglede - men hvordan hvis man har flere web sider kørende på samme server - hvor kan man sikre sig at det er den rigtige man skriver til ?

det er med det nummer efter w3svc

det er det der bestemmer hvad "site nummer" du skriver til ..

Hvor kan man se hvilke site nummer man er på ?

Hvor kan man hente hvilke site nummer man er på ?

du kan se det på logfilen.. den har nemlig samme nummer..

Hvad hedder logfilen ?

Hvordan skal koden se ud hvis man skal fjerne en ip ?

Set SecObj = GetObject("IIS://LocalHost/W3SVC/1/Root")
Set MyIPSec = SecObj.IPSecurity
If (FALSE = MyIPSec.GrantByDefault) Then
MyIPSec.GrantByDefault = TRUE
IPList = MyIPSec.IPDeny
Redim IPList (Ubound(IPList)+1)
IPList (Ubound(IPList)) = "I.P.NR.1,I.P.NR.2"
MyIPSec.IPDeny = IPList
SecObj.IPSecurity = MyIPSec
SecObj.Setinfo

Hvor ligger logfilen ? - Hvad hedder den ?

når du klikker egenskaber på det enkelte hotel, kan du se egenskaber for logfilen.. og der står nummeret i et eksempel..

Der ikke noget nummer i egenskaber for websitet ?

Hvordan får man nummeret fra websitet  returneret til  asp ?

det kan jeg ik lige huske men det kan du læse dig frem til på det microsoft link jeg sendte dig..

Jeg oplever at koden kun erstater den eksisterende ip - den skulle jo tilføje nye -
de som stod i forvejen skulle forblive urørt ?

' Remember to enable Integrated Windows authentication and
        ' disable Anonymous Access, or you will get a Server 500 error.

        Dim SecObj, MyIPSec, IPList

        ' Get the IIS object that holds the info for the default site.
        ' This could be any site root/vdir, or IIS://LocalHost/W3SVC for global
        ' properties.

        Set SecObj = GetObject("IIS://LocalHost/W3SVC/1/Root")

        ' Get the IIsIPSecurity object.

        Set MyIPSec = SecObj.IPSecurity

        ' Make sure GrantByDefault=FALSE or your changes will not count.

        If (TRUE = MyIPSec.GrantByDefault) Then
            MyIPSec.GrantByDefault = FALSE
        End If

        ' Get the Grant list as an array, and add your newly allowed IP address

        IPList = MyIPSec.IPGrant

        Redim IPList (Ubound(IPList)+1)

        IPList (Ubound(IPList)) = PrivateIP

        ' Set the new lists back in the metabase in two stages, and then set
        ' the metabase.

        MyIPSec.IPGrant = IPList
        SecObj.IPSecurity = MyIPSec
        SecObj.Setinfo

        Set SecObj = nothing
        Set MyIPSec = nothing

Ok.. det kan du jo så evt løse ved selv at have en liste over dem som skal tilføjes og så bare tilføje hele listen hver gang..

skal ik lige kunne sige hvorfor den gør det sådan da denne løsning skulle virke..

Hvordan får man udskrivet indholdet af IPList ?

IPList = MyIPSec.IPGrant

for t= 0 to ubound(IPList)
response.write "IP: "&IPList(t)&"<br>"
next

For at tilføje ser det ud til at man skal erstatte

Redim IPList (Ubound(IPList)+1)

med

Redim Preserve  IPList (Ubound(IPList)+1)

der kan man bare se.. har ik selv rodet med ip begrænsningen..

Hvordan får man nummeret fra websitet  returneret til  asp ? - jeg har ikke kunnet finde noget på det ?

det eneste jeg har der kan det.. er noget slamkode som jeg ik lige har fået rydtet op i endnu..

så det kan godt være det er lidt u-overskueligt..

computer="localhost"
webname="testsite.dk"
ArgComputers = Array("LocalHost")
ArgWebSites = webname
ArgNum = 0
for compIndex = 0 to UBound(ArgComputers)
    set foundSite = findWeb(ArgComputers(compIndex), ArgWebSites)
    if isObject(foundSite) then
        response.write "  Web Site Number = "&foundSite.Name
        response.write "  Web Site Description = "&foundSite.ServerComment
        aBinding=foundSite.ServerBindings
        if (IsArray(aBinding)) then
            if aBinding(0) = "" then
                binding = Null
            else
                binding = getBinding(aBinding(0))
            end if
        else
            if aBinding = "" then
                binding = Null
            else
                binding = getBinding(aBinding)
            end if
        end if
        if (IsArray(binding)) then
            response.write "    Hostname = "&binding(2)
            response.write "    Port = "&binding(1)
            response.write "    IP Address = "&binding(2)
        end if
    else
        Trace "No matching web found."
    end if
next
function getBinding(bindstr)

    Dim one, two, ia, ip, hn
   
    one=Instr(bindstr,":")
    two=Instr((one+1),bindstr,":")
   
    ia=Mid(bindstr,1,(one-1))
    ip=Mid(bindstr,(one+1),((two-one)-1))
    hn=Mid(bindstr,(two+1))
   
    getBinding=Array(ia,ip,hn)
end function

Function findWeb(computer, webname)
    On Error Resume Next

    Dim websvc, site
    dim webinfo
    Dim aBinding, binding

    set websvc = GetObject("IIS://"&computer&"/W3svc")
    if (Err <> 0) then
        exit function
    end if
    ' First try to open the webname.
    set site = websvc.GetObject("IIsWebServer", webname)
    if (Err = 0) and (not isNull(site)) then
        if (site.class = "IIsWebServer") then
            ' Here we found a site that is a web server.
            set findWeb = site
            exit function
        end if
    end if
    err.clear
    for each site in websvc
        if site.class = "IIsWebServer" then
            '
            ' First, check to see if the ServerComment
            ' matches
            '
            If site.ServerComment = webname Then
                set findWeb = site
                exit function
            End If
            aBinding=site.ServerBindings
            if (IsArray(aBinding)) then
                if aBinding(0) = "" then
                    binding = Null
                else
                    binding = getBinding(aBinding(0))
                end if
            else
                if aBinding = "" then
                    binding = Null
                else
                    binding = getBinding(aBinding)
                end if
            end if
            if IsArray(binding) then
                if (binding(2) = webname) or (binding(0) = webname) then
                    set findWeb = site
                    exit function
                End If
            end if
        end if
    next
end function
set sjov= findweb(computer,webname)
response.write site %>

Ja det må jeg erkende at jeg ikke kan få til at virke !

i starten af scriptet er det eneste du skal ændre.. webname...

og så skal det bare køres med samme rettigheder som det andet script..

så skulle det gerne skrive  sitenummeret ud...

Websitet har ikke noget navn kun et ip nummer

Den må da have et navn som den svarer på ?.. altså et domæne..

ellers  må du oprette domæner som du kan søge på ..

det behøver jo ik være registrerede domæner.. bare nogen du bruger internt..

Jeg kalder mit site med http://ipnr

Jeg bruger ikke domæn.

sådan skal det se ud

    Dim websvc, site
    dim webinfo
    Dim aBinding, binding

    set websvc = GetObject("IIS://localhost/W3svc")
    for each site in websvc
      if site.class = "IIsWebServer" then
        Response.Write site.ServerComment & " = " & site.Name & "<br>"
      end if
    next

Tak for hjælpen - vi klaret alt - undtagen det sidste som jeg fandt til anden side.
Du fortjener bestemt points.

tak skal du ha...