Gem som CSV via VBA macro

Hvis jeg anvender makroeditoren til at gemme flg. Excel range:

1    12-05-2005    1.234,56
2    13-05-2005    2.345,67
3    14-05-2005    3.456,78
4    15-05-2005    4.567,89
5    16-05-2005    5.679,00

med Gem som.. 'CSV (semikolonsepareret)', får jeg flg csv fil:

1;12-05-2005;1.234,56
2;13-05-2005;2.345,67
3;14-05-2005;3.456,78
4;15-05-2005;4.567,89
5;16-05-2005;5.679,00

Koden der genereres er:

    Range("A1:C5").Select
    ActiveWorkbook.SaveAs Filename:= _
        "D:\Mappe1.csv", FileFormat:= _
        xlCSV, CreateBackup:=False

Er det ikke det du efterspørger?

makroeditor >> makrooptager

Excel 97 og 2000 vil altid lave csv-filer i engelsk format.
Prøv at bruge denne makro istedet
Den eksporterer i dansk format..
Vælg en celle i området og kør makroen.

Sub EksportAsCSV_DK()
Const Delim                As String = ";"            'afgrænser (delimiter)
Dim strFileName            As String
Dim rngOmr                As Range
Dim y                      As Long                    'tæller
Dim x                      As Long                    'tæller
Dim strTemp                As String                  'streng til de enkelte rækker
Dim lRows                  As Long                    'antal rækker
Dim lCols                  As Long                    'antal kolonner
Dim lFno                  As Long                    'fil nummer

  strFileName = Application.GetSaveAsFilename(fileFilter:="CSV-Fil (*.csv), *.csv")
  rngOmr = Selection.CurrentRegion
  lFno = FreeFile
  lRows = rngOmr.Rows.Count
  lCols = rngOmr.Columns.Count
  Open strFileName For Output As #lFno

  For x = 1 To lRows
      strTemp = ""
      For y = 1 To lCols
        strTemp = strTemp & rngOmr(x, y).Text
        If y < lCols Then
            strTemp = strTemp & Delim
        Else
            Print #lFno, strTemp
        End If
      Next

  Next
  Close #lFno

End Sub

Til Brynil

Tak for dit svar, men det er ikke helt det jeg søger.

Det du har lavet er en macro der løber hele save as processen igennem og altid saver som "D:\mappe1.csv".

Jeg har prøvet din macro og her gemmer den stadig i engelsk format.
Jeg bruger Excel 2000 i engelsk version.

Det jeg har brug for er at save as dialog boksen bliver vist og at jeg derefter manuelt gemmer som CSV-fil.
Grunden til dette er at filen skal fungere som en skabelon for mine kollegaer og her kan det være vilkårligt hvilket filnavn og på hvilken sti de ønsker at gemme.
Jeg undkylder at jeg ikke fik formuleret dette tydeligt i første omgang.


--------------------------------------------------------------------
Til Bak

Også tak for dit svar.
Så vidt jeg kan se har du fat i noget af det rigtige. Men...

Jeg har prøvet at køre din macro og der popper en save as dialogbox frem som jeg ønsker det. Når jeg så giver den et filnavn og trykker på save så går den imidlertid i fejl.

Run-time error 91
object varable or with block variable not set

Debuggeren standser i linien
rngOmr = Selection.CurrentRegion

Jeg kiggede så på dimensioneringen af rngOmr as range. Range stod ikek med blå tekst så jeg valgte at slette "as range", så den bare dimesioneres som variable.

Herefter fejler den så på linien:
lRows = rngOmr.Rows.Count

Jeg skal indrømme at jeg er rimelig nybegynder i VBA så jeg ved ikke helt nøjagtigt hvad din macro gør, og jeg ved heller ikke rigtigt hvordan jeg kommer videre.

Der må vel findes en mere simpel måde at gribe det an på. Et eller andet med at kalde nogle locale settings frem i forbindelse med denne operation.

der er gledet et lille ord (set) ud under kopiering :-)
Husk at stå i det aktuelle område når du starter makroen

Sub EksportAsCSV_DK()
Const Delim                As String = ";"            'afgrænser (delimiter)
Dim strFileName            As String
Dim rngOmr                As Range
Dim y                      As Long                    'tæller
Dim x                      As Long                    'tæller
Dim strTemp                As String                  'streng til de enkelte rækker
Dim lRows                  As Long                    'antal rækker
Dim lCols                  As Long                    'antal kolonner
Dim lFno                  As Long                    'fil nummer

  strFileName = Application.GetSaveAsFilename(fileFilter:="CSV-Fil (*.csv), *.csv")
  Set rngOmr = Selection.CurrentRegion
  lFno = FreeFile
  lRows = rngOmr.Rows.Count
  lCols = rngOmr.Columns.Count
  Open strFileName For Output As #lFno

  For x = 1 To lRows
      strTemp = ""
      For y = 1 To lCols
        strTemp = strTemp & rngOmr(x, y).Text
        If y < lCols Then
            strTemp = strTemp & Delim
        Else
            Print #lFno, strTemp
        End If
      Next

  Next
  Close #lFno

End Sub

Til Bak

Nu virker det, tak for hjælpen

Øhh..

Det er første gang jeg bruger dette forum, så jeg er i tvivl om hvordan giver man point.
Jeg er bange for at jeg er kommet til at give dem til mig selv.
Det var Bak, der skulle have haft dem.

Please help

Det er helt ok jcoe, jeg har nok.
Du kan kun give point hvis jeg lægger et svar. Det venter jeg normalt med indtil jeg er sikker på vi har en løsning.

OK, endnu engang tak for hjælpen.