Du kan lave en side sådan her så, der er mail koden og en form man kan udfylde data i:
<%
if Request.ServerVariables("REQUEST_METHOD") = "POST" then
Dim Mailer
Set Mailer = Server.CreateObject("SMTPsvg.Mailer")
' Her sættes afsender navn og e-mail adresse
Mailer.FromName = "Kelvin Pagels"
Mailer.FromAddress= "Kelvin@Pagels.dk"
' Afsenders mailserver
Mailer.RemoteHost = "pop3.pagels.dk"
' Her sættes modtager navn og e-mail adresse
Mailer.AddRecipient "Modtagers navn", "pagels@gmail.com"
' Her sættes overskriften på mailen
Mailer.Subject = Request.Form("emne")
' Her sættes selve teksten til mailen
Mailer.BodyText = "Hej med dig" & VbCrLf & Request.form("navn") & " skriver dette til dig:" & vbCrLf & vbCrLf & Request.Form("besked")
' Send e-mail og skriv status
if Mailer.SendMail then
Response.Write "Mailen er afsendt..."
else
Response.Write "Der skete en fejl: " & Mailer.Response
end if
' Fjern objekt igen
Set Mailer = Nothing
Response.end
End if
%>
<html>
<body>
<table>
<form action="<%=Request.Servervariables("SCRIPT_NAME")%>" method="post">
<tr><td>Dit navn:</td><td><input type="text" name="navn"></td></tr>
<tr><td>Emne:</td><td><input type="text" name="emne"></td></tr>
<tr><td>Besked:</td><td><textarea name="besked"></textarea></td></tr>
<tr><td> </td><td><input type="submit" name="Send" value="Send"></td></tr>
</form>
</table>
</body>
</html>
