At slette bestemt linie fra en txt fil

det findes ikke en "delete" metode som man kan bruge for at slette en linie. Du er nødt til at bruge en lille kombination:

Dim fso, f, filespec
Set fso = CreateObject("Scripting.FileSystemObject")
filespec = Server.Mappath("blacklist_users.txt")
Set f = fso.GetFile(filespec)
Set objStream = f.OpenAsTextStream(1)
dim counter : counter = 1
dim intDeleteLine : intDeleteLine = CInt( Request( "sletLinie" ) )
dim strPreDelete : strPreDelete = ""
do
    strCurrent = objStream.ReadLine
    if( counter = intDeleteLine ) then
        exit do
    else
        strPreDelete = strPreDelete & strCurrent & vbCrLf
        counter = counter + 1
    end if
   
loop while not objStream.AtEndOfStream
Dim strRest : strRest = objStream.ReadAll()
Dim strContent : strContent = strPreDelete & strRest
objStream.Close
Set objStream = f.OpenAsTextStream(2)
objStream.Write( strContent )

/nute

Tak skal du have nute. Det virker bare perfekt :)

hmm, men nute eller i andre. Hvis jeg laver nogle af de her tegn . : / i min linie vil den ikke slette, den kommer med denne fejl:

Microsoft VBScript runtime error '800a003e'

Input past end of file

/admin/content/del_users.asp, line 20

Niels Bonde fra Bol?! :-D

Det er som om det kun virker med "rene" tegn, altså a-z + 0-9

Hvordan kan det komme til at virke med alle de andre tegn i acsii tabellen ?

spiffsen, ej det tror jeg næppe :P

hvis du lægger mærke til hvad scriptet gør, så "slettes" ikke linien. Linien bliver bare sprunget over.

scriptet fungerer fint for mig (selv med . : og /). Men du kan måske lave det lidt mere "bullet proof". Denne linie:

Dim strRest : strRest = objStream.ReadAll()

skal være:

Dim strRest : strRest = ""

if( not objStream.AtEndOfStream ) then
    strRest = objStream.ReadAll()
end if

du kan også lave en

if( not objStream.AtEndOfStream ) then

omkring hele din do...loop, så prøver ikke scriptet at læse noget hvis filen ikke indeholder nogle linier:

if( not objStream.AtEndOfStream ) then
    do
        strCurrent = objStream.ReadLine
        if( counter = intDeleteLine ) then
            exit do
        else
            strPreDelete = strPreDelete & strCurrent & vbCrLf
            counter = counter + 1
        end if
       
    loop while not objStream.AtEndOfStream

    Dim strRest : strRest = ""
   
    if( not objStream.AtEndOfStream ) then
        strRest = objStream.ReadAll()
    end if
    Dim strContent : strContent = strPreDelete & strRest
    objStream.Close
    Set objStream = f.OpenAsTextStream(2)
    objStream.Write( strContent )
end if

/nute

Så du har nok ikke læst den...

(tolkien's)

weeee, tak nute. Nu kan vi få lagt nogle af alle de virus links i filen, så botten kicker hvis man skriver sådan et link :)

Tusind tak :)

fino :-)

så smider jeg et svar