VBA - Hvordan finder jeg "brugernavnet"

'------------------------------ Form1 ------------------------------
Option Explicit

Private Declare Function GetUserName Lib "advapi32.dll" _
                          Alias "GetUserNameA" ( _
                          ByVal lpBuffer As String, _
                          nSize As Long) As Long

Private Declare Function GetComputerName Lib "kernel32" _
                          Alias "GetComputerNameA" ( _
                          ByVal lpBuffer As String, _
                          nSize As Long) As Long

Public Function Username() As String
Dim strBuff As String
  strBuff = String(100, Chr$(0))
  Call GetUserName(strBuff, 100)
  Username = Left$(strBuff, InStr(strBuff, Chr$(0)) - 1)
End Function

Public Function ComputerName() As String
Dim strBuff As String
  strBuff = String(100, Chr$(0))
  Call GetComputerName(strBuff, 100)
  ComputerName = Left$(strBuff, InStr(strBuff, Chr$(0)) - 1)
End Function

Private Sub Form_Load()
  Me.Caption = (ComputerName & "\" & Username)
End Sub
'------------------------------ Form1 ------------------------------

Beklager - det er "logon brugernavnet".

Eks:

Peter Jensen er oprettet som bruger på domænet med brugernavn pj.

Din funktion returerer pj - jeg vil have "Peter Jensen"

Dim wshNetwork
Set wshNetwork = CreateObject("WScript.Network")
brugernavn = wshNetwork.UserName
domain = wshNetwork.userdomain
PcNavn = wshNetwork.ComputerName
'dette lille script finder både brugernavn,domæne samt computernavn.

kabbak> Den gør præcis det samme som sjh's - blot gennem Windows Script Host. Det (stadig) ikke det jeg søger.

Jeg har fundet en løsning gennem ADSI, og det kan godt være at det er vejen frem.

Her er så min løsning:

Function GetFullUserName()
    Dim WshNetwork, Command
    Set WshNetwork = CreateObject("WScript.Network")
    UserName = WshNetwork.UserName
    Set con = CreateObject("ADODB.Connection")
    con.Provider = "ADsDSOObject"
    con.Open
    Set Command = CreateObject("ADODB.Command")
    Set Command.ActiveConnection = con
    Command.CommandText = "SELECT * FROM 'LDAP://DC=ed,DC=dk' WHERE sAMAccountName = '" & UserName & "'"
    Command.Properties("searchscope") = 2
    Set rs = Command.Execute
    If rs.EOF Then
        GetFullUserName = ""
    Else
        Set UserObject = GetObject((rs("ADsPath")))
        GetFullUserName = UserObject.FullName
    End If
   

End Function

Sub AutoNew()
  ' Signature name is a document variable (Field Type DocVariable)
  ActiveDocument.Variables("SignatureName").Value = GetFullUserName
  ActiveDocument.Fields.Update
End Sub