Hvordan kædes flerbruger basemiljø sammen (programmeringsmæssig).

På følgende side :

http://www.makeiteasy.dk/eksempler/Downloads.htm

kan du downloade et eksempel på hvordan du automatisk checker og/eller sammenkæder frontend med backend

Sorry dead link prøv denne i stedet :

http://www.makeiteasy.dk/eksempler/ReattachTables.zip

Det er noget af en opvisning programmet laver. Jeg har studeret det længe og fundet frem til at der er formeget "pop". Man når dårligt nok at se procentbaren.
Hvad er jeg nødt til at have med for at lave den simple udgave jeg bruger pt. access 2003. RefreshLink kan ikke stå alene og jeg bruger ADODB.xxxx istedet for DAO.Database.

Hej Jensen363

Jeg måtte lede mange steder før der var noget der kunne bruges.
Dette er nok et minimum til formålet.

Herunder er hvad jeg kogte det ned til for at finde og linke FrontEnd sammen med BackEnd.

1>>>>>>>>>>
Opret en ”Macro” der hedder ”Autoexec” og anvend handlingen ”AfspilKode” indsæt ”CheckMyLinks ()” i funktionskoden.
1>>>>>>>>>>

Placer resten i et Modul.

2>>>>>>>>>>
Option Compare Database
Option Explicit

' Placering af BackEnd Data-filen i forhold til FrontEnd
Const BackEndFilNavn As String = "BackEnd\The_Missing_LINKs_Data.mdb"

Public Function CheckMyLinks()
    Dim rs As DAO.Recordset
    Dim check As Boolean

On Error Resume Next
    ' Teksten "TS" er ikke et af tbl-navnene og bevirker at der kontrolleres hver gang
    Set rs = CurrentDb.OpenRecordset("TS")
    check = IIf(Err.Number = 0, True, False)
   
    If Not check Then
        ' BackEnd findes vha. "RefreshLinks(GetCurrentPath() & BackEndFilNavn)" der
        ' bruger funktionerne "GetCurrentPath()" og "RefreshLinks"
        If Not RefreshLinks(GetCurrentPath() & BackEndFilNavn) = True Then
            MsgBox "Kunne ikke finde filen 'LinkBag.mdb'(BackEnd)." _
                  & vbNewLine & vbNewLine & "Filen skal ligge i kataloget 'BackEnd'." _
                  & vbNewLine & vbNewLine & "Kataloget 'BackEnd' skal ligge i sammen sted som 'FrontEnd'."
        End If
    End If
    rs.Close
    Set rs = Nothing
   
    ' Start Databasen
    DoCmd.OpenForm "frmTS_Links"
End Function


Function GetCurrentPath() As String
    Dim Pos As Integer, path As String
    ' Find placeringen på databasen(stien)
    path = CurrentDb.Name
    Pos = Len(path)
    Do Until Mid(path, Pos, 1) = "\"
        Pos = Pos - 1
    Loop
    GetCurrentPath = Left(path, Pos)
End Function


Function RefreshLinks(strFilename As String) As Boolean

    Dim db As DAO.Database
    Dim tdf As DAO.TableDef
    Dim intCount As Integer

    ' Opdater Links til BackEnd
On Error GoTo ErrorHandler
    Set db = CurrentDb
    For intCount = 0 To db.TableDefs.Count - 1
        Set tdf = db.TableDefs(intCount)
       

        If Len(tdf.Connect) > 0 Then
            tdf.Connect = ";DATABASE=" & strFilename
            Err.Number = 0
           
            On Error Resume Next
            tdf.RefreshLink
           
            If Err.Number <> 0 Then
                RefreshLinks = False
                Exit Function
            End If
        End If
    Next intCount

    RefreshLinks = True
    Exit Function
   
ErrorHandler:
    MsgBox "Error#:  " & Err.Number & vbCrLf & Err.Description
    RefreshLinks = False
End Function
2>>>>>>>>>>

Desværre føler jeg ikke at du kan tilkomme fuld valører for hjælpen.

Hilsen
Soloven

Hvis det tilgodeser dit formål, er det vel ok ...

Takker for point