Finde ISP komponent / script

http://www.netcoders.dk/sources.asp?mode=view_source&tech_id=13&id=731

den er godt nok af ældre dato, men prøv den.

Hei!

Jeg ønsker å finde et script som kan finne ISP til en ipå adresse eller et komponent som kan gjøre dette.

//Morten

Fant ut av det:

<%
IP = Request.ServerVariables("REMOTE_ADDR")

Set objXML = CreateObject("Microsoft.XMLHTTP")
strURL="http://www.ripe.net/fcgi-bin/whois?form_type=simple&full_query_string=&searchtext=" & IP
objXML.Open "GET", strURL, False
objXML.Send   
strXML = objXML.ResponseText

x=instr(ucase(strXML),"<PRE>")+5
x=instr(x,ucase(strXML),"<PRE>")+5
y=instr(x,ucase(strXML),"</PRE>")

strData=mid(strXML,x,y-x)

'Finner den første MNT-BY blokken, som inneholder url til ISP.
x = instr(ucase(strData),"MNT-BY") + 7
y = instr(x,strData,vbLf)

LookUpISPURL = trim(mid(strData,x,y-x))

'Finner den første DESCR blokken, som inneholder navnet IP`en registrert på
x = instr(ucase(strData),"DESCR") + 7
y = instr(x,strData,vbLf)

LookUpProvider = trim(mid(strData,x,y-x))

LookUpISPURL = REPLACE(LookUpISPURL, "<a href=""","")
index = InStr(1,LookUpISPURL,""">")
if index > 0 then LookUpISPURL = Left(LookUpISPURL,index-1)

strURL=LookUpISPURL
objXML.Open "GET", strURL, False
objXML.Send   
strXML = objXML.ResponseText

x=instr(ucase(strXML),"<PRE>")+5
x=instr(x,ucase(strXML),"<PRE>")+5
y=instr(x,ucase(strXML),"</PRE>")

strData=mid(strXML,x,y-x)

'Finner den første DESCR blokken, som inneholder navnet til ISP`en
x = instr(ucase(strData),"DESCR") + 7
y = instr(x,strData,vbLf)

LookUpISPName = trim(mid(strData,x,y-x))

Set objXML = Nothing

'Navnet som IP er registrert på dvs firmanavnet.
Response.Write("<b>Firma:</b> " & LookUpProvider & "<br>")
'URL`en der ISP navnet er
Response.Write("<b>URL der ISP navnet er registrert:</b> " & LookUpISPURL & "<br>")
'Navnet til ISP`en
Response.Write("<b>ISP:</b> " & LookUpISPName)
%>