Hvordan detekteres stigende/faldende flanke smartest?

unit UBitclass;

interface

uses
  SysUtils, Classes;

type
  TOnBitChangeEvent = procedure(const aBitNo: integer; const aNewValue: boolean) of object;

  TBitActions = class
  private
    fBits: TBits;
    fOnBitChange: TOnBitChangeEvent;
    function GetBit(const aIndex: integer): boolean;
    procedure SetBit(const aIndex: integer; const Value: boolean);
  public
    constructor Create(const aSize: integer = 16);
    destructor Destroy; override;
    property OnBitChange: TOnBitChangeEvent read fOnBitChange write fOnBitChange;
    property Bit[const aIndex: integer]: boolean read GetBit write SetBit; default;
    procedure LoadFromStream(aStream: TStream);
    procedure SaveToStream(aStream: TStream);
    procedure LoadFromFile(const aFilename: string);
    procedure SaveToFile(const aFilename: string);
  end;

implementation

{ TBitActions }

constructor TBitActions.Create(const aSize: integer);
begin
  inherited Create;
  fBits := TBits.Create;
  fBits.Size := aSize;
  fOnBitChange := nil;
end;

destructor TBitActions.Destroy;
begin
  try
    fBits.Free;
  finally
    inherited;
  end;
end;

function TBitActions.GetBit(const aIndex: integer): boolean;
begin
  result := fBits[aIndex];
end;

procedure TBitActions.SetBit(const aIndex: integer; const Value: boolean);
var
  OldValue: boolean;
begin
  OldValue := fBits[aIndex];
  if OldValue <> Value then
  begin
    fBits[aIndex] := Value;
    if assigned(fOnBitChange) then
      fOnBitChange(aIndex,Value);
  end;
end;

// Gem- og hent-procedurerne kommer her.

procedure TBitActions.LoadFromFile(const aFilename: string);
var
  fs: TFileStream;
begin
  fs := TFileStream.Create(aFilename,fmCreate);
  try
    LoadFromStream(fs);
  finally
    fs.Free;
  end;
end;

procedure TBitActions.LoadFromStream(aStream: TStream);
var
  i: integer;
  Reader: TReader;
begin
  Reader := Treader.Create(aStream,100);
  try
    fBits.Size := Reader.ReadInteger;
    for i := 0 to fBits.Size - 1 do
      fBits[i] := Reader.ReadBoolean;
    Reader.FlushBuffer;
  finally
    Reader.Free;
  end;
end;

procedure TBitActions.SaveToFile(const aFilename: string);
var
  fs: TFileStream;
begin
  fs := TFileStream.Create(aFilename,fmOpenRead);
  try
    SaveToStream(fs);
  finally
    fs.Free;
  end;
end;

procedure TBitActions.SaveToStream(aStream: TStream);
var
  i: integer;
  Writer: TWriter;
begin
  Writer := TWriter.Create(aStream,100);
  try
    Writer.WriteInteger(fBits.Size);
    for i := 0 to fBits.Size - 1 do
      Writer.WriteBoolean(fBits[i]);
    Writer.FlushBuffer;
  finally
    Writer.Free;
  end;
end;

end.

unit FMain;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, UBitClass;

type
  TfrmMain = class(TForm)
    eBit: TEdit;
    chbValue: TCheckBox;
    btnSet: TButton;
    lbStatus: TListBox;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure BitChanged(const aBitNo: integer; const aNewValue: boolean);
    procedure btnSetClick(Sender: TObject);
  private
    fBits: TBitActions;
  public
  end;

var
  frmMain: TfrmMain;

implementation

{$R *.dfm}

procedure TfrmMain.BitChanged(const aBitNo: integer; const aNewValue: boolean);
begin
  lbStatus.Items.Add(format('Bit: %.2d: value: %s',[aBitNo,BoolToStr(aNewValue,true)]));
  //  case aBitNo of
  //    0 :;
  //    1 :;
  //    2 :;
  //  end;
end;

procedure TfrmMain.btnSetClick(Sender: TObject);
begin // Nok dumt at bruge StrToIntDef; sætter bit 0 ved fejl
  fBits[StrToIntDef(eBit.Text,0)] := chbValue.Checked;
end;

procedure TfrmMain.FormCreate(Sender: TObject);
begin
  fBits := TBitActions.Create;
  fBits.OnBitChange := BitChanged;
end;

procedure TfrmMain.FormDestroy(Sender: TObject);
begin
  fBits.Free;
end;

end.