Lille projekt der kan søge efter filer - men mere end een fil

Option Explicit
Dim fso As Scripting.FileSystemObject
Dim filer() As String

Private Sub FindFile(folder As Scripting.folder)
Dim tmpFolder As Scripting.folder
Dim tmpFile As Scripting.File

  If folder.Attributes <> 22 Then 'Nogle systemmapper har man ikke adgang til
    If folder.SubFolders.Count > 0 Then
      For Each tmpFolder In folder.SubFolders
        FindFile tmpFolder
        DoEvents
      Next
    End If
    If folder.Files.Count > 0 Then
      For Each tmpFile In folder.Files
        If FilSøgesEfter(tmpFile.Name) Then
          lstResultat.AddItem tmpFile.Path
        End If
      Next
    End If
  End If
End Sub

Private Sub cmdSøg_Click()
Dim dc As Drive

  If txtSøg.Text <> "" Then
    If InStr(Len(txtSøg.Text), txtSøg.Text, ";", vbTextCompare) > 0 Then txtSøg.Text = Left$(txtSøg.Text, Len(txtSøg.Text) - 1)
    filer() = Split(txtSøg.Text, ";", , vbTextCompare)
    lstResultat.Clear
    For Each dc In fso.Drives 'Søger gennem alle drev
      If dc.DriveType = Fixed Then
        FindFile fso.GetFolder(dc.Path & "\")
      End If
    Next
  End If
End Sub

Private Function FilSøgesEfter(filNavn As String) As Boolean
Dim bFound As Boolean
Dim i As Integer

  i = LBound(filer)
  While Not bFound And i <= UBound(filer)
    If filNavn = filer(i) Then bFound = True
    i = i + 1
  Wend
  FilSøgesEfter = bFound
End Function

Private Sub Form_Load()
  Set fso = New Scripting.FileSystemObject
End Sub

Private Sub Form_Unload(Cancel As Integer)
  End
End Sub

Mit forslag til hvordan det kunne gøres, hvordan det performer hvis du har indtastet 117 filer har jeg ikke lige gidet eksperimentere med.

For at kunne køre det skal der laves en reference til Microsoft Scripting Runtime.
Ellers bare en form med en knap, et tekstfelt og en listboks.

Og der er flere eksempler hvis du søger efter dem her på eksperten