fso informationer

Jeg ved ikke hvordan du kan skrive til filens comments, hvis det overhovedet er muligt.. Men du kan hente det sådan her:

http://www.experts-exchange.com/Web/WebDevSoftware/Authoring/Q_10303059.html

//>Rune

Den kræver noget abbonnement for at se den :-(
Kan du skrive lidt om det fra siden ?
/Snakeeyz

<%
Sub ShowImageForType(strName)
    strTemp = lCase(strName)
    If strTemp <> "dir" Then
          strTemp = LCase(Right(strTemp, Len(strTemp) - InStrRev(strTemp, ".", -1, 1)))
    End If
    Select Case strTemp
          Case "asp"
              strTemp = "asp"
          Case "dir"
              strTemp = "dir"
          Case "htm", "html"
              strTemp = "htm"
          Case "gif", "jpg"
              strTemp = "img"
          Case "txt"
              strTemp = "txt"
          Case "zip"
              strTemp = "zip"
          Case Else
              strTemp = "misc"
    End Select
    response.write "<IMG SRC=""/Graphics/dir_" & strTemp & ".gif"" WIDTH=16 HEIGHT=16 BORDER=0>"
    extension = strTemp
End Sub
%>


<%' Now to the Runtime code:
Dim strPath  'Path of directory to show
Dim objFSO    'FileSystemObject variable
Dim objFolder 'Folder variable
Dim objItem  'Variable used to loop through the contents of the folder

strPath = Server.MapPath(".") & "\"

' Create our FSO
Set objFSO = Server.CreateObject("Scripting.FileSystemObject")

' Get a handle on our folder
Set objFolder = objFSO.GetFolder(strPath)

' Show a little description line and the title row of our table
%>

Contents of <B>&nbsp;\<%=strPath%></B><BR>

<BR>

<TABLE BORDER="3" BORDERCOLOR="<%=BorderC%>" CELLSPACING="0" CELLPADDING="2" WIDTH="100%">
    <TR>
          <TD NOWRAP BGCOLOR="<%=SubjectBColor%>"><FONT COLOR="<%=SubjectColor%>"><B>File Name:</B></FONT></TD>
          <TD NOWRAP BGCOLOR="<%=SubjectBColor%>"><FONT COLOR="<%=SubjectColor%>"><B>File Size (bytes):</B></FONT></TD>
          <TD NOWRAP BGCOLOR="<%=SubjectBColor%>"><FONT COLOR="<%=SubjectColor%>"><B>File Type:</B></FONT></TD>
          <TD NOWRAP BGCOLOR="<%=SubjectBColor%>"><FONT COLOR="<%=SubjectColor%>"><B>Comments:</B></FONT></TD>
    </TR>

<% For Each objItem In objFolder.SubFolders %>
    <TR>
          <TD NOWRAP BGCOLOR="<%=MessageBColor%>" ALIGN="left" ><% ShowImageForType("dir") %>&nbsp;<A HREF="<%= objItem.Name %>"><%= objItem.Name %></A></TD>
          <TD NOWRAP BGCOLOR="<%=MessageBColor%>" ALIGN="right"><%= objItem.Size %></TD>
          <TD NOWRAP BGCOLOR="<%=MessageBColor%>" ALIGN="left" ><%= objItem.Type %></TD>
          <TD NOWRAP BGCOLOR="<%=MessageBColor%>" ALIGN="left" ><%FileComment(LCase(objItem.Name)) %></TD>
         
    </TR>
<% Next %>

<% For Each objItem In objFolder.Files %>
    <% If LCase(objItem.Name) <> "index.asp" then %>
    <TR BGCOLOR="<%=MessageBColor%>">
          <TD NOWRAP BGCOLOR="<%=MessageBColor%>" ALIGN="left" >
          <% ShowImageForType(objItem.Name) %>&nbsp;
          <% If lcase(extension) = "asp" then %>
              <A HREF="<%=strPath%><%= objItem.Name %>"><%= objItem.Name %></A></TD>
          <% Else %>
              <A HREF="<%= objItem.Name %>"><%= objItem.Name %></A></TD>
          <% End If %>
          <TD NOWRAP BGCOLOR="<%=MessageBColor%>" ALIGN="right"><%= objItem.Size %></TD>
          <TD NOWRAP BGCOLOR="<%=MessageBColor%>" ALIGN="left" ><%= objItem.Type %></TD>
          <TD WIDTH="80%" BGCOLOR="<%=MessageBColor%>" ALIGN="left"></TD>
    </TR>
    <% End If %>
<% Next %>

<%
Set objItem = Nothing
Set objFolder = Nothing
Set objFSO = Nothing
%>
</TABLE>

//>Rune

Er FileComment() ikke en funktion der skal kodes også? Har du den ? Ellers kan jeg ikke lige se hvordan jeg skal hente info ud.
/SNakeeyz

Det kan ikke gøres direkte i ASP uden en DLL som skal installeret på serveren.
Du kan selv lave en, som kan finde ud af det, eller download den løsning MS har lavet:
http://support.microsoft.com/default.aspx?scid=http://support.microsoft.com:80/support/kb/articles/Q224/3/51.asp&NoWebContent=1

Download filen dsofile.exe, du skal så dobbelt klikke på filen for at insalleret DLL filen.

Her et kort kode eksempel som udskriver de properties som er på summary siden:

<%
Set objPropertyReader = CreateObject("DSOleFile.PropertyReader")
Set objDocument = objPropertyReader.GetDocumentProperties( server.MapPath("test.doc") )

Response.write "Category: " & objDocument.Category & "<br>"
Response.write "Comments: " & objDocument.Comments & "<br>"
Response.write "Keywords: " & objDocument.Keywords & "<br>"
Response.write "Subject: " & objDocument.Subject & "<br>"
Response.write "Title: " & objDocument.Title & "<br>"
%>

Jeg kan varmt anbefale at læse denne side igennem og der kan du også se alle de mange properties man kan få på filen:
http://blogs.msdn.com/gstemp/archive/2004/02/25/79867.aspx