Vejrudsigt mv.

Du kan bruge weather.com

De tilbyder vejret via XML - også for Danmark

Ok, men jeg vil gerne have et eksempel

Hej

Tjek lige det her på DMI:

http://www.dmi.dk/dmi/rss_og_podcasts_fra_dmi

- og så er der et rss-script her:

http://www.html.dk/scripts/asp/00020/

De to ting skal bare "koges" sammen, så kan du i hvert fald få vejret :-)

\Dan

Ok, det er noget i den retning jeg mener, men hvordan kan jeg se hvilket værdier jeg kan forespørge i XML filen?

Den laver fejl når jeg sætter denne linie ind: http://www.dmi.dk/dmi/rss_og_podcasts_fra_dmi den fungerer fint med de andre fra DMI

Jamen du skal heller ikke sætte denne linie ind (http://www.dmi.dk/dmi/rss_og_podcasts_fra_dmi)!

På denne side står der bare en vejledning til hvordan du gør... Og på denne side står der så også nogle forskellige adresser på hvor du kan hente xml´en...

\Dan

HEHE

Jo den virker fint med den rss-reader...

Du kan for eksempel indsætte adressen http://www.dmi.dk/dmi/rss-mdr_vejr der...

\Dan

Jeg har prøvet og det virker også, men med dagensvejrudsigt virker det ikke

hmm...

Hvordan forsøger du dig med dagens vejr?

\Dan

Hejsa igen, beklager jeg først skriver nu, jeg bruger scriptet nedenfor, men kan ikke finde nogen XML fil med dagens vejr, hvor finder jeg det?

<%
' ****************************************************************
' Dette script kan benyttes gratis, frit, og uden at indhente tilladelse først
' - dog må selve kildekoden ikke distribueres på andre sites end HTML.dk
' Kontakt HTML.dk hvis du er i tvivl
' ****************************************************************

' Adressen på det RSS-feed der skal loades
extURL = "http://www.html.dk/rss/dk.edb.internet.webdesign.xml"

' RSS-feedet loades
set xmlDoc = createObject("Msxml.DOMDocument")
xmlDoc.async = false
xmlDoc.setProperty "ServerHTTPRequest", true
xmlDoc.load(extURL)

' Check at RSS-feedet er loadet korrekt
If (xmlDoc.parseError.errorCode <> 0) then
    ' Udskriv eventuelle fejl (for nem fejlretning)
    Response.Write "XML error: " & xmlDoc.parseError.reason
' Fortsæt hvis alt er ok
Else

    ' Åbn elementet <channel>
    set channelNodes = xmlDoc.selectNodes("//channel/*")

    for each entry in channelNodes
        ' De tre obligatoriske elementer i channel lægges i variable
        if entry.tagName = "title" then
            strChannelTitle = entry.text
        elseif entry.tagName = "description" then
            strChannelDescription = entry.text
        elseif entry.tagName = "link" then
            strChannelLink = entry.text
        end if
    next

    ' De tre obligatoriske elementer i channel udskrives
    response.write "<h1>" & strChannelTitle & "</h1>"
    response.write "<p>" & strChannelDescription & "</p>"
    response.write "<p><a href='" & strChannelLink & "'>Besøg " & strChannelTitle & "</a></p>"
    response.write "<hr />"

    ' Åbn elementerne <item>
    set itemNodes = xmlDoc.selectNodes("//item/*")

    For each item in itemNodes
        ' Elementerne i channel lægges i variable med #%# som adskillelse
        if item.tagName = "title" then
            strItemTitle = strItemTitle & item.text & "#%#"
        elseif item.tagName = "link" then
            strItemLink = strItemLink & item.text & "#%#"
        elseif item.tagName = "description" then
            strItemDescription = strItemDescription & item.text & "#%#"
        end if
    next

    ' Elementerne i channel splittes i arrays
    arrItemTitle = split(strItemTitle,"#%#")
    arrItemLink = split(strItemLink,"#%#")
    arrItemDescription = split(strItemDescription,"#%#")

    ' Elementerne i channel udskrives
    response.write "<ul>"
        for a = 0 to UBound(arrItemTitle) - 1
            response.write "<li>"
            response.write "<a href='" & arrItemLink(a) & "'>" & arrItemTitle(a) & "</a>"
                ' Description udskrives hvis den eksisterer
                if strItemDescription <> "" then
                    response.write "<br />" & arrItemDescription(a)
                end if
            response.write "</li>"
        next
    response.write "</ul>"

    ' Vi rydder op
    set channelNodes = nothing
    set itemNodes = nothing

End If

%>

Jeg ved ikke hvor du kan hente en xml-fil som indeholder dagens vejr... Du kunne jo eventuelt prøve at skrive til DMI om de ved det...
eller også tage en surftour på nettet omhandlende dette...
\Dan

Lukker