Hent fra db, beregn gennemsnit, udskriv i rækkefølge

Hvad skal gennemsnittet beregnes af? Der er en avg funtion eks:

"select top 10 avg(kolonne), brugerid from tabel order by avg(kolonne) desc"

arh glemte group by i sql sætningen:

"select top 10 avg(kolonne) as gensinit, brugerid from tabel group by brugerid order by avg(kolonne) desc"

gennemsnittet skal beregnes af et felt som kan se sårn ud:
13,10,5,00,03

Ok, det gør det noget mere besværlidt så skal man hente alle poster og regne gennemsnittet ud. Man kan lave et nyt recordset som man ligger data ind i smammen med gennemsnittet så sortere det efter den nye kolonne og udskrive fra det nye recordset eks:


<%
function udregnAvg(str)
  arr=split(str,",")
    sum=0
    for x=0 to ubound(arr)
      sum=sum+int(arr(x))
  next
  udregnAvg=sum/(ubound(arr)+1)
end function

set Conn = server.CreateObject("ADODB.Connection")
Conn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source="& server.mappath("db1.mdb")

set rs = server.CreateObject("ADODB.Recordset")
Const adDouble = 5
Const adVarChar = 200
rs.Fields.Append "Navn", adVarChar, 200
rs.Fields.Append "Gennemsnit", adDouble
rs.Open()

SQL = "select * from tabelnavn"
Set rsDb = Conn.Execute(sql)

do while not rsDb.EOF
  rs.Addnew
  rs("Navn") = rsDb("brugernavn")
  rs("Gennemsnit") = udregnAvg(rsDb("kolonne"))
  rs.Update
  rsDb.Movenext
loop
   
rs.Sort = "Gennemsnit DESC"
rs.MoveFirst
i = 1
do while (not rs.EOF) and i<=10
  i=i+1
  response.Write rs("navn") & " " & rs("Gennemsnit") & "<br>"
  rs.Movenext
loop
rs.Close
set rs =Nothing

Conn.Close
Set Conn = Nothing
%>

det skal lige siges at, jeg bruger MySQL og jeg har en Windows server, og at jeg har oprettet en forbindelse til min db længere oppe i scriptet...

ok, men så ville connection se anderledes ud. det andet skulle være i samme stil.

set rs = server.CreateObject("ADODB.Recordset")
Const adDouble = 5
Const adVarChar = 200
rs.Fields.Append "Navn", adVarChar, 200
rs.Fields.Append "Gennemsnit", adDouble
rs.Open()

Kan du ikk lige forklare det, da jeg ikk helt forstår det :-/

Den laver et recordset og så tilføjes der to kolonner:

rs.Fields.Append "Navn", adVarChar, 200
rs.Fields.Append "Gennemsnit", adDouble

En kolonne navn og en kolonne gennemsnit.

oki.. så skal jeg vel bare appende alle de forskellige kolonner jeg skal bruge?

Ja.

oki :)

Det ser umiddelbart ud til at virke :)
Laver lige videre på det i morgen, og ser om jeg kan få det til.. Takker for hjælpen indtil videre.. Smutter i seng nu, skal jo tidligt op og i skole :S

hvis det kunne bruges så her et svar :)

Det virker bare perfekt :)
Mange tak for hjælpen :)