Hente gemt faktura ind i aktiv ark.

Der er også point, hvis der er en der kan henvise til et tidligere stillet spørgsmål, med et svar der kan bruges til det jeg søger.

Men har selv været igang med at søge, men har ikke kunnet finde noget jeg synes kunne bruges.

Jeg har prøvet at lave en kode der skulle gøre det jeg ville have.

Men det funk. ikke lige helt efter hensigten.

Den melder fejl i :    .Filename = "Faktura_" + fakNR + ".xls"


Private Sub CommandButton2_Click()

' hent faktura der skal rykkes for
Dim fakNR
 
  fakNR = Worksheets(2).Range("D8")        ' Tilpasses
Set fs = Application.FileSearch
With fs
    .LookIn = "G:\Faktura\excelfakturaDB"
    .SearchSubFolders = True
    .Filename = "Faktura_" + fakNR + ".xls"
    If .Execute() > 0 Then
    Workbooks.Open Filename:=LookIn & Filename
       
       
    End If
    End With
End Sub

Sub OpenInvoiceFile()
    Dim strFileName As String
    Dim fakNR As String
       
    fakNR = Worksheets(1).Range("D8")
    strFileName = "Faktura_" & fakNR + ".xls"
   
    With Application.FileSearch
        .LookIn = "G:\Faktura\excelfakturaDB"
        .SearchSubFolders = True
        .Filename = strFileName
        If .Execute > 0 Then
            strFileName = .FoundFiles(1)
            Workbooks.Open strFileName
        Else
            MsgBox "Kan ikke finde fakturanr. " & fakNR, vbInformation
        End If
    End With
End Sub

Hej word-hejen.

Det var ikke lige det jeg søgte.

Det jeg søgte var at den skulle åbne den faktura med det nummer man skriver. Så skal den koiper Cellerne A1 til C45 og lægge det ind i den skabelon jeg har i forvejen. Den er magen til, Så der er ikke noget med at skulle flytte på felterne.

Det vba prg. du har givet eks. på, åbner bare fakturaen med det nummer man skriver, uden at flytte den over i den skabelon man står i fra starten.

Håber at du forstår hvad det er jeg mener. Ellers er jeg åben for spørgsmål.

MVH.

Kenneth

Det jeg mangler at der bliver bygget ind, er en copy / paste funktion. faktura fil den lige har åbnet, skal så lukkes igen. Det er bare for at få ført det over fra fakturaen, så man kan skrive en rykker.

Hej hepygula!

Ja, jeg er klar over, at filen blot bliver åbnet. Men det var nu engang det, du selv gjorde i din kode, så jeg troede egentlig, at du "bare" havde problemer med Filesearch-funktionen.

Hvilket ark skal du så have oplysningerne ind i? Eller skal du kopiere hele arket fra din faktura-fil ind i din aktive fil? Hvilket ark ligger fakturaen i i den netop åbnede fil? Har den "kun" et nummer eller har du navngivet arket?

Hej Word-hejen

Jeg kan godt se at jeg nok ikke har forklaret mig ordenligt fra starten. :-\
Men tror at dette kan gøre lidt, for at det er den rigtige løsninge der kommer.

Jeg skal prøve på at komme på siden i løbet af dagen, hvis du skal have flere oplysninger fra mig. :-)

Jeg har den rykkerskabelon ( hvor fanen hedder Rykker ), hvor jeg har en knap på. Når jeg så har skrevet hvilket faktura nr. jeg vil hente, trykker jeg på knappen.

Så åebner den fakturaen med det nummer man har bedt den om. I det ark skal jeg så have oplysningerne i cellerne B4:B7 og A21:C21. ( Fanen på denne skabelon hedder Faktura )
De oplysninger skal så lægges over i det ark der hedder Rykker, altså det ark man startede i (aktive fil ). Når den så har hentet oplysningerne over skal den lukke den netop åbnede fil igen.

Kan evt maile skabelonerne til dig, hvis det kunne hjælpe, at sidde med dem foran dig.

Og så skal jeg nok ligge løsningen ud på siden bagefter, så andre også kan få gavn af den. :-)

Sub OpenInvoiceFile()
    Dim objWB As Workbook
    Dim objWS As Worksheet
    Dim objInvoiceWB As Workbook
    Dim objInvoiceWS As Worksheet
    Dim strFileName As String
    Dim fakNR As String
       
    Set objWB = ActiveWorkbook
    Set objWS = objWB.Sheets("Rykker")
   
    fakNR = objWS.Range("D8")
    strFileName = "Faktura_" & fakNR + ".xls"
   
    With Application.FileSearch
        .LookIn = "G:\Faktura\excelfakturaDB"
        .SearchSubFolders = True
        .Filename = strFileName
        If .Execute > 0 Then
            strFileName = .FoundFiles(1)
            Set objInvoiceWB = Workbooks.Open(strFileName)
            Set objInvoiceWS = objInvoiceWB.Sheets("Faktura")
            objInvoiceWS.Range("A21:C21").Copy objWS.Range("A21:C21")
            objInvoiceWS.Range("B4:B7").Copy objWS.Range("B4:B7")
            objInvoiceWB.Close False
        Else
            MsgBox "Kan ikke finde fakturanr. " & fakNR, vbInformation
        End If
    End With
   
    Set objWB = Nothing
    Set objWS = Nothing
    Set objInvoiceWB = Nothing
    Set objInvoiceWS = Nothing
End Sub

Tak for hjælpen, og din gode toldmodighed. :-)

Her med point til dig.

Velbekomme :-)