Fejl i fil.

prøv at poste signup_save.asp

Hvad mener du? :)

koden fra signup_save.asp

post indholdet af signup_save.asp! Hvordan skulle vi kunne gemmenskue fejlen, hvis vi ikke ser scriptet?

Nåh :D

Den ser så´nm her ud:

<!--#include file="inc_settings.asp" -->
<%
    On Error Resume Next

    Set Upload = Server.CreateObject("AspSmartUpload.SmartUpload")
    Upload.MaxFileSize = MaxFileSize
    Upload.AllowedFilesList = "jpg,jpeg,png"
    Upload.Upload
    If Err <> 0 Then
        If Err = -2147220494 Then intErrorCode = 20
        If Err = -2147220399 Then intErrorCode = 21
        Err.Clear
    End If

    If Not Upload.Files("filename").IsMissing And intErrorCode = 0 Then
        Set Conn = Server.CreateObject("ADODB.Connection")
        Conn.Open "DRIVER=mysql; SERVER=" & sql_Server & "; DATABASE=" & sql_DB & "; UID=" & sql_UID & "; PWD=" & sql_PWD

        strFilename = Upload.Files("filename").FileName

        strPass = DeMessSQL(Trim(Upload.Form("pass")))
        strEmail = DeMessSQL(Trim(Upload.Form("email")))
        strName = DeMessSQL(Trim(Upload.Form("fullname")))
        strCity = DeMessSQL(Trim(Upload.Form("homecity")))
        strCountry = DeMessSQL(Trim(Upload.Form("homecountry")))
        strText = DeMessSQL(Trim(Upload.Form("teaser")))
        strGender = DeMessSQL(Trim(Upload.Form("gender")))
        If strGender = "" Or Not IsNumeric(strGender) Then intErrorCode = 3
        If strEmail = "" Or Not IsEmail(strEmail) Then intErrorCode = 2
        Set Rs = Conn.Execute("SELECT id FROM persons WHERE email='" & strEmail & "'")
        If Not Rs.BOF Then intErrorCode = 4
        If strPass = "" Then intErrorCode = 1

        If intErrorCode = 0 Then
            strSQL = "INSERT INTO persons (password,email,name,city,country,text,gender,picturefile,datetime,shown) VALUES ("
            strSQL = strSQL & "PASSWORD('" & strPass & "'),"
            strSQL = strSQL & "'" & strEmail & "',"
            strSQL = strSQL & "'" & strName & "',"
            strSQL = strSQL & "'" & strCity & "',"
            strSQL = strSQL & "'" & strCountry & "',"
            strSQL = strSQL & "'" & strText & "',"
            strSQL = strSQL & strGender & ","
            strSQL = strSQL & "'" & strFilename & "',"
            strSQL = strSQL & "now(),0);"

            Conn.Execute strSQL
            Set Rs = Conn.Execute("SELECT id FROM persons ORDER BY id DESC")
            strPID = Rs(0)

            strMail = strEMVO
            strMail = Replace(strMail, "#navn", strName)
            strMail = Replace(strMail, "#pid", strPID)

            Upload.Files("filename").SaveAs Server.MapPath("pictures/" & strPID & "_" & strFilename)
            If Err = 0 Then
                ResizeIImage Server.MapPath("pictures/" & strPID & "_" & strFilename), 615
                Conn.Execute "INSERT INTO hits (pid) VALUES (" & strPID & ");"
                SendMail strEmail, "Registrering på Hot Or Not", strMail
            Else
                Conn.Execute "DELETE FROM persons WHERE id=" & strPID
                intErrorCode = 30
            End If
        End If
    ElseIf intErrorCode = 0 Then
        intErrorCode = 40
    End If
%>
<html>
<head>
    <title>tdaugaard.dk's Hot Or Not System</title>
    <meta http-equiv="pragma" content="nocache">
    <link rel="stylesheet" type="text/css" href="hotornot.css">
</head>
<body>
<center>
    <table border="0" cellpadding="4" cellspacing="0" width="613">
        <tr><td>
            <!--#include file="inc_menu.asp" -->
<%    If intErrorCode > 0 Then %>
            Der opstod en fejl under tilmelding af din profil.<br>
            Fejlen er:
            <p>
            <font color="#ff0000"><b>
<%
        Select Case intErrorCode
            Case 1: Response.Write "Du mangler at skrive et password!"
            Case 2: Response.Write "Du mangler at skrive din email adresse, eller den indtastede email adresse er ikke gyldig!"
            Case 3: Response.Write "Du mangler at vælge om du er Mand eller Kvinde!"
            Case 4: Response.Write "Den indtastede email adresse er allerede brugt af en anden bruger!"
            Case 20: Response.Write "Forkert filtype! Der kan kun uploades JPG (*.jpg; *.jpeg) og  PNG (*.png) filer!"
            Case 21: Response.Write "Billedet fylder for meget! Max størrelse er: &tilde;" & (MaxFileSize \ 1024) & " KB"
            Case 30: Response.Write "Der opstod en fejl under upload af dit billede og din profil er derfor ikke blevet oprettet. Dette skyldes højst sandsynligt en systemfejl!"
            Case 40: Response.Write "Du valgte ikke noget billede!"
        End Select
%>
            </font></b>
            <p>
            Klik på din browsers tilbage knap, ret fejlen og prøv igen :-)<br>
            Mener du at Hot Or Not er skyld i denne fejl, så kan du skrive til os på <a href="mailto:hon@tdaugaard.dk">hon@tdaugaard.dk</a>
<%    Else %>
            <b>Du er nu oprettet på Hot or Not :-)</b>
            <p>
            Det direkte link til din profil er: <a href="<%=BaseAddress%>default.asp?pid=<%=strPID%>"><%=BaseAddress%>default.asp?pid=<%=strPID%></a>
            <p>
            Du vil i løbet af få minutter modtage en velkomst email :-)
<%    End If %>
            <hr>
            <center>Copyright (C) Thomas Daugaard 2001</center>
        </td></tr>
    </table>
</center>
</body>

Prøv at poste indholdet af inc_settings.asp

Okay :)

<%
    ' Liste størrelser i personer
    Const ListSize = 25
    ' Hvor mange der skal have stemt på en, før brugeren kan komme på en Top liste.
    Const RatersBeforeTop = 20
    ' Sitets base adresse. (SKAL ende på /)
    Const BaseAddress = "http://www.friserverplads.dk/mats1122/"
    ' Emailen på ejeren af sitet (en gyldig POP3 email)
    Const OwnerEmail = "hotornot@tdaugaard.dk"
    ' Ret til din egen SMTP server
    Const SMTPServer = "mail.data-doktorn.nu"
    ' Ret til dit site's navn
    Const SenderName = "Hot Or Not"
    ' Max billede størrelse i bytes
    Const MaxFileSize = 204800 ' 200 KB

    ' Din mySQL server
    Const sql_Server = ""
    ' Dit brugernavn til mySQL'en
    Const sql_UID = ""
    ' Dit password til mySQL'en
    Const sql_PWD = ""
    ' mySQL database navnet
    Const sql_DB = ""

    ' Emailen der bliver sendt til en bruger når der bliver skrevet en kommentar. (EMOC=EMailOnComment)
    ' #navn bliver erstattet med brugerens navn.
    strEMOC = "Hej #navn," & vbCrLf
    strEMOC = strEMOC & "Du har modtaget en besked inde på Hot Or Not." & vbCrLf & vbCrLf
    strEMOC = strEMOC & "Klik dig ind på " & BaseAddress & "default.asp?mode=login for at læse den." & vbCrLf & vbCrLf
    strEMOC = strEMOC & "Med venlig hilsen, Hot Or Not."

    ' Emailen der bliver sendt når en person opretter sig i systemet. (EMVO=EMailVedOprettelse)
    ' #navn og #pid bliver erstattet med hhv. personens navn samt ProfileID.
    strEMVO = "Hej #navn," & vbCrLf
    strEMVO = strEMVO & "Du er nu oprettet på Hot Or Not." & vbCrLf & vbCrLf
    strEMVO = strEMVO & "Du kan se dit billede samt tekst på:" & vbCrLf & vbCrLf & "  " & BaseAddress & "default.asp?pid=#pid" & vbCrLf & vbCrLf
    strEMVO = strEMVO & "Du kan logge ind og rette din profil til hver en tid på" & vbCrLf & vbCrLf & "    " & BaseAddress & "default.asp?mode=login" & vbCrLf & vbCrLf
    strEMVO = strEMVO & "Mvh, Hot Or Not"

    ' Emailen der bliver sendt når der bliver rapporteret om et fake billede. (EMOF=EMailOnFake)
    ' #pid bliver erstattet med brugerens ProfileID.
    strEMOF = "Hejsa!" & vbCrLf & vbCrLf
    strEMOF = strEMOF & "En anmeldelse vedr. et fake billede er blevet sendt:" & vbCrLf & vbCrLf
    strEMOF = strEMOF & "-------------------------------" & vbCrLf
    strEMOF = strEMOF & "Billede ID: #pid" & vbCrLf & vbCrLf

    ' Forskellinge funktioner der bruges til diverse ting. RET IKKE I DEM!

    Function SendMail(strTo, strSubject, strMail)
        Set JMail = Server.CreateObject("JMail.SMTPMail")

        JMail.ServerAddress = SMTPServer
        JMail.SenderName = SenderName
        JMail.Sender = CStr(OwnerEmail)

        JMail.AddRecipient strTo
        JMail.Subject = strSubject
        JMail.Body = strMail
        JMail.Silent = True

        SendMail = JMail.Execute()
    End Function

    Function IsEmail(strEmail)
        Set objRegExpEMail = New RegExp

        objRegExpEMail.Pattern = "([\w\._-]+@[\w\._-]+\.[A-Za-z]{2,4}\S*)"
        objRegExpEMail.Global = False
        objRegExpEMail.IgnoreCase = True

        IsEmail = objRegExpEMail.Test(strEmail)

        Set objRegExpEMail = Nothing
    End Function

    Function DeMessSQL(strSource)
        DeMessSQL = Replace(strSource, "'", "''")
    End Function

    Function ResizeIImage(strImage, lngMaxWidth)
        Set Image = Server.CreateObject("AspImage.Image")

        Image.LoadImage strImage

        If Image.MaxX > lngMaxWidth Then
            intRatio = ((lngMaxWidth * 100) / Image.MaxX)
            intNewY = CInt(Image.MaxY * (intRatio / 100))
            Image.ResizeR lngMaxWidth, intNewY

            Select Case (LCase(Right(strImage, 3)) = "jpg")
                Case True
                    Image.ProgressiveJPEGEncoding = True
                    Image.ImageFormat = 1
                Case False
                    Image.ImageFormat = 3
            End Select

            Image.FileName = strImage
            Image.SaveImage
        End If

        Set Image = nothing
    End Function
%>

Kunne det tænkes at friserverplads.dk ikke under stytter ASPSmartUpload kompunenten som bruges i scriptet??

Set Upload = Server.CreateObject("AspSmartUpload.SmartUpload")

eagleeye >>> Sikker på det?

for den skriver jo noget med password?

Nej.. men i toppen af filen signup_save.asp står:

On Error Resume Next


Hvilket betyder den skal gå til næste linie sevlom der er fejl i linien, prøv at udkommentere linien.

Hvor skal jeg udkommentere henne?

i filen signup_save.asp skal linien On Error Resume Next udkommenteres.


<!--#include file="inc_settings.asp" -->
<%
'    On Error Resume Next        '<--------- Denne linie

    Set Upload = Server.CreateObject("AspSmartUpload.SmartUpload")

Prøv at opret en profil nu

Jeg tror du har fået fjernet  <% fra koden. Derffor udskriver den hele koden.

Vil du ik udkommentere den for mig :)

Det driller lidt for mig...

jeps.. så skal jeg bare havde brugernavn og password igen..

Du må hellere huske at ændre dit password efter dette hvis man kan det eller så send det til eagleeye@c.dk så der ikke er nogle som bruger det til uheldigheder.

Så er mailen sendt :)

Du skal bare sætte en ' foran linien On Error Resume Next

hmm, prøv lige at tjek det :)

jeg har ikke fået en mail endnu.. underligt...

Skal jeg skrive den her?

hmmm prøv lige anders@eagleeye.dk

sendt

nu fik jeg den

godt :)

Så det rettet.. Prøv at oprette nu,

Så kommer fejlen:

Server object error 'ASP 0177 : 800401f3'

Server.CreateObject Failed

/mats1122/signup_save.asp, line 6

Invalid ProgID. For additional information specific to this message please visit the Microsoft Online Support site located at: http://www.microsoft.com/contentredirect.asp.


Hvilket betyder freserverplads.dk ikke understytter ASPSmartUpload kompunenten.

Så står der:

Server object error 'ASP 0177 : 800401f3'

Server.CreateObject Failed

/mats1122/signup_save.asp, line 6

Invalid ProgID. For additional information specific to this message please visit the Microsoft Online Support site located at: http://www.microsoft.com/contentredirect.asp.

ok...men hvad vil det sige..at der er fejl i koden?

Både og.. For at uploade et billede til serveren benyttes typsik en kompuent ASPSmartUpload/ASPUpload.

Der findes scripts som kan uploade filer uden brug af kompunenter og der kræver lidt ændre af koden for at få det til at passe.

Men spørgsmålet er om Friserverplads understytter man kan uploade til deres server for man bruger typisk FSO eller Stream til at gemme billedet.

Kræver det meget at lave den kode om?

eller er der noget at gøre?

Det jeg vil forstå, hvis man kan uploade til serveren er at bruget dette scrip, som kan uploade en fil og samtidig også form data.:
http://activedeveloper.dk/download/default.asp?mode=showdownload&id=430

Den folder som billedet skal gemmes i skal man havde skrive rettighede i...
Jeg vil gerne prøve at hjælpe med at få scriptet tilrettet, men jeg vil i seng nu.. så det bliver i morgen eller onsdag...

Prøv at kontakte dem og hør hvilken kompunent man kan bruge til upload og om man kan overhoved kan upload filer via HTML-forms, ligeledes hvilken folder man skal gemme filerne i..

okay..vi ses så :)

Jeg har spurgt friserverplads.dk om de understøtter ASPSmartUpload, og det gjorde de ikke...

Tror du at det er der fejlen ligger?

Ja det er derfor den fejlen. Scriptet du har bruger ASPSmartUpload til at uploade det valgte billede til serveren.

Okay, men hvis man finder en server som understøtter det...ville det så virke perfekt?

Ja det ville det..
Det findes ASPUpload kompunent og ASPSmartUpload som er to forskellige kompunenter med de virker dog meget ens. Eksvis har azero.dk support af ASPUpload, men så er hosting ikke længere gratis.

Alternativt kan det laves med en upload kode som ikke kræver en kompunent som den jeg linkede til (23/07-2002 02:34:18), men det kræver lidt arbejde at få tilpasset scriptet.Ligeledes kræver det du har en folder hvor man som internet bruger har mulighed for at gemme filer.

Okay :)

hvorfor er det der tal der igen? 1880

http://www.friserverplads.dk/mats1122