Eksportere tabeller til Excel

Du kan blot eksportere en forespørgsel der udvælger dine data i stedet for en tabel. Syntaksen for eksport er den samme for tabel / forespørgsel

Jeg tror ikke jeg har formuleret mig godt nok. Jeg kan godt finde ud af at eksportere tabeller og forespørgsler med Access, dog ikke i VBA. Men problemet er at jeg gerne vil have noget VBA kode, der danner distincte excel filer for hvert projekt i mine forespørgsler/tabeller. Eller sagt på en anden måde den skal kunne danne en excel fil til et projekt hvis der er data på det i mine tabeller/forespørgsler.

Jeg opererer med ca 100 forskellige projekter hver måned, og der kommer hele tiden nye til og gamle falder fra. Så det kunne være fedt hvis man kunne lave en dynamisk kode der selv kunne finde ud af hvilke excel filer der hver måned skal dannes.

Syntaksen er:

DoCmd.TransferSpreadsheet acExport, 8, "FORESPØRGSLENS NAVN", "DESTINATION", True, ""

Du kunne fremfinde alle relevante projekter og så lave en løkke, der løb dem igennem og trak de korrekte data ud af dine tabeller/forespørgsler.

En grovskitse (som skal tilrettes med dine forespørgselsnavne osv):

Sub ExporterProjekter()
  Const ExportQueryNavn = "Q_Export"
  Dim Qdf As QueryDef
  Dim TotalSQL As String
  Dim TotalRst As Recordset
  Dim ProjektSQL As String
  Dim FilNavn As String
  Dim Mappe As String
 
  Mappe = "c:\Projektopfølgning\" & Year(Date) & "\" & Year(Date) & "-" & Format(Month(Date), "00")
  On Error Resume Next
  MkDir ("c:\Projektopfølgning")
  MkDir ("c:\Projektopfølgning\" & Year(Date))
  MkDir Mappe
  On Error GoTo 0
 
  ' Find alle relevante projekter
  TotalSQL = "SELECT Q_Projekter.* FROM Q_Projekter WHERE Aktiv=True"
  Set TotalRst = CurrentDb.OpenRecordset(TotalSQL)
       
  Do
    ProjektSQL = "SELECT Q_Eksport.* FROM Q_Eksport WHERE ID=" & TotalRst.Fields("ID")
   
    ' Slet evt. gammel forespørgsel
    On Error Resume Next
    CurrentDb.QueryDefs.Delete ExportQueryNavn
    On Error GoTo 0
    ' Opret ny forespørgsel
    Set Qdf = CurrentDb.CreateQueryDef(ExportQueryNavn)
    With Qdf
      .SQL = ProjektSQL
      .Close
    End With
    Set Qdf = Nothing
   
    FilNavn = TotalRst.Fields("ProjektNavn")
    DoCmd.TransferSpreadsheet acExport, acSpreadsheetTypeExcel9, ExportQueryNavn, Mappe & "\" & FilNavn, True
   
    TotalRst.MoveNext
  Loop Until TotalRst.EOF
  TotalRst.Close
 
  Set TotalRst = Nothing
End Sub

Ud fra ovenstående burde du i det mindste kunne danne dig en ide om principperne.

Ups...
FilNavn = TotalRst.Fields("ProjektNavn") & ".xls"

Når jeg får tid vil jeg gå videre med den skitse du har trukket op fdata. Det ser nemlig ud til at være præcis det jeg leder efter.

Helt ok. Venter spændt ...

Jeg fik lavet en helt anden løsning. Men synes du skulle belønnes for dit arbejde alligevel:-)

Det var godt nok en gammel sag  ;o)
Takker for point.