Tæl unik værdier samt afhængig af året

=SUMPRODUCT((I14:I2008<>"")*(L14:L2008=2016))
/COUNTIF(I14:I2008;I14:I2008&""))

Ikke rigtigt.
Lav evt. en ekstra kolonne der trækker årstallet ud af datoen.

Jeg oplever selv at nogle gange fungerer SUMPRODUCT ikke korrekt. Har du prøvet med SUM.HVISER()

Har du fået løst opgaven?
Ellers prøv denne matrixformel:

=COUNT(1/FREQUENCY(IF((YEAR(L14:L2008)=2016)*(I14:I2008<>"");I14:I2008);I14:I2008))

Hej

Opgaven er endnu ikke løst xl-enthusiasten

Når jeg anvender
=COUNT(1/FREQUENCY(IF((YEAR(L14:L2008)=2016)*(I14:I2008<>"");I14:I2008);I14:I2008))
Får jeg "FALSE"

Hvad mener du med
SUM.HVISER()
Rosco?

Sorry xl jeg får ikke FALSE (jeg havde lavet en fejl) jeg får 0

Har du behandlet formlen som det jeg skrev det er - en matrixformel?

Matrixformler skal indtastes på en bestemt måde, nemlig ved at holde Ctrl og Shift nede før duu trykker på Enter.

Nej det vidste jeg ikke man skulle....

Når jeg gør det kommer der stil at stå
{=COUNT(1/FREQUENCY(IF((YEAR($H$14:$H$2008)=P1)*($I$14:$I$2008<>"");$I$14:$I$2008);$I$14:$I$2008))}

og trykker jeg igen på formlen står der
=COUNT(1/FREQUENCY(IF((YEAR($H$14:$H$2008)=P1)*($I$14:$I$2008<>"");$I$14:$I$2008);$I$14:$I$2008))

og resultatet er desværre stadig 0

Hvis jeg skal se mere på det må duu uploade en fil der viser opgaven til:

http://208.89.215.167/gratisupload/

og så give et link til filen her på siden (+ anfør det korrekte resulltat).

(Jeg er først tilbage sidst på efttermiddagen).

Ok jeg forsøger at lav et ark som er mere overskueligt end mit og sender til dig.

Takker :)

Hej igen,

Jeg vil mene jeg har fundet ud af det
Hermed mit excel sheet:

Date            SOP    Area   
04-05-2011    019465    Area1   
04-05-2011    110020    Area2   
08-06-2011    110020    Area2   
04-05-2011    110085    Area2   
06-05-2011    110141    Area2   
04-05-2011    127942    Area1   
19-05-2011    110038    Area2   
19-05-2011    110059    Area2   
18-05-2011    110159    Area2   
18-05-2011    110158    Area2   
26-05-2011    110181    Area2   
26-05-2011    110183    Area2   
07-07-2011    026469    Area1   
13-06-2011    054173    Area1   
15-06-2011    127724    Area1   
20-06-2011    110144    Area2   
15-06-2011    110033     Area2   
15-06-2011    024405    Area3   
           
           
           
Selected year            2011
Test count of unique        17 (formel1)
Above + Area2            11 (formel2)
Above + Selected year        11 (formel3)




Formel1: {=SUM(1/COUNTIF(J2:J19;J2:J19))}

Formel2: {=SUM(--(FREQUENCY(IF(K2:K19=Q1;MATCH(J2:J19;J2:J19;0));ROW(J2:J19)-ROW(J2)+1)>0))}

Formel3: {=SUM(--(FREQUENCY(IF(YEAR(I2:I19)=Q2;IF(K2:K19=Q1;MATCH(J2:J19;J2:J19;0)));ROW(J2:J19)-ROW(J2)+1)>0))}


og jeg anvendte denne site
https://exceljet.net/formula/count-unique-values-in-a-range-with-criteria

men xl du må gerne lave et svar så får du pointene :) og takker endnu engang for hjælpen.

Jeg samler ikke på point, og du har jo ikke brugt noget fra 5, så tag du selv dine point.

Takker, lukker spm