Fylde en combobox liste på en userform med data fra et andet regneark.

Er regnearket med Kunder et anden fil eller samme fil, hvor fanenavn er Kunder?

Du er velkommen til at sende det/de relevante filer.

@-adresse under min profil.

Hej Supertekst
fanen "Kunder" er i regnearket "Kunder"

Jeg kan først sende filerne i eftermiddag.

Med venlig hilsen
Mimet

Ok..

VBA-kode i Userform:

Const kunderFilNavn = "kunder.xlsm"
Const førsteKundeRække = 2
Dim kunderXLS As Object
Dim antalRækker As Long, kundeRæk As Long

Dim sti As String
Private Sub CB1_Kunder_Change()
    kundeRæk = Me.CB1_Kunder.ListIndex + førsteKundeRække
    indsætKundeData kundeRæk
End Sub
Private Sub CmdLuk_Click()
    Application.DisplayAlerts = False
    lukKunder
    Unload Me
End Sub
Private Sub lukKunder()
    With kunderXLS
        .ActiveWorkbook.Saved = True
        .ActiveWorkbook.Close
        .Application.Quit
    End With
   
    Set kunderXLS = Nothing
End Sub
Private Sub userform_initialize()
    Application.ScreenUpdating = False
   
    opsætningAfSti
    indlæsningAfKunder
End Sub
Private Sub opsætningAfSti()
    sti = hentSti
    sti = ActiveWorkbook.Path
    If Right(sti, 1) <> "\" Then
        sti = sti & "\"
    End If
End Sub
Private Sub indlæsningAfKunder()
Dim ræk As Long, kundeNr As Integer
    Set kunderXLS = CreateObject("Excel.Application")
    With kunderXLS
        .Workbooks.Open sti & kunderFilNavn
       
        .ActiveWorkbook.Sheets("Kunder").Activate
       
        antalRækker = .ActiveCell.SpecialCells(xlLastCell).Row
       
        For ræk = førsteKundeRække To antalRækker
            kundeNr = .Range("A" & ræk)
            If CStr(kundeNr) <> "" Then
                Me.CB1_Kunder.AddItem .Range("A" & ræk)
                indsætKundeData ræk
            End If
        Next ræk
    End With
   
    Me.CB1_Kunder.ListIndex = 0
   
End Sub
Private Sub indsætKundeData(ræk)
    With kunderXLS.ActiveWorkbook.Sheets("Kunder")
        Me.TxtNavn1 = .Range("B" & ræk)
        Me.TxtNavn2 = .Range("C" & ræk)
        Me.TxtNavn3 = .Range("D" & ræk)
        Me.TxtNavn4 = .Range("E" & ræk)
    End With
End Sub

Tak for løsningen, det virker fint!
Her er svar og point