Vis ikke allerede viste records

Du kan med distinct hente forskellige, når du åbner det nye recordset:

SQL = "select distinct tech_pattern.navn from tech_pattern limit 20"

Så tager den 20 forskeliige fra tech_pattern. Der nok også en where på så den henter de rigtige fra tech_pattern i forhold til det første recordset.

ohh den skal ikke hente forskellige...

Det den skal gøre, er at liste de samme tech_pattern (som er et felt i den tabel der bliver listet fra i første loop), som er blevet listet i første loop. Der er bare nogle af dem som bliver listet to gange, fordi den samme værdi i tech_pattern eksisterer i flere forskellige records. Derfor skal man udelukke nogle af dem, så den kun viser den samme værdi én gang.

tech_pattern er ikke en tabel, men et felt i den tabel som bliver loopet.

Ok, så må du lave en liste med de test_patten som er udskrevet og før du udskriver et test_pattern tjekke om det findes i den liste, her en variable som hedder test_pattern_list :

test_pattern_list = ","  'Sæt listen lig med et skille tegn som ikke kan være i teksten.

'Udskriv test_pattern
if inStr(1,test_pattern_list, "," & rs("test_pattern") & ",",1)=0 then
  'Udskriv og gem det test_pattern listen
  response.write rs("test_pattern")
  test_pattern_list = test_pattern_list & rs("test_pattern") & ","
end if

Frækt... :)
Hvordan er det så at jeg laver et loop ud fra denne liste??

Hmm jeg bruger vel en split på den right? Men så skal jeg så bare loope alle de strings der ligger i mit array.. hvordan er det nu jeg gør det?

Det er den liste som bliver udskrevet vil du også loopen igennem den?

Ja du kan bruge split til at lave et array så skal det første og sidste skille tegen fjernes


test_pattern_list = mid(test_pattern_list,2, len(test_pattern_list)-2)
test_pattern_array = split(test_pattern_list, ",")

yups netop... så langt nåede jeg, men når jeg så skal loope den, kan jeg jo self. ikke huske hvordan man finder antallet af "post" i array'et... så jeg kan lave en "for" sætning

Ja ubound giver din antalet -1 da array's starter fra index 0.

Så du kan udskrive dem:

test_pattern_list = mid(test_pattern_list,2, len(test_pattern_list)-2)
test_pattern_array = split(test_pattern_list, ",")

for i = 0 to ubound(test_pattern_array)
  response.write test_pattern_array(i)
next

Det er perfekt!! Smid et svar ;)

Ok her er et svar :)

Ehh lige et tillægsspørgsmål... Kan man sortere et array? Altså i alfabetisk rækkefølge???

Ja så skal man havde en sort function


Her er en som kan det:


Function SortArray(ByVal arrToSort)
  Dim arrWork
  Dim intOuterIndex, intInnerIndex, intSmallestIndex
  Dim varTemp
  arrWork = arrToSort
  For intOuterIndex = 0 To UBound(arrWork)
    intSmallestIndex = intOuterIndex
    For intInnerIndex = intOuterIndex To UBound(arrWork)
      If arrWork(intInnerIndex) < arrWork(intSmallestIndex) Then
        intSmallestIndex = intInnerIndex
      End If
    Next
    If intSmallestIndex <> intOuterIndex Then
      varTemp = arrWork(intOuterIndex)
      arrWork(intOuterIndex) = arrWork(intSmallestIndex)
      arrWork(intSmallestIndex) = varTemp
    End If
  Next
  SortArray = arrWork
End Function


Den kaldes sådan ehr:

array = SortArray(array)

Her er et link til en anden sort funktion QuickSort:

http://www.4guysfromrolla.com/webtech/012799-2.shtml