Pivot Tabel Excel Til Bak

Den virker ikke i xl97 / xl2000 fordi "MissingItems" ikke findes der.
Du havde jo skrevet xl2002 :-) .
Jeg har også en løsning til de andre, men den skal køres hver gang man vil have ryddet op....

Sub CleanPivotItems()

    Dim pt As PivotTable, pf As PivotField, pi As PivotItem
    Dim booShowMsg As Boolean, mbxResult As VbMsgBoxResult, msg As String

    booShowMsg = True
    On Error GoTo ErrorHandler

    For Each pt In ActiveSheet.PivotTables
        pt.RefreshTable
        For Each pf In pt.PivotFields
            For Each pi In pf.PivotItems
                If pi.RecordCount = 0 And pi.IsCalculated = False Then pi.Delete
            Next pi
        Next pf
    Next pt
    Set pi = Nothing
    Set pf = Nothing
    Set pt = Nothing
    Exit Sub

ErrorHandler:

    If booShowMsg Then
        msg = "Macro kunne ikke slette et emne." & vbCr
        msg = msg & "En grund kunne være at at den engang har været en del af en gruppering," & vbCr
        msg = msg & "eller at det (tom) " & vbCr
        msg = msg & "Click [CANCEL] for at undgå yderligere fejlmeddelelser."
        mbxResult = MsgBox(msg, vbExclamation + vbOKCancel, "Fejl ved sletning")
        booShowMsg = (mbxResult = vbOK)
    End If
    Resume Next
   
End Sub