Bruger script SBS 2003

det gøre man med et script, som køres ved logon.

Kan give dig et eksempel (som jeg selv bruger) er et bat script ?

Du kan få et VBS - script her:

Nedenstående script undersøger om det er en computer eller server, alt efter hvilken løsning mapper den drev.
Samtidig ændrer den også navnet på "Denne Computer" til computernavnet



On Error Resume Next

strComputer = "."
Set objWMIService = GetObject("Winmgmts:\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * From Win32_DesktopMonitor")
For Each objItem in colItems
    intHorizontal = objItem.ScreenWidth
    intVertical = objItem.ScreenHeight
Next

Set objExplorer = CreateObject _
    ("InternetExplorer.Application")

objExplorer.Navigate "about:blank" 
objExplorer.ToolBar = 0
objExplorer.StatusBar = 0
objExplorer.Left = (intHorizontal - 400) / 2
objExplorer.Top = (intVertical - 200) / 2
objExplorer.Width = 400
objExplorer.Height = 200
objExplorer.Visible = 1           

objExplorer.Document.Body.Style.Cursor = "wait"

objExplorer.Document.Title = "Logon script in progress"
objExplorer.Document.Body.InnerHTML = "Your logon script is being processed. " _
    & "This might take several minutes to complete."

Const MY_COMPUTER = &H11&

Set objNetwork = CreateObject("Wscript.Network")
objComputerName = objNetwork.ComputerName
Set objShell = CreateObject("Shell.Application")
Set objFolder = objShell.Namespace(MY_COMPUTER)
Set objFolderItem = objFolder.Self
objFolderItem.Name = objComputerName



strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")

Set colComputers = objWMIService.ExecQuery _
    ("Select * from Win32_ComputerSystem")

For Each objComputer in colComputers
    If objComputer.DomainRole < 2 Then
        Set objNetwork = CreateObject("Wscript.Network")   
    strdriveletter = "W:"
        objNetwork.MapNetworkDrive strdriveletter, "\\computer\mappe"
    strdriveletter = "X:"
        objNetwork.MapNetworkDrive strdriveletter, "\\computer\mappe"
    strdriveletter = "Y:"
        objNetwork.MapNetworkDrive strdriveletter, "\\computer\mappe"
    strdriveletter = "Z:"
        objNetwork.MapNetworkDrive strdriveletter, "\\computer\mappe"

    Else
        objExplorer.Document.Body.InnerHTML = "THIS IS A SERVER  " _
    & "Mapping drives aborted!"
    Wscript.Sleep 500
    End If
Next

objExplorer.Document.Body.InnerHTML = "Your logon script is now complete."

objExplorer.Document.Body.Style.Cursor = "default"

Wscript.Sleep 500

objExplorer.Quit

Og et logoff script - (For at lukke butikken pænt)(fjerner alle mappede drev)

On Error Resume Next

strComputer = "."
Set objWMIService = GetObject("Winmgmts:\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * From Win32_DesktopMonitor")
For Each objItem in colItems
    intHorizontal = objItem.ScreenWidth
    intVertical = objItem.ScreenHeight
Next

Set objExplorer = CreateObject _
    ("InternetExplorer.Application")

objExplorer.Navigate "about:blank" 
objExplorer.ToolBar = 0
objExplorer.StatusBar = 0
objExplorer.Left = (intHorizontal - 400) / 2
objExplorer.Top = (intVertical - 200) / 2
objExplorer.Width = 400
objExplorer.Height = 200
objExplorer.Visible = 1           

objExplorer.Document.Body.Style.Cursor = "wait"

objExplorer.Document.Title = "Logon script in progress"
objExplorer.Document.Body.InnerHTML = "Your logoff script is being processed. " _
    & "This might take several minutes to complete."

Set objNetwork = CreateObject("Wscript.Network")

Set colDrives = objNetwork.EnumNetworkDrives

For i = 0 to colDrives.Count-1 Step 2
    objNetwork.RemoveNetworkDrive colDrives.Item(i)
Next


objExplorer.Document.Body.InnerHTML = "Your logoff script is now complete."

objExplorer.Document.Body.Style.Cursor = "default"

Wscript.Sleep 500

objExplorer.Quit

Er det I siger at jeg skal lave en .bat fil og skrive stien til den samt filnavn i bruger/profile?

Og hvad er den korte syntaks for at mappe en mappe til et drev på klienten?

På hvilken sti, skal sådanne .bat scripts typisk gemmes?

Fik selv svar på de sidste spørgsmål.
Takker.