Fejlmeddelse ved makroafspilning

Det kræver nok at vi får lov til at se makroen :)

Den kommer her ;-)

Option Explicit

Public Sub GetUserInfo()
   
    On Error GoTo Errhandler
   
    Sheets(1).Cells(1, 2).Value = GetOwnerName 'ldap username
    Sheets(1).Cells(2, 2).Value = GetUserDomain 'ldap username
   
Exit Sub
Errhandler:
    Exit Sub
End Sub

Private Function GetUserDomain() As String
   
    On Error GoTo Errhandler
   
    Dim OSinfo As New ActiveDs.WinNTSystemInfo
   

    If Len(OSinfo.DomainName) = 0 Or (OSinfo.ComputerName = OSinfo.DomainName) Then
        GetUserDomain = Application.OrganizationName 'excel registered organization name
    Else
        GetUserDomain = OSinfo.DomainName 'Wins name
    End If
   
   
    Set OSinfo = Nothing

Exit Function
Errhandler:
    Set OSinfo = Nothing
    Call MsgBox("Dine informationer kunne ikke hentes!" & vbCrLf & Err.Description, vbCritical + vbOKOnly, "Advarsel")
    Exit Function
   
End Function


Private Function GetOwnerName() As String
   
    On Error GoTo Errhandler
   
    Dim OSinfo As New ActiveDs.WinNTSystemInfo
   
    Dim s As String
   
    If Len(OSinfo.UserName) > 0 Then
        s = OSinfo.UserName & "/" & OSinfo.DomainName 'Netbios user and domain
    Else
        s = Application.UserName
    End If
   
   
    GetOwnerName = s
   
 
   
    Set OSinfo = Nothing
   
Exit Function
Errhandler:
    Set OSinfo = Nothing
    Call MsgBox("Dine informationer kunne ikke hentes!" & vbCrLf & Err.Description, vbCritical + vbOKOnly, "Advarsel")
    Exit Function
End Function

Ser jeg forkert, eller prøver den at hente info op WinNT? NT er jo fra 1993, og er muligvis derfor det ikke virker..

kører makroen som bruger eller som programmet?
Er du logget på med en domænebruger, eller lokalt?
Har du startet Excel som administrator?
Hvilket af dine funktioner/sub giver fejlen? har du prøvet at køre step-by-step for at finde ud af, hvad programmet finder?

Jeg kan ikke helt gennemskue, hvilken information, du ønsker, men måske kan du blive inspireret af denne, som viser navn og domæne, du er logget på.

Function NameAndDomain() As String
    Dim WSHnet, UserName, UserDomain, objUser
    Set WSHnet = CreateObject("WScript.Network")
    UserName = WSHnet.UserName
    UserDomain = WSHnet.UserDomain
    Set objUser = GetObject("WinNT://" & UserDomain & "/" & UserName & ",user")
    NameAndDomain = objUser.FullName & " " & "at " & UserDomain
End Function

Sub test()
Dim WSHnet
Dim objUser
Dim Oplysning

Set WSHnet = CreateObject("WScript.Network")
Set objUser = GetObject("WinNT://" & WSHnet.UserDomain & "/" & WSHnet.UserName & ",user")

    Oplysning = MsgBox(WSHnet.UserName, , "PC brugernavn")
    Oplysning = MsgBox(objUser.FullName, , "PC fulde brugernavn")
    Oplysning = MsgBox(WSHnet.UserDomain, , "Domæne")
    Oplysning = MsgBox(Application.UserName, , "Excel brugernavn")
    Set Oplysning = Nothing
End Sub