09. august 2005 - 09:06
Der er
2 løsninger
Slette nøgler / hive i RegDB
Jeg har brug for at slette en nøgle + alle undernøgler og alle værdier under nøglen... men hvordan? nedenstående script virker kun hvis der ikke findes subkeys til nøglen???
--- start
Const HKEY_LOCAL_MACHINE = &H80000002
strComputer = "."
Set objReg=GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\default:StdRegProv")
strKeyPath = "SOFTWARE\HHJ\PMS"
objReg.DeleteKey HKEY_LOCAL_MACHINE, strKeyPath
msgbox("fini")
09. august 2005 - 09:39
#2
Men kan du ikke bruge
ws.RegDelete mainkey
?
Men altså prøv det her script, det skulle gerne virke:
Const HKEY_CURRENT_USER = &H80000001
sComputer = "." ' use "." for local computer
Set oReg = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" _
& sComputer & "\root\default:StdRegProv")
sPath = "Software\Adobe\Acrobat Reader\5.0"
DeleteRegistryKey HKEY_CURRENT_USER, sPath
MsgBox "Done..."
Sub DeleteRegistryKey(ByVal sHive, ByVal sKey)
Dim aSubKeys, sSubKey, iRC
On Error Resume Next
iRC = oReg.EnumKey(sHive, sKey, aSubKeys)
If iRC = 0 And IsArray(aSubKeys) Then
For Each sSubKey In aSubKeys
If Err.Number <> 0 Then
Err.Clear
Exit Sub
End If
DeleteRegistryKey sHive, sKey & "\" & sSubKey
Next
End If
oReg.DeleteKey sHive, sKey
End Sub
//>Rune
