Flet kundeoplysninger fra Access ind i Excel dok.

Jeg ville lave det med en makro eller to.

Hvis du har et excel ark med dette layout:

      A                    B                C                  D
1 kundenummer  kundenavn  adresse    postnummer
2



Så lave to funktioner, den første er en standart funktion som bliver kaldt når arket ændres. Den er lavet sådan at hvis celle A2 har ændre sig kaldes den anden funktion som slår op i databasen. Den anden funktion ligger kundenavn ind i B2, adresse ind i C2 og postnummer ind i D2:

Private Sub Worksheet_Change(ByVal Target As Excel.Range)
    'Cells(2,1) svar til A2, første tal = række, andet tal = kolonne
    If Target = Cells(2, 1) Then Call getinfo
End Sub


Sub getinfo()
Dim cn As ADODB.Connection
Set cn = New ADODB.Connection
'Husk at angive stien til databasen
cn.Open "Provider=Microsoft.Jet.OLEDB.4.0; " & _
        "Data Source=C:\sti\til\databasefilen\db1.mdb;"

Set rs = New ADODB.Recordset
 
'finder kundenummer
kundenr = Range("A2").Value

'Er kundenummer kolonnen definet som en tal kolonne skal der ikke ' omkring:
Sql = "select * from kundedata where kundenummer = '" & kundenr & "'"

Set rs = cn.Execute(Sql)
If Not rs.EOF Then
  Range("B2").Value = rs.Fields("Kundenavn")
  Range("C2").Value = rs.Fields("Adresse")
  Range("D2").Value = rs.Fields("postnummer")
Else
  Range("B2").Value = "Ukendt"
  Range("C2").Value = ""
  Range("D2").Value = ""
End If
rs.Close
Set rs = Nothing
cn.Close
Set cn = Nothing
End Sub



Den anden funktion skal tilpasses stien til databasen samt tabel og kolonnennavne.

For at kunne conecte til databasen skal du i excel:
1. Start the Visual Basic Editor and select your VBA project.
2. On the Tools menu, click References.
3. Click to select the most recent version of the Microsoft ActiveX Data Objects Library check box.