Notifikationer

Markér alle som læst Log ud

pelskee Nybegynder

26. august 2004 - 09:22 Der er 18 kommentarer og
1 løsning

Upload med progress bar

er der et modul eller kode som man kan bruge til at uploade filer hvor den vises en status bar på hvor meget af filen der er uploade - tænker på at det ville være en god funktion når man uploader større filer

Synes godt om

fennec Nybegynder

26. august 2004 - 09:25 #1

Xupload og Jupload kan gøre det. Der er også mulighed for at vælge flere filer på en gang.

http://www.aspupload.com/xupload.html
http://www.aspupload.com/jupload.html

Synes godt om

eagleeye Praktikant

26. august 2004 - 09:27 #2

Hvis du har mulighed for at bruge ASPupload komponenten har den en progress bar:
http://www.aspupload.com/manual_progress.html

Har du ikke den mulighed kan upload unde komponent også findes med progrss bar:
http://www.motobit.com/help/scptutl/upload.asp

Synes godt om

pelskee Nybegynder

26. august 2004 - 09:33 #3

ASPupload har jeg hørt meget godt om, men ser det ikke ret uoverskueligt ud at implementere ?. Skal man installere ting på serveren eller skal man bare implementere koden ?

Synes godt om

eagleeye Praktikant

26. august 2004 - 09:35 #4

Ja alle komponenter skal installeres på serveren for de virker. Er det ens egen server er det som regel ikke et problem, er det et web-hotel vil de som regel ikke installere flere komponenter. Bemærk også ASPupload koster lidt $'s.

Upload uden brug af komponent skal der ikke installeres noget på serveren der er hele koden i det script man laver.

Synes godt om

pelskee Nybegynder

26. august 2004 - 09:37 #5

jeg bruger dette script på en af mine andre sider kan/skal den der progressbar implementeres i det ?

<%Session.lcid = 1030%>





<HTML><style type="text/css">

</style>
<link href="stylesheet.css" rel="stylesheet" type="text/css">
<BODY leftmargin="0" topmargin="0" marginwidth="0" marginheight="0" class="black9">

<%
Set Upload = Server.CreateObject("Persits.Upload")

' Capture files
Upload.SaveVirtual "../images/upload"

' Obtain file object
Set File = Upload.Files("THEFILE")

If Not File Is Nothing Then
' Build ODBC connection string
Connect = "Driver={Microsoft Access Driver (*.mdb)};DBQ=" & Server.MapPath("../db/gutterne.mdb")

' If you use SQL Server, the connecton string must look something like this:
' Connect = "Driver=SQL Server;Server=MYSRV;Database=master;UID=sa;PWD=xxx"

' Build SQL INSERT statement
SQL = "INSERT INTO myimages(ImageBlob, Filename, Filesize, userID, UploadDate, UploadTime, Category, Title, Description) VALUES(?, '"
SQL = SQL & File.Filename & "', '"
SQL = SQL & File.Size & "', '"
SQL = SQL & Replace(Upload.Form("IDuser"), "'", "''") & "', "
SQL = SQL & "#"& Replace(Upload.Form("Date"), "'", "''") & "#, "
SQL = SQL & "'"& Replace(Upload.Form("Time"), "'", "''") & "', "
SQL = SQL & "'"& Replace(Upload.Form("Category"), "'", "''") & "', "
SQL = SQL & "'"& Replace(Upload.Form("Title"), "'", "''") & "', "
SQL = SQL & "'"& Replace(Upload.Form("Description"), "'", "''") & "')"

' Save to database
File.ToDatabase Connect, SQL
Response.Write "Filen er gemt.</P>"
Response.Write "<a href='../galleri.asp' target='_parent'>Klik her for at uploade flere billeder</a>"
Else
Response.Write "Vælg en fil inden du prøver at uploade."
End If
%>
</BODY>
</HTML>

Synes godt om

pelskee Nybegynder

26. august 2004 - 09:41 #6

så ikke din post Eagle inden jeg skrev ovenstående
hjemmesiden hostes hos web10, de skriver:
Nedenstående komponenter er installeret på alle windowsserverne.

Components:
AspUpload3.0.0.3
AspImage 2.x
W3 Jmail4.4
MyODBC-3.51.06
ODBC.NET

Synes godt om

eagleeye Praktikant

26. august 2004 - 09:41 #7

Jamen du bruger jo ASPupload :)

Synes godt om

eagleeye Praktikant

26. august 2004 - 09:45 #8

1. I toppen af den fil du har din form hvor du vælger filer skal du indsætte:

<%
Set UploadProgress = Server.CreateObject("Persits.UploadProgress")
PID = "PID=" & UploadProgress.CreateProgressID()
barref = "framebar.asp?to=10&" & PID
%>

2. I samme fil tilføjer du imellem <head> og </head> dette java script:
<SCRIPT LANGUAGE="JavaScript">
function ShowProgress()
{
strAppVersion = navigator.appVersion;
if (document.MyForm.FILE1.value != "" || document.MyForm.FILE2.value != "" || document.MyForm.FILE3.value != "")
{
if (strAppVersion.indexOf('MSIE') != -1 && strAppVersion.substr(strAppVersion.indexOf('MSIE')+5,1) > 4)
{
winstyle = "dialogWidth=385px; dialogHeight:140px; center:yes";
window.showModelessDialog('<% = barref %>&b=IE',null,winstyle);
}
else
{
window.open('<% = barref %>&b=NN','','width=370,height=115', true);
}
}
return true;
}
</SCRIPT>

3. Ret form tagen til at havde PID med som her, smat kalde en onSubmit:

<FORM NAME="MyForm" METHOD="POST" ENCTYPE="multipart/form-data"
ACTION="dinfil.asp?<% = PID %>"
OnSubmit="return ShowProgress();">

4. Tilføje denne linje:
Upload.ProgressID = Request.QueryString("PID")

Lige efter denne:
Set UploadProgress = Server.CreateObject("Persits.Upload")

Men det hele er ogås beskrever her step-by-step , min steps er ikke nummereret ens med dem på siden :) Håber det går:
http://www.aspupload.com/manual_progress.html

Synes godt om

eagleeye Praktikant

26. august 2004 - 09:55 #9

Start med at følge deres step 1-6 og stop ved Customizing the Progress Bar i føste omgang. Når det virker kan du altid kigge vidre hvis du vil tilpasse progress Baren.

Synes godt om

pelskee Nybegynder

26. august 2004 - 09:56 #10

jeg kan ikke se hvad jeg skal skrive i filen: framebar.asp

Synes godt om

eagleeye Praktikant

26. august 2004 - 10:03 #11

framebar.asp:

<%@EnableSessionState=False%>
<% Response.Expires = -1 %>

<HTML>
<HEAD>
<TITLE>Uploading files</TITLE>
<style type='text/css'>td {font-family:arial; font-size: 9pt }</style>
</HEAD>

<% If Request("b") = "IE" Then %> 
<BODY BGCOLOR="#C0C0B0">
<IFRAME src="bar.asp?PID=<%= Request("PID") & "&to=" & Request("to") %>" title="Upload Progress" noresize scrolling=no
frameborder=0 framespacing=10 width=369 height=65></IFRAME>
<TABLE BORDER="0" WIDTH="100%" cellpadding="2" cellspacing="0">
<TR><TD ALIGN="center">
To cancel uploading, press your browser's <B>STOP</B> button.
</TD></TR>
</TABLE>
</BODY>

<%Else%> 

<FRAMESET ROWS="65%, 35%" COLS="100%" border="0" framespacing="0" frameborder="NO">
<FRAME SRC="bar.asp?PID=<%= Request("PID") & "&to=" & Request("to") %>" noresize scrolling="NO" frameborder="NO" name="sp_body">
<FRAME SRC="note.htm" noresize scrolling="NO" frameborder="NO" name="sp_note">
</FRAMESET>

<%End If%>

</HTML>

Synes godt om

eagleeye Praktikant

26. august 2004 - 10:04 #12

BAR.ASP:

<%@EnableSessionState=False%>

<%
Response.Expires = -1
PID = Request("PID")
TimeO = Request("to")

Set UploadProgress = Server.CreateObject("Persits.UploadProgress")

format = "%TUploading files...%t%B3%T%R left (at %S/sec) %r%U/%V(%P)%l%t"

bar_content = UploadProgress.FormatProgress(PID, TimeO, "#00007F", format)

If "" = bar_content Then
%>
<HTML>
<HEAD>
<TITLE>Upload Finished</TITLE>
<SCRIPT LANGUAGE="JavaScript">
function CloseMe()
{
window.parent.close();
return true;
}
</SCRIPT>
</HEAD>
<BODY OnLoad="CloseMe()">
</BODY>
</HTML>
<%
Else ' Not finished yet
%>
<HTML>
<HEAD>



<meta HTTP-EQUIV="Refresh" CONTENT="1;URL=<%
Response.Write Request.ServerVariables("URL")
Response.Write "?to=" & TimeO & "&PID=" & PID %>">



<TITLE>Uploading Files...</TITLE>

<style type='text/css'>td {font-family:arial; font-size: 9pt } td.spread {font-size: 6pt; line-height:6pt } td.brick {font-size:6pt; height:12px}</style>

</HEAD>
<BODY BGCOLOR="#C0C0B0" topmargin=0>
<% = bar_content %>
</BODY>
</HTML>

<% End If %>

Synes godt om

eagleeye Praktikant

26. august 2004 - 10:05 #13

NOTE.HTML:

<HTML>
<HEAD>
<style type='text/css'>td {font-family:arial; font-size: 9pt } </style>
</HEAD>

<BODY BGCOLOR="#C0C0B0">

<TABLE WIDTH=100%>
<TR><TD>
To cancel uploading, press your browser's <B>STOP</B> button.
</TD></TR>
</TABLE>

</BODY>
</HTML>

Synes godt om

pelskee Nybegynder

26. august 2004 - 10:12 #14

kan du se nogen progressbar på denne side: http://www.gutternes.dk/galleri.asp

Synes godt om

pelskee Nybegynder

26. august 2004 - 10:13 #15

alle filerne ligger i samme bibliotek

Synes godt om

eagleeye Praktikant

26. august 2004 - 10:18 #16

Jeg kan slet ikke vælge download der kommer en fejl på siden:
ADODB.Field error '800a0bcd'

Either BOF or EOF is True, or the current record has been deleted. Requested operation requires a current record.

/include/odbc.asp, line 117

Synes godt om

eagleeye Praktikant

26. august 2004 - 10:20 #17

men prøv at rette denne linje i javascriptet:

if (document.MyForm.FILE1.value != "" || document.MyForm.FILE2.value != "" || document.MyForm.FILE3.value != "")

Til:

if (document.MyForm.THEFILE.value != "")

Synes godt om

pelskee Nybegynder

26. august 2004 - 10:29 #18

dope - der var den

TUSINDE tak for hjælpen eagle

du er for vild. altid super hjælp

Synes godt om

timmwillum Nybegynder

20. november 2007 - 19:40 #19

Hey ... ser lige om der stadig er liv i denne her gamle tråd. Har nemlig nogenlunde samme problem.

Har gjort som vejledningen siger (har derefter kopieret framebar.asp, bar.asp og note.htm herfra (dejligt at de lige lå her). Har ikke ændret noget som helst i dem ... er det rigtigt?

Har tilpasset document.formnavn.formfelt ...

Mit problem er som følger:

For det første får jeg en tom progress bar. Under den står der "<unknown>left (at 0/sec) 0/0(0%)"

Pop-up-vinduet lukker så efter ca. 20 sekunder også selv om siden fortsat loader billedet.

Og så det helt store problem ... der blier ikke oploadet NOGET SOM HELST. Og det til trods for, at upload fungerede fint, inden jeg lavede tilpasningerne.

Nogen gode forslag????

Synes godt om

Ny bruger Nybegynder

Din løsning...

Tilladte BB-code-tags: [b]fed[/b] [i]kursiv[/i] [u]understreget[/u] Web- og emailadresser omdannes automatisk til links. Der sættes "nofollow" på alle links.

Følg dette spørgsmål

Opret Preview

Programmeringssprog kurser

Kurser inden for grundlæggende programmering

Se alle Programmeringssprog kurser

Flere spørgsmål fra ASP kategorien

Titel	Indlæg	Oprettet	Seneste aktivitet
Jeg bakser med noget Database og If Then med ASP - hvad gør jeg galt? Af Peer i ASP	9	25/06/202622:20	29/06/202621:55
Tjek alle checkbox i form Af bsn i ASP	4	18/05/202601:57	19/05/202613:33
Lost focus Af bsn i ASP	1	07/11/202415:34	01/01/202514:58
ASP classic Af bsn i ASP	8	28/10/202423:11	30/10/202422:51
Classic - filer vist med sidste fil først Af bsn i ASP	5	23/05/202409:56	24/05/202400:02

Se alle spørgsmål i kategorien Opret spørgsmål

Log ind eller opret profil

Hov!

For at kunne deltage på Computerworld Eksperten skal du være logget ind.

Det er heldigvis nemt at oprette en bruger: Det tager to minutter og du kan vælge at bruge enten e-mail, Facebook eller Google som login.

Du kan også logge ind via nedenstående tjenester

Alle kategorier på Eksperten

Seneste artiklerRSS