Sende mail fra Access

Se lige denne!

http://www.eksperten.dk/spm/9038

senj - desværre. Det er ikke på den måde jeg har brug for det. når jeg skriver en besked ud for en given person, skal jeg blot trykke på en knap, så sender den beskeden via den e-mail der står ud for personen. Hvordan skal det gøres?

Sub SendMessage(DisplayMsg As Boolean, ParSubject As String, ParBody As String, Optional AttachmentPath)
          Dim objOutlook As Outlook.Application
          Dim objOutlookMsg As Outlook.MailItem
          Dim objOutlookRecip As Outlook.Recipient
          Dim objOutlookAttach As Outlook.Attachment

          \' Opret Outlook session.
          Set objOutlook = CreateObject(\"Outlook.Application\")

          \' Opret meddelelsen.
          Set objOutlookMsg = objOutlook.CreateItem(olMailItem)

          With objOutlookMsg
              \' Tilføj modtager.
              Set objOutlookRecip = .Recipients.Add(Her indsættes din modtagers e-mail)
              objOutlookRecip.Type = olTo
             
             
             
              \' Tilføj evt. CC modtager.
\'              Set objOutlookRecip = .Recipients.Add(CC modtager)
\'              objOutlookRecip.Type = olCC


            \' Sæt Emne, Indhold og Prioritet.
            .Subject = ParSubject
            .Body = ParBody
            .Importance = olImportanceHigh  \'High importance

            \' Tilføj evt. vedhæftet fil.
            If Not IsMissing(AttachmentPath) Then
                Set objOutlookAttach = .Attachments.Add(AttachmentPath)
            End If

            \' Kontroller navne.
            For Each objOutlookRecip In .Recipients
                objOutlookRecip.Resolve
            Next

            \' Skal meddelelsen vises inden afsendelse?
            If DisplayMsg Then
                .Display
            Else
                .Save
                .Send
            End If
          End With
          Set objOutlook = Nothing
      End Sub

Kald denne rutine fra din knap\'s hændelsesprocedure og overfør modtager, emne og indhold, så skulle den være der.

Husk at databasen skal indeholde en reference til Outlook 8.0 Object library.

Hilsen Søren

Tak for svaret. Skal den ikke sættes ind i MODULES? Skal den ikke vide hvorfra den skal hente tabellen med e-mail adressen, samt tabellen for beskeden?

-fw

Funktionen behøver ikke nødvendigvis at ligge under Modules, men det ville nok være mest fornuftigt, eftersom du måske skal kalde den fra forskellige formularer. Og jo, funktionen skal have de input jeg nævnte \"modtager\", \"emne\" og \"indhold\". Dem skal din knap\'s hændelsesprocedure selv \"fiske\" ud af formen og sende med.
  Søren

Hej igen.

Øh, hvordan får jeg knappen til at fiske ud af formen og sender det med?

-fw

Hvis vi går ud fra at du på din form har følgende navngivne felter: \"email\", \"Emne\" og \"Indhold\" som er bundet til de respektive kolonner i tabellen, så kan det gøres sådan her:

SendMessage(False, Me!email, Me!Emne, Me!Indhold)

eller, hvis du vil have vist meddelelsen inden afsendelse så du selv kan rette i den:
SendMessage(True, Me!email, Me!Emne, Me!Indhold)

Det kræver en lille ændring i funktionen:

Sub SendMessage(DisplayMsg As Boolean, ParRecipient As String, ParSubject As String, ParBody As String, Optional AttachmentPath)
          Dim objOutlook As Outlook.Application
          Dim objOutlookMsg As Outlook.MailItem
          Dim objOutlookRecip As Outlook.Recipient
          Dim objOutlookAttach As Outlook.Attachment

          \' Opret Outlook session.
          Set objOutlook = CreateObject(\"Outlook.Application\")

          \' Opret meddelelsen.
          Set objOutlookMsg = objOutlook.CreateItem(olMailItem)

          With objOutlookMsg
              \' Tilføj modtager.
              Set objOutlookRecip = .Recipients.Add(ParRecipient)
              objOutlookRecip.Type = olTo
             
            \' Sæt Emne, Indhold og Prioritet.
            .Subject = ParSubject
            .Body = ParBody
            .Importance = olImportanceHigh  \'High importance

            \' Tilføj evt. vedhæftet fil.
            If Not IsMissing(AttachmentPath) Then
                Set objOutlookAttach = .Attachments.Add(AttachmentPath)
            End If

            \' Kontroller navne.
            For Each objOutlookRecip In .Recipients
                objOutlookRecip.Resolve
            Next

            \' Skal meddelelsen vises inden afsendelse?
            If DisplayMsg Then
                .Display
            Else
                .Save
                .Send
            End If
          End With
          Set objOutlook = Nothing
      End Sub

Jeg prøver den lige lidt senere, måske i aften, men jeg synes alligevel du fortjener points for din udholdenhed!

mvh fw