Generer form og send til email adresse?

http://www.library.unr.edu/subjects/guides/mailplay.asp

her er lidt...

Synes der er en frygtlig masse man skal ændre først... er det virkelig nødvendigt? :-)

Tænkte måske man kunne køre alt det script igennem en anden asp fil (form_handler.asp) så man ik skal blande alt koden sammen i samme fil...

Evt fra min form...

<form action="form_handler.asp" name="form" method="post">

hvilket mail komponent har du tilrådighed på serveren?

du kan nemt lave en side der hedder form_handler.asp, hvor du hiver værdierne ud af den submittede form med: Request.From("feltnavn"). du kan så lave en streng, som du sender som en mail via et mailkomponent.

Kan det passe den hedder SMTP ?

El. JMail

Kan godt trækker værdierne over og lægge dem i variabler men jeg har ik så meget styr på ASP, Hvordan sender jeg det til en email? kan du komme med et eksempel på koden? :-)

Det hedder nok Jmail, jeg finder lige et eksempel til dig.

<%

' Create the JMail message Object
set msg = Server.CreateOBject( "JMail.Message" )

' Set logging to true to ease any potential debugging
' And set silent to true as we wish to handle our errors ourself
msg.Logging = true
msg.silent = true

' Most mailservers require a valid email address
' for the sender
msg.From = "test@mydomain.com"
msg.FromName = "My Realname"

' Next we have to add some recipients.
' The addRecipients method can be used multiple times.
' Also note how we skip the name the second time, it
' is as you see optional to provide a name.
msg.AddRecipient "recipient@hisDomain.com", "His Name"
msg.AddRecipient "recipientelle@herDomain.com"


' The subject of the message
msg.Subject = "How you doin?"

' The body property is both read and write.
' If you want to append text to the body you can
' use JMail.Body = JMail.Body & "Hello world! "
' or you can use JMail.AppendText "Hello World! "
' which in many cases is easier to use.
'
' Note the use of vbCrLf to add linebreaks to our email
msg.Body = "Hello Jim" & vbCrLf & vbCrLf & "How's it going? ..."

' There.. we have now succesfully created our message.
' Now we can either send the message or save it
' as a draft in a Database.
' To save the message you would typicly use the
' Message objects Text property
' to do something like this:
'
' SaveMessageDraft( msg.Text )
' Note that this function call is only an
' example. The function does not exist by
' default, you have to create it yourself.


' To send the message, you use the Send()
' method, which takes one parameter that
' should be your mailservers address
'
' To capture any errors which might occur,
' we wrap the call in an IF statement
if not msg.Send("mail.myDomain.net" ) then
    Response.write "<pre>" & msg.log & "</pre>"
else
    Response.write "Message sent succesfully!"
end if


' And we're done! the message has been sent.


%>

du laver så bare din string, og kalder den ex. strFrom - så sætter du bare msg.Body = strForm

Prøver lige...

Synes ik rigtig jeg kan få det til at funke... Tror måske min mailkomponent er ASPMail istedet...

så får du her koden til AspMail

Set Mailer = Server.CreateObject("SMTPsvg.Mailer")
Mailer.FromName  = "Joe’s Widgets Corp."
Mailer.FromAddress= "Joe@somehost.com"
Mailer.RemoteHost = "mailhost.localisp.net"
Mailer.AddRecipient "John Smith", "jsmith@anotherhostname.com"
Mailer.Subject    = "Great SMTP Product!"
Mailer.BodyText  = "Dear Stephen" & VbCrLf & "Your widgets order has been processed!"
if Mailer.SendMail then
  Response.Write "Mail sent..."
else
  Response.Write "Mail send failure. Error was " & Mailer.Response
end if

Okay tror nu stadig min komponent er JMail.. min udbyder er Cliche.dk

Jeg får bare en fejl når jeg trykker send...

-----------------------------------------------------------------

Microsoft JScript compilation error '800a03f7'

Unterminated string constant

/form_handler.asp, line 4

' Create the JMail message Object
---------------------------------^

-----------------------------------------------------------------

den burde ignorere alle linier med ' foran, da det bare er kommentarer. Men du kan bare slette dem, for de har ingen funktion anden end at forklare dig hvad der sker i koden.

Så nu virker det! Den sender ihvertfald... :-)) Men der kommer lagt fra alle values med fra mine felter. Min formular bruger POST metoden... Derfor kan man ik bruge Request.Form vel ?? Jeg vil gerne udtrække de values der står i min formfelter jo. :-)

msg.Body = Request.Form("tilmelding1") & ", " & Request.Form("framelding1") & " " & Request.Form("gaester1") & " "& vbCRLF
msg.Body = Request.Form("tilmelding2") & ", " & Request.Form("framelding2") & " " & Request.Form("gaester2") & " "& vbCRLF
msg.Body = Request.Form("tilmelding3") & ", " & Request.Form("framelding3") & " " & Request.Form("gaester3") & " "& vbCRLF
msg.Body = Request.Form("tilmelding4") & ", " & Request.Form("framelding4") & " " & Request.Form("gaester4") & " "& vbCRLF
msg.Body = Request.Form("tilmelding5") & ", " & Request.Form("framelding5") & " " & Request.Form("gaester5") & " "& vbCRLF

Kan man lave en string eller nået med alle values fra formen og så nede i msg.body = vise den?

Evt

strform = new String ("Request.Form("booking")") ?

msg.Body = strform

Eller?

du kan du kan fint bruge Request.Form sammen med POST

dit problem er at du kun kan lav en msg.Body, ellers overskriver du den igen og igen.

du skal lave en streng som du selv viser. Så gør således:

strForm = strForm & Request.Form("tilmelding1") & ", " & Request.Form("framelding1") & " " & Request.Form("gaester1") & " "& vbCRLF
strForm = strForm & Request.Form("tilmelding2") & ", " & Request.Form("framelding2") & " " & Request.Form("gaester2") & " "& vbCRLF
strForm = strForm & Request.Form("tilmelding3") & ", " & Request.Form("framelding3") & " " & Request.Form("gaester3") & " "& vbCRLF
strForm = strForm & Request.Form("tilmelding4") & ", " & Request.Form("framelding4") & " " & Request.Form("gaester4") & " "& vbCRLF
strForm = strForm & Request.Form("tilmelding5") & ", " & Request.Form("framelding5") & " " & Request.Form("gaester5") & " "& vbCRLF

msg.Body = strForm

Ahhh mange tak!!... ved godt jeg er lidt besværlig nu men har lige et sidste spørgsmål, kan man sætte det op i evt. en tabel så det står pænt? :-)

yep, så skal du bare sende mailen i HTML format ved at bruge

msg.HTMLBody i stedet for msg.Body

Jeg siger tak. ;-)

det var så lidt