Vis kun id fra db en gang..

prøv at kigge nærmere på denne lektion på www.html.dk (Arrays):

http://www.html.dk/tutorials/asp/lektion8.asp

/theSurfer.

Hvad hvade du tænkt der skulle ske når alle er vist ??

Umilbart ville jeg forslå at lave en liste med ID med komma mellem i cookien i stedet for at lave en ID med værdien vist ...:

Response.Cookies("tjek")("id") = Response.Cookies("tjek")("id") & "," & rs("id")

Så kan du bruge cookien i SQL sætningen i stil med:

SQL = "SELECT * FROM tabel WHERE ID NOT IN(" & Request.Cookies("tjek")("id") & ")"

Så har du et recordet kun med records som ikke er vist.

Jeg har lige skruet dette eks sammen:

<html>
<head><title></title></head>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open Server.MapPath("DATABASEFIL.mdb")
set rs = Server.CreateObject("ADODB.Recordset")

vistIDer = Request.Cookies("tjek")("id")

Response.Write "For test : " & vistIDer & "<br><br>"

SQL = "SELECT * FROM tabel"
if vistIDer <> "" then
  SQL = SQL & " WHERE ID NOT IN (" & vistIDer & ")" 
end if

rs.open SQL, conn, 1

if rs.eof then
  Response.Write "Alle ID vist cookien bliver slettet"
  Response.Cookies("tjek")("id") = ""
else
  randomize
  rs.Move(int(rs.RecordCount * rnd))
  'UDSKRIV Recorden
  Response.Write Rs("id")

  if vistIDer = "" then
    vistIDer = rs("id")
  else
    vistIDer = vistIDer & "," & rs("id")
  end if

  Response.Cookies("tjek")("id") = vistIDer
end if

rs.Close
conn.close
set rs=nothing
set conn=nothing
%>
</body>
</html>

når alle er vist ska der bare stå at der ikke nogle nye..

Ok så retter du bare disse to linier:

  Response.Write "Alle ID vist cookien bliver slettet"
  Response.Cookies("tjek")("id") = ""

Til denne ene linie:

  Response.Write "Der er ikke nogle nye indlæg"

takker..

brugte den her måde:
SQL = "SELECT * FROM tabel WHERE ID NOT IN(" & Request.Cookies("tjek")("id") & ")"