replace [x] med billede

Er det dette du søger efter:

MyText = "en test hvor [2] skal udskiftes [23] med noget andet [11]."
function replaceNum(funkText)
dim MyRegExp, returVal
  Set MyRegExp = New RegExp
  MyRegExp.Pattern = "\[(\d*)\]"
  MyRegExp.Global = True
  MyRegExp.IgnoreCase = True
  returVal = MyRegExp.replace(funkText, "<img src='pic/nyheder/temp/$1.jpg'/>")
  Set MyRegExp = Nothing
  replaceNum = returVal
end function
Response.write replaceNum(MyText)

Der bliver alle "[etTal]" udskiftet med et billed, med tilsvarendende nummer.

hmm ja det er næsten sådan, men billedet har ikke samme navn som nummeret

nummeret mellem [] svare til et nummer i min db, som hentes med rsPic("placering"), navnet på billedet svare så til rsPic("navn")

så kan man flette en SQL ind på en måde??
"select navn, placering from Billeder where placering ="& $1

sådan så stien på billedet bliver:
<img src='pic/nyheder/temp/rsPic("navn")'/>

Så kan du ikke bruge regExp. Du bliver nød til at loope igennem databasen og finde dem som passer.

nyhed = rs("nyhed")
set rsPic = conn.execute("select * from pictures")
do while not rsPic.eof
  nyhed = replace(nyhed,"["& rsPic("placering") &"]","<img src='pic/nyheder/temp/"&rsPic("navn")&"' />")
  rsPic.MoveNext
loop

hmm okay, men hvis jeg looper på den måde får jeg vel udskrevet nyheden det antal gange som den looper igennem databasen ikke??

hvordan kan man undgå det?

Nope. Du gemmer jo "nyheden" i variablen nyhed. Så looper du igennem alle billeder i databasen, og replacer i nyhed-variablen, hvorefter du udskriver. Det hele løber måske også i et loop, fordi der skal udskrives flere nyhedder. Det vil så ca se sådan ud:

set rs = conn.execute("select top 5 * from nyhedder order by dato desc")
do while not rs.eof
  response.write rs("title")
  nyhed = rs("nyhed")
  set rsPic = conn.execute("select * from pictures")
  do while not rsPic.eof
    nyhed = replace(nyhed,"["& rsPic("placering") &"]","<img src='pic/nyheder/temp/"&rsPic("navn")&"' />")
    rsPic.MoveNext
  loop
  response.write nyhed
  rs.MoveNext
loop

det ser ud til at det virker, så du kan lige komme med et svar hvis du vil ha' point : )

hvad er forskellen egentlig på at bruge "do while not rsPic.eof / loop" også do "while not rsPic.eof / wend"?

hov - minus "do" i den sidste : )

I dette tilfælde er der ingen forskeld på at bruge de to løkker. Do/loop løkken har bare flere muligheder for at styre gennemløbet.

Hvor while/wend syntaxen er:
While condition
  [statements]
Wend

Har do/loop syntaxen flere muligheder:
Do [{While | Until} condition]
  [statements]
  [Exit Do]
  [statements]
Loop

Do
  [statements]
  [Exit Do]
  [statements]
Loop [{While | Until} condition]

okay...takker for hjælpen : )