ADODB.Recordset ind i en ComboBox

overfør dit recordset til en variant og indsæt det så i comboboxen

Lav en global variabel VA
Public VA as Variant

overførsel
VA = Application.Worksheetfunction.Transpose(RS)

Indsættelse

Private Sub UserForm_Initialize()
ComboBox1.ColumnCount = 2
ComboBox1.List = VA
End Sub

Jeg får følgende fejl.

Run-time error '1004'
Application-defined or object-defined error

i linjen
VA = Application.Worksheetfunction.Transpose(RS)

Skal variablen være global?
Har prøvet både lokal og global, uden held.

Den skal være Public og dimensioneret i et alm. modul.

Har du stadig problemer så send hele koden herind eller send den til mig
excel snabela tbdl.dk

Her er hele koden, med en global variabel VA i et modul.

Private Sub UpdateAfdeling()
  On Error GoTo errHandler
  Dim lSql As String
  Dim lConn As ADODB.Connection
  Dim lRs As ADODB.Recordset
  lSql = "Select * From MinTabel"
  Set lConn = New ADODB.Connection
  lConn.ConnectionString = Min SQL database
  lConn.Open
  Set lRs = New ADODB.Recordset
  lRs.Open lSql, lConn, adOpenDynamic, adLockReadOnly
  If Not lRs.EOF Then
    cboAfdeling.Clear
    VA = Application.WorksheetFunction.Transpose(lRs)
    cboAfdeling.List = VA
  End If
errHandler:
  ' Ingen fejlhåndtering
  lConn.Close
  Set lRs = Nothing
End Sub

Kan ikke umiddelbart se noget der skulle give anledning til denne fejl.

Prøv lige at dimme VA i selve subben istedet.

Har prøvet at lave variablen lokal, uden held.

Udskift denne linie
VA = Application.WorksheetFunction.Transpose(lRs)

med

VA = Application.WorksheetFunction.Transpose(lRs.GetRows)

så skulle det køre

Hvis du gør sådan behøver du ikke VA

cboAfdeling.List = Application.WorksheetFunction.Transpose(lRs.GetRows)

Alletiders.
Det var lige den sidste "GetRows" der skulle til.

Tak for hjælpen.

ok :-)