Macro

Måske kan du bruge dette link
http://www.mvps.org/word/FAQs/InterDev/ControlXLFromWord.htm

Din makro får fat i regnearket, men den kan ikke få fat i makroen i excel, den siger hele tiden at det kan man ikke, hvordan skal det skrives hvis man ønsker at afspille en makro i excel fra en worddokument???

Tjek lige i Visual Basic modulet, at du under Tools - References, har afkrydset Microsoft Excel 9.0 (XP= 10.0) object library. Man skal nemlig altid sørge for, at have adgang til det programs object library som man vil bruge.

Jeg har nu afprøvet den macro jeg tidligere henviste til, med indsættelse af:

Call oXL.Run("Macro navn")

Jeg måtte lægge macroen i selve workbooken, men med den rette henvisning, kan den nok også virke i personal marcro workbook.

Det virker, så jeg gengiver hele macroen her med min tilføjelse. Du skal selvfølgelig tilpasse den til dit, men det er vigtigt at afkrydse objekt biblioteket for Excel i Word, ellers virker den ikke.


Sub WorkOnAWorkbook()


Dim oXL As Excel.Application
Dim oWB As Excel.Workbook
Dim oSheet As Excel.Worksheet
Dim oRng As Excel.Range
Dim ExcelWasNotRunning As Boolean
Dim WorkbookToWorkOn As String

'specify the workbook to work on
WorkbookToWorkOn = "E:\myworkbook.xls"

'If Excel is running, get a handle on it; otherwise start a new instance of Excel
On Error Resume Next
Set oXL = GetObject(, "Excel.Application")

If Err Then
  ExcelWasNotRunning = True
  Set oXL = New Excel.Application
End If

On Error GoTo Err_Handler

'If you want Excel to be visible, you could add the line: oXL.Visible = True here; but your code will run faster if you don't make it visible

'Open the workbook
Set oWB = oXL.Workbooks.Open(FileName:=WorkbookToWorkOn)

'Process each of the spreadsheets in the workbook
For Each oSheet In oXL.ActiveWorkbook.Worksheets
 
Call oXL.Run("SortData")

  'put guts of your code here
  'get next sheet
Next oSheet

If ExcelWasNotRunning Then
  oXL.Quit
End If

'Make sure you release object references.
Set oRng = Nothing
Set oSheet = Nothing
Set oWB = Nothing
Set oXL = Nothing

'quit
Exit Sub

Err_Handler:
  MsgBox WorkbookToWorkOn & " caused a problem. " & Err.Description, vbCritical, "Error: " _
  & Err.Number
  If ExcelWasNotRunning Then
      oXL.Quit
  End If

End Sub

Du kunne importer din makro fra Excel til Word. Ovenstående kode ligger faktisk op til det, idet er er oprettet et ExcelObjekt (oXL)

Det gøres således: Du skriver bare oXL. foran alle linierne i din Excel kode og kopier din ind i Word. F.eks.

oXL.Range("A1").select

Det virker perfekt tak skal du have!!

Selv tak, så lærte jeg også selv noget nyt :-)