Hvor mange forskellige navne i kollonne 1?

=HVIS(TÆL.HVIS(A1:$A$100;A1)=1;SUM.HVIS($A$1:$A$100;A1;$B$1:$B$100);"")
eller
=HVIS(TÆL.HVIS(A1:$A$100;A1)=1;A1&" - "&SUM.HVIS($A$1:$A$100;A1;$B$1:$B$100);"")

Denne formel tæller unikke værdier i A1:A100

=SUM(SAND/TÆL.HVIS(A1:A100;A1:A100&""))

excelent
Tak for dine forslag, de er fine.
Det er formlen
=HVIS(TÆL.HVIS(A1:$A$100;A1)=1;A1&" - "&SUM.HVIS($A$1:$A$100;A1;$B$1:$B$100);"")
der kommer tættet på det jeg ønsker, bl.a. fordi du både kan vise hvilke navne der eksisterer på en lang navneliste, men også fordi du kan summere en værdi der står i tilknytning til navnet, og så at du kan vise begge dele i samme felt, det er bare flot.
Men, men, resultatet vises med tomme celler ud for gengangere af navne på datalisten. Så derfor er mit spørgsmål, om ikke ovenstående formel kan konstrueres sådan, at resultatet vises under hinanden (ovenfra) og hvor de tomme celler kommer sidst i kollonnen hvor resultatet vises?

Desværre, så langt rækker mine evner ikke, men jeg kan måske lave en makro til opgaven hvis det har interesse.

Måske en anden har en løsning :-)

Lav evt. en pivottabel og brug resultatet til at lave dine formler ud fra.

Excelent
Opret dit svar, så tildeles du dine point.

mikker
Pivottabel bruger jeg meget i forvejen. Du har ret, den kan også bruges til formålet, men det var ikke lige det jeg havde brug for her.

Hvis du kan leve med en ekstra kolonne, så indsæt denne og afslut med ctrl+shift+enter og kopier ned
Du kan evt. skjule den anden kolonne

=HVIS(RÆKKER($1:1)<=TÆLV($C$1:$C$30);INDEKS($C$1:$C$30;MINDSTE(IF($C$1:$C$30<>"";RÆKKE($C$1:$C$30)-MIN(RÆKKE($C$1:$C$30))+1);RÆKKER($1:1)));"")

excelent
Jeg ser på dit forslag ved et senere tidspunkt, men her har du dine point.

der var en lille fejl i denne:

=HVIS(RÆKKER($1:1)<=TÆLV($C$1:$C$30);INDEKS($C$1:$C$30;MINDSTE(HVIS($C$1:$C$30<>"";RÆKKE($C$1:$C$30)-MIN(RÆKKE($C$1:$C$30))+1);RÆKKER($1:1)));"")