Planlagt arbejdstid - udført arbejdstid

=HVIS(ER.TOM(D4);HVIS(B4<=C4;C4-B4;C4-B4+1);HVIS(D4<=E4;E4-D4;E4-D4+1))

Formlen kontrollerer om D4 er tom.
Hvis det er muligt at kun sluttiden i E4 er ændret (Og D4 er tom), skal formlen laves om. Så må du lige sige til.

Skal på arbejde nu og har ikke haft tid til at kontrollere din formel.
Både D4 OG E4 skal være udfyldte hvis formlen skal beregne på dem.
Hvis en af dem er tomme skal formlen beregne på B4 og C4

Får først tid til at kigge ind igen i morgen

=HVIS((HVIS(ER.TOM(D4);B4;D4))<=(HVIS(ER.TOM(E4);C4;E4));(HVIS(ER.TOM(E4);C4;E4))-(HVIS(ER.TOM(D4);B4;D4));(HVIS(ER.TOM(E4);C4;E4))-(HVIS(ER.TOM(D4);B4;D4))+1)

Denne formel virker, hvis én eller begge celler er tomme.

Formlen virker som ønsket.
Der er bare det, at der er en detalje jeg ikke lige fik med!

Hvis celle F4=R skal der lægges 6 timer til

Kan du mon også klare den?

Måske en nærmere forklaring er på plads.
Celle F4 indeholder en kode der i et enkelt tilfælde udløser et tillæg i arbejdstiden på 6 timer.
Cellen hvor beregningen foretages er formateret som tid med formatet [t]:mm
De mulige koder er: 700 - 730 - 740 - 900 - 000 - R - S - 000/SH - A - B - C
Kun koden R udløser 6 timer

Er det okay med en hjælpe-celle?

Hvis ja, så:
F.eks. i F5 indtaster du =HVIS(F4="R";"6:00";0)

Så hedder formlen:
=HVIS((HVIS(ER.TOM(D4);B4;D4))<=(HVIS(ER.TOM(E4);C4;E4));(HVIS(ER.TOM(E4);C4;E4))-(HVIS(ER.TOM(D4);B4;D4));(HVIS(ER.TOM(E4);C4;E4))-(HVIS(ER.TOM(D4);B4;D4))+1)+F5

Fik lige gennemtestet din formel.
Det viser sig at formlen vil medtage kolonne D eller E hvis der står en tid i bare en af dem.
Hvis der f.eks. er indtastet mødetid 7:00 i kolonne B, sluttid 15:00 i kolonne C og man herefter begynder at ændre vagt (det er det kolonne D og E er der til) og taster den ny mødetid i kolonne D (f.eks. 15:00), men ingen ting i kolonn E, vil resultatet blive beregnet til 0:00

Til gengæld har jeg fundet ud af at man kan slutte formlen med +HVIS(F4="R";"6:00";0) for at få lagt 6 timer til hvis der står R i celle F4.

Men altså, din formel:
=HVIS((HVIS(ER.TOM(D4);B4;D4))<=(HVIS(ER.TOM(E4);C4;E4));(HVIS(ER.TOM(E4);C4;E4))-(HVIS(ER.TOM(D4);B4;D4))_
;(HVIS(ER.TOM(E4);C4;E4))-(HVIS(ER.TOM(D4);B4;D4))+1)
virker forkert

Jamen, hvis du indtaster en ny mødetid i D, f.eks. 15:00, så skal du vel også indtaste en ny sluttid i E, eller hvad?

Du kan da ikke have både start- og sluttid til at være 15:00???
Det er jo derfor den viser 00:00

Det er ikke mig der skal bruge det.
Jeg prøver at tage højde for alt hvad de kan finde på. Det gør de nemlig!

Jamen du er altså nødt til at forklare hvordan du vil have det, ellers har jeg jo ikke en chance for at lave det.

Både D4 OG E4 skal være udfyldte hvis formlen skal beregne på dem.
Hvis en af dem er tomme skal formlen beregne på B4 og C4

Okay, nu håber jeg at jeg har fattet det.  :-)

=HVIS(ELLER(ER.TOM(D4);(ER.TOM(E4)));HVIS(B4<=C4;C4-B4;C4-B4+1);HVIS(D4<=E4;E4-D4;E4-D4+1))+HVIS(F4="R";"6:00";0)

Så ser det ud til at virke. Har testet den i et testark.
Skal nu til at indsætte den i 980 celler. På grund af forskelle i antal af rækker den skal virke på må det gøres manuelt, jeg kan ikke bare kopiere nedad og henad. Melder tilbage når jeg har indsat den over det hele, men forventer at det virker.
Tak!

Velbekomme, er der yderligere problemer, så skriver du bare.  :-)

Har testet på alle celler formlen skal bruges i.
Det var ikke så stort et arbejde igen. Ved hjælp af kopier og indsæt samt lidt søg og erstat tog det kun godt en times tid ;-)
Det virker som det skal