loop .jpg og opret xml fil

ps. eks gerne i vb.net :-)

Imports System
Imports System.IO
Imports System.Xml

Public Class MyUtilities
    Public Shared Function DirToXml(Dir As String, Pat As String) As XmlDocument
        Dim doc As XmlDocument = New XmlDocument
        Dim root As XmlElement = doc.CreateElement("IMAGES")
        doc.AppendChild(root)
        Dim files As String() = Directory.GetFiles(Dir, Pat)
        For Each f As String In files
            Dim elm As XmlElement = doc.CreateElement("IMAGE")
            elm.AppendChild(doc.CreateTextNode(f.ToString))
            root.AppendChild(elm)
        Next
        DirToXml = doc
    End Function
End Class

kaldes som:

Dim res As XmlDocument = MyUtilities.DirToXml("C:\", "*.jpg")

Hov den skriver directory navn med.

Det gør den her version ikke:

Public Class MyUtilities
    Public Shared Function DirToXml(Dir As String, Pat As String) As XmlDocument
        Dim doc As XmlDocument = New XmlDocument
        Dim root As XmlElement = doc.CreateElement("IMAGES")
        doc.AppendChild(root)
        Dim files As String() = Directory.GetFiles(Dir, Pat)
        For Each f As String In files
            Dim elm As XmlElement = doc.CreateElement("IMAGE")
            elm.AppendChild(doc.CreateTextNode((New FileInfo(f)).Name))
            root.AppendChild(elm)
        Next
        DirToXml = doc
    End Function
End Class

Og du kan gemme XML dokumentet som fil med:

res.Save("jpg.xml")

Super, Arne v

Jeg kigger på det i aften når det er blevet ro i huset :-)

Hej Arne

Det køre jo bare fint :-)

Dog udskriver den følgende:
<IMAGES>
  <IMAGE>IMG_0224.JPG</IMAGE>
  <IMAGE>IMG_0225.JPG</IMAGE>
</IMAGES>

hvor jeg gerne vil have at den udskriver:

<IMAGES>
  <IMAGE><NAME>IMG_0224.JPG</NAME></IMAGE>
  <IMAGE><NAME>IMG_0225.JPG></NAME></IMAGE>
</IMAGES>

Kan man rette det til? .-)

Selvfølgelig kan man det !

Public Class MyUtilities
    Public Shared Function DirToXml(Dir As String, Pat As String) As XmlDocument
        Dim doc As XmlDocument = New XmlDocument
        Dim root As XmlElement = doc.CreateElement("IMAGES")
        doc.AppendChild(root)
        Dim files As String() = Directory.GetFiles(Dir, Pat)
        For Each f As String In files
            Dim elm As XmlElement = doc.CreateElement("IMAGE")
            Dim subelm As XmlElement = doc.CreateElement("NAME")
            subelm.AppendChild(doc.CreateTextNode((New FileInfo(f)).Name))
            elm.AppendChild(subelm)
            root.AppendChild(elm)
        Next
        DirToXml = doc
    End Function
End Class

burde ordne det

Super.... Mange tak :-)

vil det sige at man bare kan oprette nye xmlEmementer inden i hinanden ved at oprette endnu en?

Ja du kan neste elementer så dybt som du nu vil.

Der er også andre måder at generere XML på i .NET framework, men et sådant
DOM træ her synes jeg passede godt til opgaven.

ok det er da smart.
Jeg skal på .net framework kursus hele næste uge, så der lære jeg forhåbentligt meget mere.
Men endnu en gang tak.