Replace HTML og URL

Brug din indsættelse som den er nu. Men når du udskriver så send det igennem en server.HTMLencode("tekst"). Fortæl samtidig dine brugere at links bare skal skrives som "www.domæne.dk" og lav så selv alle links om til <a></a> tags med en funktion.

Her har du koden:
Function LinkString(strInput)
dim arrPattern, arrReplaceString, Rx, intIndex
  arrPattern = Array("([\w\._-]+@[\w\._-]+\.[A-Za-z]{2,4}\S*)", _
  "(http|https|ftp)(:\/\/[\w\._-]+\.[\w\._-]+\S*)", _
  "(^|[^\/])(www[^\.\s]?\.[\w\._-]+\.[A-Za-z]{2,4}\S*)")

  arrReplaceString = Array(" <a href='mailto:$1'>$1</a> ", _
  " <a href='$1$2' target='_blank'>$1$2</a> ", _
  " <a href='http://$2' target='_blank'>$2</a> ")

  Set Rx = New RegExp
  Rx.Global = True
  Rx.IgnoreCase = True

  For intIndex = 0 To UBound(arrPattern)
    Rx.Pattern = arrPattern(intIndex)
    strInput = Rx.Replace(strInput, arrReplaceString(intIndex))
  Next
  Set Rx = Nothing

  LinkString = strInput
End Function

Response.write LinkString(server.htmlencode("en tekst med link www.site.dk/index.asp"))

den laver også email adr om til mailto links.

Det er bare kanon godt, det virker bare! Tak :-)
Smider du lige et svar?

.o) <-- One Eyed Jack

=O) <-- No eye Bob

Tak for point.
|o) <-- Anonymius Bill