Reqest XML værdi

Hvormeget kode har du? Hvis du har et XML-objekt (MSXML2.DOMDocument.4.0) oppe og køre, så kan du finde en hvilkensomhelst node i din struktur ved at kalde

doc.documentElement.selectSingleNode("//currency[@code='EUR']")

hvor doc er et DOMDocument-objekt som du opretter med server.createobject.

Jeg har følgende:

<%
Set objXMLHTTP = Server.CreateObject("Microsoft.XMLHTTP")
Set objXMLDOM = Server.CreateObject("Microsoft.XMLDOM")
Call objXMLHTTP.Open("GET", "http://www.nationalbanken.dk/dndk/valuta.nsf/valuta.xml", False)
objXMLHTTP.Send
Set objXMLDOM = objXMLHTTP.ResponseXML

If objXMLDOM.parseError.errorcode = 0 Then
  'Udskriver datoen for kurserne i filen
  set datoen = objXMLDOM.getElementsByTagName("dailyrates")
  Response.Write "Dato : " & datoen(0).getAttribute("id")
  Response.Write "<br>"

  'Udskriver valuta data her
  set n=objXMLDOM.getElementsByTagName("currency")
  Response.Write "<table>"
  Response.Write "<tr><td>Code</td><td>Beskrivelse</td><td>Rate</td></tr>"
  for each node in n
 

    Response.Write "<tr>" 
    Response.Write "<td>" & node.getAttribute("code") & "</td>"
    Response.Write "<td>" & node.getAttribute("desc") & "</td>"
    Response.Write "<td>" & Valutakurs & "</td>"
    Response.Write "</tr>"
  next
  Response.Write "</table>"
Else
  Response.Write ("There was an error")
End If


Set objXMLHTTP = Nothing
Set objXMLDOM = Nothing






%>

Hvordan kan jeg trække EUR ud her?

Jeg er lidt usikker på hvad du efterspørger for du har jo allerede noget kode der fungerer (såvidt jeg kan se), så det er bare at spørge efter currency med code="EUR". Jeg har formuleret din kode lidt anderledes herunder og der er lagt en lille passage ind som henter EUR-valutaen også:

<%@ language="vbscript" %>
<%
Set objXMLHTTP = Server.CreateObject("Microsoft.XMLHTTP")
Call objXMLHTTP.Open("GET", "http://www.nationalbanken.dk/dndk/valuta.nsf/valuta.xml", False)
objXMLHTTP.Send
Set objXMLDOM = objXMLHTTP.ResponseXML

If objXMLDOM.parseError.errorcode = 0 Then
  'Udskriver datoen for kurserne i filen
  set datoen = objXMLDOM.selectSingleNode("//dailyrates")
  Response.Write "Dato : " & datoen.getAttribute("id")
  Response.Write "<br>"

  set eur = objXMLDOM.selectSingleNode("//currency[@code='EUR']")
  Response.Write "EUR : " & eur.getAttribute("rate")
  Response.Write "<br>"
 
  'Udskriver valuta data her
  set n=objXMLDOM.selectNodes("//dailyrates/currency")
  Response.Write "<table>"
  Response.Write "<tr><td>Code</td><td>Beskrivelse</td><td>Rate</td></tr>"
  for each node in n
    Response.Write "<tr>" 
    Response.Write "<td>" & node.getAttribute("code") & "</td>"
    Response.Write "<td>" & node.getAttribute("desc") & "</td>"
    Response.Write "<td>" & node.getAttribute("rate") & "</td>"
    Response.Write "</tr>"
  next
  Response.Write "</table>"
Else
  Response.Write ("There was an error")
End If

Set objXMLHTTP = Nothing
Set objXMLDOM = Nothing
%>

Det er lige præcis det. Smid et svar

Så gerne :)

Tak for point :)