Automatisk tilpasning af rækkehøjde

Har du prøvet at sætte hak i "ombryd tekst" under celleformatering.

Ja, men det har ingen indflydelse. Desværre.

Jeg tror problemet skyldes de flettede celler.
Hvis jeg fletter et par celler, justerer den ikke rækkehøjden, hvis der ombrydes.
Er den samme tekst derimod skrevet i én celle, justeres rækkehøjden automatisk til indholdet.

Den er ikke længere end at Excel ikke kan finde ud af det selv, når der er tale om flettede celler. Dog er det sådan, at det kan løses med en makro der løber f.eks. et område igennem og laver nummeret for dig.

Jeg har lavet den før, og kan vel finde den....! Jeg vil kigge på det senere i aften, når jeg kommer hjem.

Lyder godt. Jeg er nemlig gået i stå her, og skal lave en masse om i min model, hvis jeg "kun" kan bruge 1 celle.

Denne her virker vist kun en merged celle - men der kan leges - prøv

Public Sub AutoFitMergedCellRowHeight()
    Dim iCurrentRowHeight As Single
    Dim iMergedCellRgWidth As Single
    Dim iActiveCellWidth As Single
    Dim iPossNewRowHeight As Single
    Dim rCurCell As Range
   
    If ActiveCell.MergeCells Then
      With ActiveCell.MergeArea
            If .Rows.Count = 1 And .WrapText = True Then
                Application.ScreenUpdating = False
                iCurrentRowHeight = .RowHeight
                iActiveCellWidth = ActiveCell.ColumnWidth
                For Each rCurCell In Selection
                    iMergedCellRgWidth = rCurCell.ColumnWidth + iMergedCellRgWidth
                Next
                .MergeCells = False
                .Cells(1).ColumnWidth = iMergedCellRgWidth
                .EntireRow.AutoFit
                iPossNewRowHeight = .RowHeight
                .Cells(1).ColumnWidth = iActiveCellWidth
                .MergeCells = True
                .RowHeight = IIf(iCurrentRowHeight > iPossNewRowHeight, _
                iCurrentRowHeight, iPossNewRowHeight)
            End If
        End With
    End If

    Set rCurCell = Nothing
End Sub

Indtil videre tak. Jeg er lidt presset her inden julen, så jeg vender tilbage snarest, når jeg får den testet.

Det ser ud til at virke, når jeg skal forøge rækkehøjden. Jeg kan dog ikke få makroen til at virke, når jeg skal formindske fra fx 3 i højden til 2 i højden. Kan dette løses? Jeg kan ikke selv gennemskue ovennævnte kode.

Her er tilføjet en enkelt linie......

Public Sub AutoFitMergedCellRowHeight()
    Dim iCurrentRowHeight As Single
    Dim iMergedCellRgWidth As Single
    Dim iActiveCellWidth As Single
    Dim iPossNewRowHeight As Single
    Dim rCurCell As Range
   
    If ActiveCell.MergeCells Then
      With ActiveCell.MergeArea
            If .Rows.Count = 1 And .WrapText = True Then
                Application.ScreenUpdating = False
                .EntireRow.AutoFit
                iCurrentRowHeight = .RowHeight
                iActiveCellWidth = ActiveCell.ColumnWidth
                For Each rCurCell In Selection
                    iMergedCellRgWidth = rCurCell.ColumnWidth + iMergedCellRgWidth
                Next
                .MergeCells = False
                .Cells(1).ColumnWidth = iMergedCellRgWidth
                .EntireRow.AutoFit
                iPossNewRowHeight = .RowHeight
                .Cells(1).ColumnWidth = iActiveCellWidth
                .MergeCells = True
                .RowHeight = IIf(iCurrentRowHeight > iPossNewRowHeight, _
                iCurrentRowHeight, iPossNewRowHeight)
            End If
        End With
    End If

    Set rCurCell = Nothing
End Sub


Der er et problem i Excel med autohøjden af en række..... hvis sidste linie i en celle går næsten til kanten af cellen, så kan Excel finde på at lave højden en række for høj, og det kan jeg ikke komme omkring ved.

Det virker. Mange tak for hjælpen.