Soter billeder faldende

Der er et problem med FSO og det er man kan ikke få FSO til at sortere filerne. Så man må selv lave en sortering og det kan gøre på flere måder her to eksempler et med et array og som gør brug af et recordset.

Her er et eks som smider filerne i et array som så sorteres.:
http://www.aspfaqs.com/aspfaqs/ShowFAQ.asp?FAQID=118

Her er et eks hvor filerne smides i et recordset og sorteres:
http://www.roubaixinteractive.com/PlayGround/FSO/Sort_Folder_Contents.asp

det kan jeg virkeligt ikke finde ud af!! er der ikke noget der er beregnet til billeder??

Beklader det ene link virkede ikke. Ja det kan bruges til billeder, billeder er også filer :)

Eks på din koden med et recordset som sortere filerne :


<%
if Request.Querystring("sub") = "" then
  Response.Redirect "default.asp"
end if

ImageDir = "/fester/" & Request.Querystring("sub") ' Mappen med filerne

Set objFS = CreateObject("Scripting.FileSystemObject")
Set objFolder = objFS.GetFolder(Server.MapPath(ImageDir))
Set RS = Server.CreateObject("ADODB.Recordset")

RS.Fields.Append "navn", 200, 50
RS.Open

For Each file in objFolder.Files
  RS.Addnew
  RS("navn") = file.Name
  RS.Update 
Next
RS.Sort = "navn ASC"

intPage = Request.Querystring("page")
If isNumeric(intPage) = False Or intPage < 1 Then
  intPage = 1
End If

intPageSize = 16 ' Antal filer på hver side
intImgCount = RS.RecordCount
intPageCount = -Int(-(intImgCount/intPageSize))
tmp=intPageSize
RS.Move((intPage-1)*intPageSize)

do while (not RS.EOF) and tmp>0
  Response.Write "<a href=""#"" onclick=""showLargeImage('img.asp?img=" & ImageDir & "stor/" & RS("navn") & "')"">"
  Response.Write "<img border='0' src='" & ImageDir & RS("navn") & "'></a>&nbsp;"
  tmp=tmp-1
  RS.MoveNext
loop

strScriptName = Request.Servervariables("ScriptName")
Response.Write "<br>"
Response.Write "Gå til side "
For i = 1 To intPageCount
Response.Write "<a href=" & strScriptName & "?page=" & i & "&sub=" & Request.Querystring("sub") & ">" & i & "</a> "   
Next
Set objFS = Nothing
%>

tak