Afvikle sub med tidsinterval

Helt simpelt kan du placere en Timer på din form.

Sæt Interval-egenskaben til dit tidsinterval (i millisekunder).

Enabled-egenskaben bestemmer, om Timeren står og kører, og for hver gang intervallet nås, kaldes Timerens Tick-event. Heri kan du lave et kald til din subrutine:

  Private Sub Timer1_Tick(ByVal sender As Object, _
                          ByVal e As EventArgs) _
                          Handles Timer1.Tick
    MySub()
  End Sub

Det lyder jo meget rigtigt.

Skal timeren første gang kaldes af formens load-event, eller..?

Øh, det virker sådan set fint nu...

Altså måske lige bortset fra, at min applikation går kold, når timeren er kørt første gang..?

:)

Du kan sætte Enabled egenskaben til at være True i designeren. Derved begynder timeren automatisk at køre så snart formen loades. Alternativt kan du, som du nævner, sætte Enabled = True i Form_Load.

Jeg forstår ikke lige hvorfor din applikation går kold. Det må have noget med din subrutine at gøre. Har du prøvet at debugge?

Har fået selve timeren til at køre - selvfølgelig ved at sætte Enabled til True i designeren.

Scenariet er som følger:

Med et tidsinterval laver jeg en HTTPRequest, som downloader en fil. Hvis filen allerede eksisterer på klienten, får jeg er fejl. Herefter går applikationen kold.

Jeg skal have fundet en måde hvorpå den får at vide, at den må overskrive filen.

Kan du vise mig koden, som skriver til filen?

Public Sub Download()

        Try

            Dim WebURL As String = "http://www.directit.dk/gfx/brugerupload/documents/"
            Dim FileName As String = "vsnet.doc"
            Dim Request As HttpWebRequest = CType(WebRequest.Create(WebURL & FileName), HttpWebRequest)
            Dim Response As HttpWebResponse = CType(Request.GetResponse, HttpWebResponse)
            Dim DateLastModified As DateTime = Response.LastModified
            Dim TotalFileSize As Long = Response.ContentLength
            Dim InStream As Stream = Response.GetResponseStream
            Dim OutStream As Stream = New FileStream(FileName, FileMode.CreateNew, FileAccess.Write)
            Dim ElapsedTimeCounter As New Stopwatch()
            Dim b(1000) As Byte
            Dim n As Integer

            n = InStream.Read(b, 0, b.Length)

            ElapsedTimeCounter.Start()


            While (n > 0)

                OutStream.Write(b, 0, n)
                n = InStream.Read(b, 0, b.Length)

                ToggleStatusStrip(((OutStream.Length * 100) / TotalFileSize), OutStream.Length, TotalFileSize)

            End While


            ElapsedTimeCounter.Stop()

            OutStream.Close()
            InStream.Close()
            Response.Close()

        Catch ex As Exception

            MessageBox.Show(ex.Message.ToString(), "Fejlbesked", MessageBoxButtons.OK, MessageBoxIcon.Error)

        End Try

    End Sub


    Public Sub ToggleStatusStrip(ByVal DownloadPercent As Integer, ByVal CurrentFileSize As Integer, ByVal TotalFileSize As Integer)

        If DownloadPercent <= 100 Then

            ToolStripProgressBar.Value = DownloadPercent

            Me.ToolStripStatusLabel.Text = Math.Round((CurrentFileSize / 1024), 0) & " kb af " & Math.Round((TotalFileSize / 1024), 0) & " kb hentet"

        End If

        If CurrentFileSize = TotalFileSize Then

            ToolStripProgressBar.Value = ToolStripProgressBar.Minimum

            Me.ToolStripStatusLabel.Text = "Udført"

        End If

    End Sub

Dim OutStream As Stream = New FileStream(FileName, FileMode.CreateNew, FileAccess.Write)


Ovenstående linie skal ændres til:

  Dim OutStream As Stream = New FileStream(FileName, FileMode.Create, FileAccess.Write)


Forskellen på FileMode.Create og FileMode.CreateNew er:
- CreateNew opretter en ny fil, men kun hvis den ikke eksisterer i forvejen.
- Create opretter en ny fil hver gang, og overskriver en eventuelt eksisterende fil.

Jamen det er jo fantastisk!  ;-)