Jeg har lige lavet noget kode, der:
1) viser et billede for at indikerer hvilken type. Billedet indeholder f.eks. teksten "ASP", "PHP", "PDF", "ZIP", osv.. Billeder placeres i en mappe der hedder "gfx", som placeres i mappen med ASP-filen der skaber oversigten. Billederne, som er af typen GIF, skal hedde f.eks. "pdf.gif", "zip.gif", osv.. Jeg har sat ikon størrelsen til 16x16 pixels, som det fremgår af følgende: width:16px;height:16px;
2) laver filnavnet om til et link, så man kan downloade filen.
Jeg har tilføjet lidt til koden fra
http://www.roubaixinteractive.com/PlayGround/FSO/Sort_Folder_Contents.aspTest denne kode, og fortæl hvad der sker:
<%
Function icon(filetype)
Dim r
r = "gfx/space.gif" ' tomt/gennemsigtigt billede
Dim fso
Set fso = server.CreateObject("scripting.filesystemobject")
If fso.fileexists(server.mappath("./gfx/" & filetype & ".gif")) = True Then r = "gfx/" & filetype & ".gif"
Set fso = Nothing
icon = r
End Function
'**********
'kc_fsoFiles
'Purpose:
' 1. To create a recordset using the FSO object and ADODB
' 2. Allows you to exclude files from the recordset if needed
'Use:
' 1. Call the function when you're ready to open the recordset
' and output it onto the page.
' example:
' Dim rsFSO, strPath
' strPath = Server.MapPath("\PlayGround\FSO\Stuff\")
' Set rsFSO = kc_fsoFiles(strPath, "_")
' The "_" will exclude all files beginning with
' an underscore
'**********
Function kc_fsoFiles(theFolder, Exclude)
Dim rsFSO, objFSO, objFolder, File
Const adInteger = 3
Const adDate = 7
Const adVarChar = 200
'create an ADODB.Recordset and call it rsFSO
Set rsFSO = Server.CreateObject("ADODB.Recordset")
'Open the FSO object
Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
'go get the folder to output it's contents
Set objFolder = objFSO.GetFolder(theFolder)
'Now get rid of the objFSO since we're done with it.
Set objFSO = Nothing
'create the various rows of the recordset
With rsFSO.Fields
.Append "Name", adVarChar, 200
.Append "Type", adVarChar, 200
.Append "DateCreated", adDate
.Append "DateLastAccessed", adDate
.Append "DateLastModified", adDate
.Append "Size", adInteger
.Append "TotalFileCount", adInteger
.Append "Extension", adVarChar, 10 ' new!
End With
rsFSO.Open()
'Now let's find all the files in the folder
For Each File In objFolder.Files
'hide any file that begins with the character to exclude
If (Left(File.Name, 1)) <> Exclude Then
rsFSO.AddNew
rsFSO("Name") = File.Name
rsFSO("Type") = File.Type
rsFSO("DateCreated") = File.DateCreated
rsFSO("DateLastAccessed") = File.DateLastAccessed
rsFSO("DateLastModified") = File.DateLastModified
rsFSO("Size") = File.Size
rsFSO("Extension") = Mid(file.name, InstrRev(file.name, ".") + 1) ' new!
rsFSO.Update
End If
Next
'And finally, let's declare how we want the files
'sorted on the page. In this example, we are sorting
'by File Type in descending order,
'then by Name in an ascending order.
rsFSO.Sort = "DateCreated DESC, Size ASC "
'Now get out of the objFolder since we're done with it.
Set objFolder = Nothing
'now make sure we are at the beginning of the recordset
'not necessarily needed, but let's do it just to be sure.
rsFSO.MoveFirst()
Set kc_fsoFiles = rsFSO
End Function
'Now let's call the function and open the recordset on the page
'the folder we will be displaying
Dim strFolder : strFolder = Server.MapPath(".")
'the actual recordset we will be creating with the kc_fsoFiles function
Dim rsFSO 'now let's call the function and open the recordset
'we will exclude all files beginning with a "_"
Set rsFSO = kc_fsoFiles(strFolder, "_")
'now we'll create a loop and start displaying the folder
'contents with our recordset. Of course, this is just a
'simple example and not very well formatted, i.e., not in
'a table, but it gets the point across on how you can
'ouput the recordset on the page.
While Not rsFSO.EOF
%>
<p><a href="<%= rsFSO("Name").Value %>"><img src="<%=icon(rsFSO("Extension"))%>" style="width:16px;height:16px;vertical-align:bottom;"> <%= rsFSO("Name").Value %></a></p>
<%
'and let's move to the next record
rsFso.MoveNext()
Wend
'finally, close out the recordset
rsFSO.close()
Set rsFSO = Nothing
%>
