ListView Kolonne 2 og Label.Caption

Label1.Caption := Listview1.Items.Item[1].caption;

ListView1.Selected.SubItems[0]

Det skal stå i Listview OnSelectItem.. ;)

Det er faktisk lidt pænere at skrive ListView1.Selected.SubItems.Strings[0], men det er op til dig!! :)

eller nej:
if ListView1.Items.Item[1].Selected then
Label1.Caption := Listview1.Items.Item[1].Caption;

I OnSelectItem

prøv det her :

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  ExtCtrls, commctrl, ComCtrls, StdCtrls;

type
  PLVHitTestInfoNew = ^TLVHitTestInfoNew;
  TLVHitTestInfoNew = record
    Pt: TPoint;
    Flags: Integer;
    iItem: Integer;
    iSubItem: Integer;
  end;

  TCell = record
    x, y: Integer;
  end;
  TExListView = class(TListview)
  private
    FSelectedCell: TCell;
    function ListView_SubItemHitTest(var lvhti: TLVHitTestInfoNew): Integer;
    function ListViewSubItemHitTest(X: Integer; Y: Integer): Integer;
    function GetCellText(const x, y: Integer): string;
    procedure SetCellText(const x, y: Integer; const Text: string);
    procedure WMLButtonDown(var Message: TWMLButtonDown); message WM_LBUTTONDOWN;
  public
    property SelectedCell: TCell read FSelectedCell;
  end;

  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
  private
    ListView: TExListView;
    procedure ListViewMouseDown(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.DFM}

procedure TForm1.ListViewMouseDown(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
begin
  Caption := Format('Selected Cell : [%d,%d] Text : %s', [ListView.SelectedCell.x, ListView.SelectedCell.y, ListView.GetCellText(X, Y)]);
end;

procedure TForm1.FormCreate(Sender: TObject);
var
  ListColumn: TListColumn;
  ListItem: TListItem;
  i: Integer;
begin
  Randomize;
  ListView := TExListView.Create(Form1);

  with ListView do
  begin
    Align := alClient;
    ReadOnly := True;
    OnMouseDown := ListViewMouseDown;
    ViewStyle := vsReport;
    RowSelect := True;
  end;

  Form1.InsertControl(ListView);

  for i := 0 to 2 do
  begin
    ListColumn := ListView.Columns.Add;
    ListColumn.AutoSize := True;
    ListColumn.Alignment := taCenter;
    ListColumn.Caption := IntToStr(Random(5000));
  end;

  for i := 0 to 15 do
  begin
    ListItem := ListView.Items.Add;
    ListItem.Caption := IntToStr(Random(5000));
    ListItem.SubItems.Add(IntToStr(Random(5000)));
    ListItem.SubItems.Add(IntToStr(Random(5000)));
  end;
end;

{ TExListView }

function TExListView.ListView_SubItemHitTest(var lvhti: TLVHitTestInfoNew): Integer;
begin
  Result := SendMessage(Self.Handle, LVM_SUBITEMHITTEST, 0, Longint(@lvhti));
end;

function TExListView.ListViewSubItemHitTest(X, Y: Integer): Integer;
var
  HitTest: TLVHitTestInfoNew;
begin
  HitTest.pt.X := X;
  HitTest.pt.Y := Y;
  // Calls ListView_SubItemHitTest from *this* unit, not from CommCtrl.pas
  ListView_SubItemHitTest(HitTest);
  Result := HitTest.iSubItem;
end;

procedure TExListView.SetCellText(const x, y: Integer; const Text: string);
var
  Item: TListItem;
  iSubItem: Integer;
begin
  Item := Self.GetItemAt(X, Y);
  if Assigned(Item) then
  begin
    iSubItem := ListViewSubItemHitTest(X, Y);
    if iSubItem = 0 then
      Item.Caption := Text
    else
      Item.SubItems[iSubItem - 1] := Text;
  end;
end;

function TExListView.GetCellText(const x, y: Integer): string;
var
  Item: TListItem;
  iSubItem: Integer;
begin
  Item := Self.GetItemAt(X, Y);

  if Assigned(Item) then
  begin
    iSubItem := ListViewSubItemHitTest(X, Y);
    if iSubItem = 0 then
      Result := Format('%s', [Item.Caption])
    else
      Result := Format('%s', [Item.SubItems[iSubItem - 1]]);
  end;
end;

procedure TExListView.WMLButtonDown(var Message: TWMLButtonDown);
var
  aCell: TCell;
var
  Item: TListItem;
  iSubItem: Integer;
  iRow: Integer;
begin
  Item := Self.GetItemAt(Message.XPos, Message.YPos);

  if Assigned(Item) then
  begin
    iSubItem := Self.ListViewSubItemHitTest(Message.XPos, Message.YPos);
    iRow := Self.Items.IndexOf(Item);
    aCell.x := iRow;
    aCell.y := iSubItem;
  end;

  fSelectedCell := aCell;

  inherited;
end;

end.

Kigger på det og vender tilbage om lidt

Jeg kan ikke helt få det til at virke. Jeg kigger på det når jeg kommer hjem. Vi skrives om et par timer. ;-)

Opret et nyt projekt og paste DET hele ind i stedet for det der stod

borrisholt> Tom form ;)

www.borrisholt.com/Eksperten/TListViewDemo.zip

Så kom det til at virke som det skulle. Jeg brugte hermandsen 's metode men jeg skal ikke frasige mig om de andre virkede. Derfor har jeg forhøjet og fordelt point'ne mellem jer. Jeg håber det er ok sådan ;-)